VBoxGuestAdditions.nsi@ 53332

Last change on this file since 53332 was 53129, checked in by vboxsync, 10 years ago
Additions/WINNT/Installer: show svn revision in the installer GUI.
Property svn:eol-style set to `native` Property svn:keywords set to `Author Date Id Revision`
File size: 42.5 KB

Line
1	; $Id: VBoxGuestAdditions.nsi 53129 2014-10-23 10:16:25Z vboxsync $
2	; @file
3	; VBoxGuestAdditions.nsi - Main file for Windows Guest Additions installation.
4	;
5
6	;
7	; Copyright (C) 2012-2014 Oracle Corporation
8	;
9	; This file is part of VirtualBox Open Source Edition (OSE), as
10	; available from http://www.virtualbox.org. This file is free software;
11	; you can redistribute it and/or modify it under the terms of the GNU
12	; General Public License (GPL) as published by the Free Software
13	; Foundation, in version 2 as it comes in the "COPYING" file of the
14	; VirtualBox OSE distribution. VirtualBox OSE is distributed in the
15	; hope that it will be useful, but WITHOUT ANY WARRANTY of any kind.
16	;
17
18	!if $%BUILD_TYPE% == "debug"
19	!define _DEBUG ; Turn this on to get extra output
20	!endif
21
22	!ifdef _DEBUG
23	; Scratch directory for plugin tests
24	!addincludedir .\PluginTest
25	!addplugindir .\PluginTest
26	!endif
27
28	; Defines for special functions
29	!define WHQL_FAKE ; Enables faking of non WHQL signed / approved drivers
30	; Needs the VBoxWHQLFake.exe in the additions output directory!
31	!define WFP_FILE_EXCEPTION ; Enables setting a temporary file exception for WFP proctected files
32
33	!define VENDOR_ROOT_KEY "SOFTWARE\$%VBOX_VENDOR_SHORT%"
34
35	; Product defines
36	!define PRODUCT_NAME "$%VBOX_PRODUCT% Guest Additions"
37	!define PRODUCT_DESC "$%VBOX_PRODUCT% Guest Additions"
38	!define PRODUCT_VERSION "$%VBOX_VERSION_MAJOR%.$%VBOX_VERSION_MINOR%.$%VBOX_VERSION_BUILD%.0"
39	!define PRODUCT_PUBLISHER "$%VBOX_VENDOR%"
40	!define PRODUCT_COPYRIGHT "(C) $%VBOX_C_YEAR% $%VBOX_VENDOR%"
41	!define PRODUCT_OUTPUT "VBoxWindowsAdditions-$%BUILD_TARGET_ARCH%.exe"
42	!define PRODUCT_WEB_SITE "http://www.virtualbox.org"
43	!define PRODUCT_INSTALL_KEY "${VENDOR_ROOT_KEY}\VirtualBox Guest Additions"
44	!define PRODUCT_UNINST_KEY "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}"
45	!define PRODUCT_UNINST_ROOT_KEY "HKLM"
46
47	!define LICENSE_FILE_RTF "license.rtf"
48
49	; Needed for InstallLib macro: Install libraries in every case
50	!define LIBRARY_IGNORE_VERSION
51
52	VIProductVersion "${PRODUCT_VERSION}"
53	VIAddVersionKey "FileVersion" "$%VBOX_VERSION_STRING%"
54	VIAddVersionKey "ProductName" "${PRODUCT_NAME}"
55	VIAddVersionKey "ProductVersion" "${PRODUCT_VERSION}"
56	VIAddVersionKey "CompanyName" "${PRODUCT_PUBLISHER}"
57	VIAddVersionKey "FileDescription" "${PRODUCT_DESC}"
58	VIAddVersionKey "LegalCopyright" "${PRODUCT_COPYRIGHT}"
59	VIAddVersionKey "InternalName" "${PRODUCT_OUTPUT}"
60
61	; This registry key will hold the mouse driver path before install (NT4 only)
62	!define ORG_MOUSE_PATH "MousePath"
63
64	; If we have our guest install helper DLL, add the
65	; plugin path so that NSIS can find it when compiling the installer
66	; Note: NSIS plugins always have to be compiled in 32-bit!
67	!if $%VBOX_WITH_GUEST_INSTALL_HELPER% == "1"
68	!addplugindir "$%PATH_TARGET_X86%\VBoxGuestInstallHelper"
69	!endif
70
71	!include "LogicLib.nsh"
72	!include "FileFunc.nsh"
73	!insertmacro GetParameters
74	!insertmacro GetOptions
75	!include "WordFunc.nsh"
76	!insertmacro WordFind
77	!insertmacro StrFilter
78
79	!include "nsProcess.nsh"
80	!include "Library.nsh"
81	!include "Sections.nsh"
82	!include "strstr.nsh" ; Function "strstr"
83	!include "servicepack.nsh" ; Function "GetServicePack"
84	!include "winver.nsh" ; Function for determining Windows version
85	!define REPLACEDLL_NOREGISTER ; Replace in use DLL function
86	!include "ReplaceDLL.nsh"
87	!include "dumplog.nsh" ; Dump log to file function
88
89	!if $%BUILD_TARGET_ARCH% == "amd64"
90	!include "x64.nsh"
91	!endif
92
93	; Set Modern UI (MUI) as default
94	!define USE_MUI
95
96	!ifdef USE_MUI
97	; Use modern UI, version 2
98	!include "MUI2.nsh"
99
100	; MUI Settings
101	!define MUI_WELCOMEFINISHPAGE_BITMAP "$%VBOX_BRAND_WIN_ADD_INST_DLGBMP%"
102	!define MUI_ABORTWARNING
103	!define MUI_WELCOMEPAGE_TITLE_3LINES "Welcome to the ${PRODUCT_NAME} Additions Setup"
104
105	; API defines
106	!define SM_CLEANBOOT 67
107
108	; Icons
109	!if $%BUILD_TARGET_ARCH% == "x86" ; 32-bit
110	!define MUI_ICON "$%VBOX_NSIS_ICON_FILE%"
111	!define MUI_UNICON "$%VBOX_NSIS_ICON_FILE%"
112	!else ; 64-bit
113	!define MUI_ICON "$%VBOX_WINDOWS_ADDITIONS_ICON_FILE%"
114	!define MUI_UNICON "$%VBOX_WINDOWS_ADDITIONS_ICON_FILE%"
115	!endif
116
117	; Welcome page
118	!insertmacro MUI_PAGE_WELCOME
119	!ifdef VBOX_WITH_LICENSE_DISPLAY
120	; License page
121	!insertmacro MUI_PAGE_LICENSE "$(VBOX_LICENSE)"
122	!define MUI_LICENSEPAGE_RADIOBUTTONS
123	!endif
124	; Directory page
125	!insertmacro MUI_PAGE_DIRECTORY
126	; Components Page
127	!insertmacro MUI_PAGE_COMPONENTS
128	; Instfiles page
129	!insertmacro MUI_PAGE_INSTFILES
130
131	!ifndef _DEBUG
132	!define MUI_FINISHPAGE_TITLE_3LINES ; Have a bit more vertical space for text
133	!insertmacro MUI_PAGE_FINISH ; Only show in release mode - useful information for debugging!
134	!endif
135
136	; Uninstaller pages
137	!insertmacro MUI_UNPAGE_INSTFILES
138
139	; Define languages we will use
140	!insertmacro MUI_LANGUAGE "English"
141	!insertmacro MUI_LANGUAGE "French"
142	!insertmacro MUI_LANGUAGE "German"
143
144	; Set branding text which appears on the horizontal line at the bottom
145	!ifdef _DEBUG
146	BrandingText "VirtualBox Windows Additions $%VBOX_VERSION_STRING% (r$%VBOX_SVN_REV%) - Debug Build"
147	!else
148	BrandingText "VirtualBox Windows Additions $%VBOX_VERSION_STRING% r$%VBOX_SVN_REV%"
149	!endif
150
151	!ifdef VBOX_WITH_LICENSE_DISPLAY
152	; Set license language
153	LicenseLangString VBOX_LICENSE ${LANG_ENGLISH} "$%VBOX_BRAND_LICENSE_RTF%"
154
155	; If license files not available (OSE / PUEL) build, then use the English one as default
156	!ifdef VBOX_BRAND_fr_FR_LICENSE_RTF
157	LicenseLangString VBOX_LICENSE ${LANG_FRENCH} "$%VBOX_BRAND_fr_FR_LICENSE_RTF%"
158	!else
159	LicenseLangString VBOX_LICENSE ${LANG_FRENCH} "$%VBOX_BRAND_LICENSE_RTF%"
160	!endif
161	!ifdef VBOX_BRAND_de_DE_LICENSE_RTF
162	LicenseLangString VBOX_LICENSE ${LANG_GERMAN} "$%VBOX_BRAND_de_DE_LICENSE_RTF%"
163	!else
164	LicenseLangString VBOX_LICENSE ${LANG_GERMAN} "$%VBOX_BRAND_LICENSE_RTF%"
165	!endif
166	!endif
167
168	!insertmacro MUI_RESERVEFILE_LANGDLL
169	!else ; !USE_MUI
170	XPStyle on
171	!ifdef VBOX_WITH_LICENSE_DISPLAY
172	Page license
173	!endif
174	Page components
175	Page directory
176	Page instfiles
177	!endif
178
179	; Language files
180	!include "Languages\English.nsh"
181	!include "Languages\French.nsh"
182	!include "Languages\German.nsh"
183
184	; Variables and output files
185	Name "${PRODUCT_NAME} $%VBOX_VERSION_STRING%"
186	!ifdef UNINSTALLER_ONLY
187	!echo "Uninstaller only!"
188	OutFile "$%PATH_TARGET%\VBoxWindowsAdditions-$%BUILD_TARGET_ARCH%-uninst.exe"
189	!else
190	OutFile "VBoxWindowsAdditions-$%BUILD_TARGET_ARCH%.exe"
191	!endif ; UNINSTALLER_ONLY
192
193	; Define default installation directory
194	!if $%BUILD_TARGET_ARCH% == "x86" ; 32-bit
195	InstallDir "$PROGRAMFILES32\$%VBOX_VENDOR_SHORT%\VirtualBox Guest Additions"
196	!else ; 64-bit
197	InstallDir "$PROGRAMFILES64\$%VBOX_VENDOR_SHORT%\VirtualBox Guest Additions"
198	!endif
199
200	InstallDirRegKey HKLM "${PRODUCT_DIR_REGKEY}" ""
201	ShowInstDetails show
202	ShowUnInstDetails show
203	RequestExecutionLevel highest
204
205	; Internal parameters
206	Var g_iSystemMode ; Current system mode (0 = Normal boot, 1 = Fail-safe boot, 2 = Fail-safe with network boot)
207	Var g_strSystemDir ; Windows system directory
208	Var g_strSysWow64 ; The SysWow64 directory on 64-bit systems
209	Var g_strCurUser ; Current user using the system
210	Var g_strAddVerMaj ; Installed Guest Additions: Major version
211	Var g_strAddVerMin ; Installed Guest Additions: Minor version
212	Var g_strAddVerBuild ; Installed Guest Additions: Build number
213	Var g_strAddVerRev ; Installed Guest Additions: SVN revision
214	Var g_strWinVersion ; Current Windows version we're running on
215	Var g_bLogEnable ; Do logging when installing? "true" or "false"
216	Var g_bWithWDDM ; Install the WDDM graphics driver instead of the XPDM one
217	Var g_bCapDllCache ; Capability: Does the (Windows) guest have have a DLL cache which needs to be taken care of?
218	Var g_bCapWDDM ; Capability: Is the guest able to handle/use our WDDM driver?
219
220	; Command line parameters - these can be set/modified
221	; on the command line
222	Var g_bFakeWHQL ; Cmd line: Fake Windows to install non WHQL certificated drivers (only for W2K and XP currently!!) ("/unsig_drv")
223	Var g_bForceInstall ; Cmd line: Force installation on unknown Windows OS version
224	Var g_bUninstall ; Cmd line: Just uninstall any previous Guest Additions and exit
225	Var g_bRebootOnExit ; Cmd line: Auto-Reboot on successful installation. Good for unattended installations ("/reboot")
226	Var g_iScreenBpp ; Cmd line: Screen depth ("/depth=X")
227	Var g_iScreenX ; Cmd line: Screen resolution X ("/resx=X")
228	Var g_iScreenY ; Cmd line: Screen resolution Y ("/resy=Y")
229	Var g_iSfOrder ; Cmd line: Order of Shared Folders network provider (0=first, 1=second, ...)
230	Var g_bIgnoreUnknownOpts ; Cmd line: Ignore unknown options (don't display the help)
231	Var g_bNoVBoxServiceExit ; Cmd line: Do not quit VBoxService before updating - install on next reboot
232	Var g_bNoVBoxTrayExit ; Cmd line: Do not quit VBoxTray before updating - install on next reboot
233	Var g_bNoVideoDrv ; Cmd line: Do not install the VBoxVideo driver
234	Var g_bNoGuestDrv ; Cmd line: Do not install the VBoxGuest driver
235	Var g_bNoMouseDrv ; Cmd line: Do not install the VBoxMouse driver
236	Var g_bWithAutoLogon ; Cmd line: Install VBoxGINA / VBoxCredProv for auto logon support
237	Var g_bWithVBoxMMR ; Cmd line: Install VBoxMMR for media redirection support
238	Var g_bWithD3D ; Cmd line: Install Direct3D support
239	Var g_bOnlyExtract ; Cmd line: Only extract all files, do not install them. Only valid with param "/D" (target directory)
240	Var g_bPostInstallStatus ; Cmd line: Post the overall installation status to some external program (VBoxTray)
241
242	; Platform parts of this installer
243	!include "VBoxGuestAdditionsLog.nsh"
244	!include "VBoxGuestAdditionsExternal.nsh"
245	!include "VBoxGuestAdditionsCommon.nsh"
246	!if $%BUILD_TARGET_ARCH% == "x86" ; 32-bit only
247	!include "VBoxGuestAdditionsNT4.nsh"
248	!endif
249	!include "VBoxGuestAdditionsW2KXP.nsh"
250	!include "VBoxGuestAdditionsVista.nsh"
251	!include "VBoxGuestAdditionsUninstall.nsh" ; Product uninstallation
252	!include "VBoxGuestAdditionsUninstallOld.nsh" ; Uninstallation of deprecated versions which must be removed first
253
254	Function HandleCommandLine
255
256	Push $0 ; Command line (without process name)
257	Push $1 ; Number of parameters
258	Push $2 ; Current parameter index
259	Push $3 ; Current parameter pair (name=value)
260	Push $4 ; Current parameter name
261	Push $5 ; Current parameter value (if present)
262
263	StrCpy $1 "0" ; Init param counter
264	StrCpy $2 "1" ; Init current param counter
265
266	${GetParameters} $0 ; Extract command line
267	${If} $0 == "" ; If no parameters at all exit
268	Goto exit
269	${EndIf}
270
271	; Enable for debugging
272	;MessageBox MB_OK "CmdLine: $0"
273
274	${WordFind} $0 " " "#" $1 ; Get number of parameters in cmd line
275	${If} $0 == $1 ; If result matches the input then
276	StrCpy $1 "1" ; no delimiter was found. Correct to 1 word total
277	${EndIf}
278
279	${While} $2 <= $1 ; Loop through all params
280
281	${WordFind} $0 " " "+$2" $3 ; Get current name=value pair
282	${WordFind} $3 "=" "+1" $4 ; Get current param name
283	${WordFind} $3 "=" "+2" $5 ; Get current param value
284
285	${StrFilter} $4 "-" "" "" $4 ; Transfer param name to lowercase
286
287	; Enable for debugging
288	;MessageBox MB_OK "#$2 of #$1, param='$3', name=$4, val=$5"
289
290	${Switch} $4
291
292	${Case} '/d' ; NSIS: /D=<instdir> switch, skip
293	${Break}
294
295	${Case} '/depth'
296	${Case} 'depth'
297	StrCpy $g_iScreenBpp $5
298	${Break}
299
300	${Case} '/extract'
301	StrCpy $g_bOnlyExtract "true"
302	${Break}
303
304	${Case} '/force'
305	StrCpy $g_bForceInstall "true"
306	${Break}
307
308	${Case} '/help'
309	${Case} '/H'
310	${Case} '/h'
311	${Case} '/?'
312	Goto usage
313	${Break}
314
315	${Case} '/ignore_unknownopts' ; Not officially documented
316	StrCpy $g_bIgnoreUnknownOpts "true"
317	${Break}
318
319	${Case} '/l'
320	${Case} '/log'
321	${Case} '/logging'
322	StrCpy $g_bLogEnable "true"
323	${Break}
324
325	${Case} '/ncrc' ; NSIS: /NCRC switch, skip
326	${Break}
327
328	${Case} '/no_vboxservice_exit' ; Not officially documented
329	StrCpy $g_bNoVBoxServiceExit "true"
330	${Break}
331
332	${Case} '/no_vboxtray_exit' ; Not officially documented
333	StrCpy $g_bNoVBoxTrayExit "true"
334	${Break}
335
336	${Case} '/no_videodrv' ; Not officially documented
337	StrCpy $g_bNoVideoDrv "true"
338	${Break}
339
340	${Case} '/no_guestdrv' ; Not officially documented
341	StrCpy $g_bNoGuestDrv "true"
342	${Break}
343
344	${Case} '/no_mousedrv' ; Not officially documented
345	StrCpy $g_bNoMouseDrv "true"
346	${Break}
347
348	!if $%VBOX_WITH_GUEST_INSTALL_HELPER% == "1"
349	; This switch tells our installer that it
350	; - should not quit VBoxTray during the update, because ...
351	; - ... it should show the overall installation status
352	; using VBoxTray's balloon message feature (since VBox 4.0)
353	${Case} '/post_installstatus' ; Not officially documented
354	StrCpy $g_bNoVBoxTrayExit "true"
355	StrCpy $g_bPostInstallStatus "true"
356	${Break}
357	!endif
358
359	${Case} '/reboot'
360	StrCpy $g_bRebootOnExit "true"
361	${Break}
362
363	${Case} '/s' ; NSIS: /S switch, skip
364	${Break}
365
366	${Case} '/sforder'
367	${Case} 'sforder'
368	StrCpy $g_iSfOrder $5
369	${Break}
370
371	!ifdef WHQL_FAKE
372	${Case} '/unsig_drv'
373	StrCpy $g_bFakeWHQL "true"
374	${Break}
375	!endif
376
377	${Case} '/uninstall'
378	StrCpy $g_bUninstall "true"
379	${Break}
380
381	${Case} '/with_autologon'
382	StrCpy $g_bWithAutoLogon "true"
383	${Break}
384
385	!if $%VBOX_WITH_MMR% == "1"
386	${Case} '/with_vboxmmr'
387	StrCpy $g_bWithVBoxMMR "true"
388	${Break}
389	!endif
390
391	!if $%VBOX_WITH_CROGL% == "1"
392	${Case} '/with_d3d'
393	${Case} '/with_direct3d'
394	StrCpy $g_bWithD3D "true"
395	${Break}
396	!endif
397
398	!if $%VBOX_WITH_WDDM% == "1"
399	${Case} '/with_wddm'
400	StrCpy $g_bWithWDDM "true"
401	${Break}
402	!endif
403
404	${Case} '/xres'
405	${Case} 'xres'
406	StrCpy $g_iScreenX $5
407	${Break}
408
409	${Case} '/yres'
410	${Case} 'yres'
411	StrCpy $g_iScreenY $5
412	${Break}
413
414	${Default} ; Unknown parameter, print usage message
415	; Prevent popping up usage message on (yet) unknown parameters
416	; in silent mode, just skip
417	IfSilent +1 +2
418	${Break}
419	goto usage
420	${Break}
421
422	${EndSwitch}
423
424	next_param:
425
426	IntOp $2 $2 + 1
427
428	${EndWhile}
429	Goto exit
430
431	usage:
432
433	; If we were told to ignore unknown (invalid) options, just return to
434	; the parsing loop ...
435	${If} $g_bIgnoreUnknownOpts == "true"
436	Goto next_param
437	${EndIf}
438	MessageBox MB_OK "${PRODUCT_NAME} Installer$\r$\n$\r$\n \
439	Usage: VBoxWindowsAdditions-$%BUILD_TARGET_ARCH% [OPTIONS] [/l] [/S] [/D=<PATH>]$\r$\n$\r$\n \
440	Options:$\r$\n \
441	/depth=BPP$\tSets the guest's display color depth (bits per pixel)$\r$\n \
442	/extract$\t$\tOnly extract installation files$\r$\n \
443	/force$\t$\tForce installation on unknown/undetected Windows versions$\r$\n \
444	/uninstall$\t$\tJust uninstalls the Guest Additions and exits$\r$\n \
445	/with_autologon$\tInstalls auto-logon support$\r$\n \
446	/with_d3d$\tInstalls D3D support$\r$\n \
447	/with_vboxmmr$\tInstalls multimedia redirection (MMR) support$\r$\n \
448	/with_wddm$\tInstalls the WDDM instead of the XPDM graphics driver$\r$\n \
449	/xres=X$\t$\tSets the guest's display resolution (width in pixels)$\r$\n \
450	/yres=Y$\t$\tSets the guest's display resolution (height in pixels)$\r$\n \
451	$\r$\n \
452	Installer parameters:$\r$\n \
453	/l$\t$\tEnables logging$\r$\n \
454	/S$\t$\tSilent install$\r$\n \
455	/D=<PATH>$\tSets the default install path$\r$\n \
456	$\r$\n \
457	Note: Order of options and installer parameters are mandatory." /SD IDOK
458
459	; No stack restore needed, we're about to quit
460	Quit
461
462	done:
463
464	!ifdef _DEBUG
465	${LogVerbose} "Property: XRes: $g_iScreenX"
466	${LogVerbose} "Property: YRes: $g_iScreenY"
467	${LogVerbose} "Property: BPP: $g_iScreenBpp"
468	${LogVerbose} "Property: Logging enabled: $g_bLogEnable"
469	!endif
470
471	exit:
472
473	Pop $5
474	Pop $4
475	Pop $3
476	Pop $2
477	Pop $1
478	Pop $0
479
480	FunctionEnd
481
482	Function CheckForOldGuestAdditions
483
484	Push $0
485	Push $1
486	Push $2
487
488	begin:
489
490	${LogVerbose} "Checking for old Guest Additions ..."
491
492	sun_check:
493
494	; Check for old "Sun VirtualBox Guest Additions"
495	; - before rebranding to Oracle
496	ReadRegStr $0 HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Sun VirtualBox Guest Additions" "UninstallString"
497	StrCmp $0 "" sun_xvm_check ; If string is empty, Sun additions are probably not installed (anymore)
498
499	MessageBox MB_YESNO $(VBOX_SUN_FOUND) /SD IDYES IDYES sun_uninstall
500	Pop $2
501	Pop $1
502	Pop $0
503	MessageBox MB_ICONSTOP $(VBOX_SUN_ABORTED) /SD IDOK
504	Quit
505
506	sun_uninstall:
507
508	Call Uninstall_Sun
509	Goto success
510
511	sun_xvm_check:
512
513	; Check for old "Sun xVM VirtualBox Guest Additions"
514	; - before getting rid of the "xVM" namespace
515	ReadRegStr $0 HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Sun xVM VirtualBox Guest Additions" "UninstallString"
516	StrCmp $0 "" innotek_check ; If string is empty, Sun xVM additions are probably not installed (anymore)
517
518	MessageBox MB_YESNO $(VBOX_SUN_FOUND) /SD IDYES IDYES sun_xvm_uninstall
519	Pop $2
520	Pop $1
521	Pop $0
522	MessageBox MB_ICONSTOP $(VBOX_SUN_ABORTED) /SD IDOK
523	Quit
524
525	sun_xvm_uninstall:
526
527	Call Uninstall_SunXVM
528	Goto success
529
530	innotek_check:
531
532	; Check for old "innotek" Guest Additions" before rebranding to "Sun"
533	ReadRegStr $0 HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\innotek VirtualBox Guest Additions" "UninstallString"
534	StrCmp $0 "" exit ; If string is empty, innotek Guest Additions are probably not installed (anymore)
535
536	MessageBox MB_YESNO $(VBOX_INNOTEK_FOUND) /SD IDYES IDYES innotek_uninstall
537	Pop $2
538	Pop $1
539	Pop $0
540	MessageBox MB_ICONSTOP $(VBOX_INNOTEK_ABORTED) /SD IDOK
541	Quit
542
543	innotek_uninstall:
544
545	Call Uninstall_Innotek
546	Goto success
547
548	success:
549
550	; Nothing to do here yet
551
552	exit:
553
554	Pop $2
555	Pop $1
556	Pop $0
557
558	FunctionEnd
559
560	Function CheckForInstalledComponents
561
562	Push $0
563	Push $1
564
565	${LogVerbose} "Checking for installed components ..."
566	StrCpy $1 ""
567
568	Call SetAppMode64
569
570	; VBoxGINA already installed? So we need to update the installed version as well,
571	; regardless whether the user used "/with_autologon" or not
572	ReadRegStr $0 HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\WinLogon" "GinaDLL"
573	${If} $0 == "VBoxGINA.dll"
574	StrCpy $1 "GINA"
575	${Else}
576	ReadRegStr $0 HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Authentication\Credential Providers\{275D3BCC-22BB-4948-A7F6-3A3054EBA92B}" ""
577	${If} $0 == "VBoxCredProv"
578	StrCpy $1 "Credential Provider"
579	${EndIf}
580	${EndIf}
581
582	!ifdef _DEBUG
583	${LogVerbose} "Auto-logon module: $0"
584	!endif
585
586	${IfNot} $1 == ""
587	${LogVerbose} "Auto-logon support ($1) was installed previously"
588	StrCpy $g_bWithAutoLogon "true" ; Force update
589	${Else}
590	${LogVerbose} "Auto-logon support was not installed previously"
591	${EndIf}
592
593	; Check for installed MMR support and enable updating
594	; those modules if needed
595	${If} ${FileExists} "$g_strSystemDir\VBoxMMR.exe"
596	!if $%BUILD_TARGET_ARCH% == "amd64"
597	${AndIf} ${FileExists} "$g_strSysWow64\VBoxMMRHook.dll"
598	!else
599	${AndIf} ${FileExists} "$g_strSystemDir\VBoxMMRHook.dll"
600	!endif
601	${LogVerbose} "MultiMedia Redirection support (MMR) was installed previously"
602	StrCpy $g_bWithVBoxMMR "true" ; Force update
603	${Else}
604	${LogVerbose} "MultiMedia Redirection support (MMR) support was not installed previously"
605	${EndIf}
606
607	Pop $1
608	Pop $0
609
610	FunctionEnd
611
612	; Main Files
613	Section $(VBOX_COMPONENT_MAIN) SEC01
614
615	SectionIn RO ; Section cannot be unselected (read-only)
616	${If} $g_bPostInstallStatus == "true"
617	${LogToVBoxTray} "0" "${PRODUCT_NAME} update started, please wait ..."
618	${EndIf}
619
620	IfSilent +1 +2
621	StrCpy $g_bLogEnable "true" ; Force logging in silent mode
622
623	${LogEnable} "$g_bLogEnable"
624	IfSilent +1 +2 ; NSIS will expand ${LogVerbose} before doing relative jumps!
625	LogText "Installer runs in silent mode"
626
627	SetOutPath "$INSTDIR"
628	SetOverwrite on
629
630	Call SetAppMode64
631
632	StrCpy $g_strSystemDir "$SYSDIR"
633
634	${LogVerbose} "Version: $%VBOX_VERSION_STRING% (Rev $%VBOX_SVN_REV%)"
635	${If} $g_strAddVerMaj != ""
636	${LogVerbose} "Previous version: $g_strAddVerMaj.$g_strAddVerMin.$g_strAddVerBuild (Rev $g_strAddVerRev)"
637	${Else}
638	${LogVerbose} "No previous version of ${PRODUCT_NAME} detected"
639	${EndIf}
640	!if $%BUILD_TARGET_ARCH% == "amd64"
641	${LogVerbose} "Detected OS: Windows $g_strWinVersion (64-bit)"
642	!else
643	${LogVerbose} "Detected OS: Windows $g_strWinVersion (32-bit)"
644	!endif
645	${LogVerbose} "System Directory: $g_strSystemDir"
646
647	!ifdef _DEBUG
648	${LogVerbose} "Installer runs in debug mode"
649	!endif
650
651	;
652	; Here starts the main dispatcher (based on guest OS)
653	;
654
655	; Which OS are we using?
656	; @todo Use logic lib here
657	!if $%BUILD_TARGET_ARCH% == "x86" ; 32-bit
658	StrCmp $g_strWinVersion "NT4" nt4 ; Windows NT 4.0
659	!endif
660	StrCmp $g_strWinVersion "2000" w2k ; Windows 2000
661	StrCmp $g_strWinVersion "XP" w2k ; Windows XP
662	StrCmp $g_strWinVersion "2003" w2k ; Windows 2003 Server
663	StrCmp $g_strWinVersion "Vista" vista ; Windows Vista
664	StrCmp $g_strWinVersion "7" vista ; Windows 7
665	StrCmp $g_strWinVersion "8" vista ; Windows 8
666	StrCmp $g_strWinVersion "8_1" vista ; Windows 8.1 / Windows 2012 Server R2
667	StrCmp $g_strWinVersion "10" vista ; Windows 10
668
669	${If} $g_bForceInstall == "true"
670	Goto vista ; Assume newer OS than we know of ...
671	${EndIf}
672
673	Goto notsupported
674
675	!if $%BUILD_TARGET_ARCH% == "x86" ; 32-bit
676	nt4: ; Windows NT4
677
678	Call GetServicePack
679	Pop $R0 ; Major version
680	Pop $R1 ; Minor version
681
682	; At least Service Pack 6 installed?
683	${If} $R0 <> "6"
684	MessageBox MB_YESNO $(VBOX_NT4_NO_SP6) /SD IDYES IDYES +2
685	Quit
686	${EndIf}
687
688	; Copy some common files ...
689	Call Common_CopyFiles
690
691	Call NT4_Main
692	goto success
693	!endif
694
695	w2k: ; Windows 2000 and XP ...
696
697	; Copy some common files ...
698	Call Common_CopyFiles
699
700	Call W2K_Main
701	goto success
702
703	vista: ; Windows Vista / Windows 7 / Windows 8(.1)
704
705	; Check requirments; this function can abort the installation if necessary!
706	Call Vista_CheckForRequirements
707
708	; Copy some common files ...
709	Call Common_CopyFiles
710
711	Call W2K_Main ; First install stuff from Windows 2000 / XP
712	Call Vista_Main ; ... and some specific stuff for Vista / Windows 7
713	goto success
714
715	notsupported:
716
717	MessageBox MB_ICONSTOP $(VBOX_PLATFORM_UNSUPPORTED) /SD IDOK
718	goto exit
719
720	success:
721
722	; Write a registry key with version and installation path for later lookup
723	WriteRegStr HKLM "${PRODUCT_INSTALL_KEY}" "Version" "$%VBOX_VERSION_STRING_RAW%"
724	WriteRegStr HKLM "${PRODUCT_INSTALL_KEY}" "VersionExt" "$%VBOX_VERSION_STRING%"
725	WriteRegStr HKLM "${PRODUCT_INSTALL_KEY}" "Revision" "$%VBOX_SVN_REV%"
726	WriteRegStr HKLM "${PRODUCT_INSTALL_KEY}" "InstallDir" "$INSTDIR"
727
728	; Set the reboot flag to tell the finish page that is should
729	; default to the "reboot now" entry
730	SetRebootFlag true
731
732	exit:
733
734	SectionEnd
735
736	; Auto-logon support (section is hidden at the moment -- only can be enabled via command line switch)
737	Section /o -$(VBOX_COMPONENT_AUTOLOGON) SEC02
738
739	Call SetAppMode64
740
741	Call GetWindowsVersion
742	Pop $R0 ; Windows Version
743
744	${LogVerbose} "Installing auto-logon support ..."
745
746	; Another GINA already is installed? Check if this is ours, otherwise let the user decide (unless it's a silent setup)
747	; whether to replace it with the VirtualBox one or not
748	ReadRegStr $0 HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\WinLogon" "GinaDLL"
749	${If} $0 != ""
750	${If} $0 != "VBoxGINA.dll"
751	${LogVerbose} "Found another already installed GINA module: $0"
752	MessageBox MB_ICONQUESTION\|MB_YESNO\|MB_DEFBUTTON1 $(VBOX_COMPONENT_AUTOLOGON_WARN_3RDPARTY) /SD IDYES IDYES install
753	${LogVerbose} "Skipping GINA installation, keeping: $0"
754	goto skip
755	${EndIf}
756	${EndIf}
757
758	install:
759
760	; Do we need VBoxCredProv or VBoxGINA?
761	${If} $R0 == 'Vista' ; Windows Vista.
762	${OrIf} $R0 == '7' ; Windows 7.
763	${OrIf} $R0 == '8' ; Windows 8.
764	${OrIf} $R0 == '8_1' ; Windows 8.1 / Windows Server 2012 R2.
765	${OrIf} $R0 == '10' ; Windows 10.
766	; Use VBoxCredProv on Vista and up.
767	${LogVerbose} "Installing VirtualBox credential provider ..."
768	!insertmacro ReplaceDLL "$%PATH_OUT%\bin\additions\VBoxCredProv.dll" "$g_strSystemDir\VBoxCredProv.dll" "$INSTDIR"
769	WriteRegStr HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Authentication\Credential Providers\{275D3BCC-22BB-4948-A7F6-3A3054EBA92B}" "" "VBoxCredProv" ; adding to (default) key
770	WriteRegStr HKCR "CLSID\{275D3BCC-22BB-4948-A7F6-3A3054EBA92B}" "" "VBoxCredProv" ; adding to (Default) key
771	WriteRegStr HKCR "CLSID\{275D3BCC-22BB-4948-A7F6-3A3054EBA92B}\InprocServer32" "" "VBoxCredProv.dll" ; adding to (Default) key
772	WriteRegStr HKCR "CLSID\{275D3BCC-22BB-4948-A7F6-3A3054EBA92B}\InprocServer32" "ThreadingModel" "Apartment"
773	${Else} ; Use VBoxGINA on older Windows OSes (< Vista)
774	${LogVerbose} "Installing VirtualBox GINA ..."
775	!insertmacro ReplaceDLL "$%PATH_OUT%\bin\additions\VBoxGINA.dll" "$g_strSystemDir\VBoxGINA.dll" "$INSTDIR"
776	WriteRegStr HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\WinLogon" "GinaDLL" "VBoxGINA.dll"
777	; Add Windows notification package callbacks for VBoxGINA
778	WriteRegStr HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\WinLogon\Notify\VBoxGINA" "DLLName" "VBoxGINA.dll"
779	WriteRegDWORD HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\WinLogon\Notify\VBoxGINA" "Impersonate" 0
780	WriteRegStr HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\WinLogon\Notify\VBoxGINA" "StopScreenSaver" "WnpScreenSaverStop"
781	${EndIf}
782
783	skip:
784
785	; Nothing to do here right now
786
787	exit:
788
789	SectionEnd
790
791	; Direct3D support
792	Section /o $(VBOX_COMPONENT_D3D) SEC03
793
794	!if $%VBOX_WITH_WDDM% == "1"
795	${If} $g_bWithWDDM == "true"
796	${LogVerbose} "Installing WDDM Direct3D support ..."
797
798	; Do we need to restore the original d3d8.dll/d3d9.dll files because the guest
799	; installation was upgraded from XPDM to WDDM driver? In a XPDM installation
800	; those DLLs were replaced by our own stub files.
801	Call RestoreFilesDirect3D
802	Return
803	${EndIf}
804	!endif
805
806	Call SetAppMode64
807	SetOverwrite on
808
809	${If} $g_strSystemDir == ''
810	StrCpy $g_strSystemDir "$SYSDIR"
811	${EndIf}
812
813	SetOutPath $g_strSystemDir
814	${LogVerbose} "Installing XPDM Direct3D support ..."
815	FILE "$%PATH_OUT%\bin\additions\VBoxD3D8.dll"
816	FILE "$%PATH_OUT%\bin\additions\VBoxD3D9.dll"
817	FILE "$%PATH_OUT%\bin\additions\wined3d.dll"
818
819	;
820	; Update DLL cache
821	;
822	${If} $g_bCapDllCache == "true"
823	${If} ${FileExists} "$g_strSystemDir\dllcache"
824	SetOutPath "$g_strSystemDir\dllcache"
825	${CopyFileEx} "" "$g_strSystemDir\dllcache\d3d8.dll" "$g_strSystemDir\dllcache\msd3d8.dll" "Microsoft Corporation" "$%BUILD_TARGET_ARCH%"
826	${CopyFileEx} "" "$g_strSystemDir\dllcache\d3d9.dll" "$g_strSystemDir\dllcache\msd3d9.dll" "Microsoft Corporation" "$%BUILD_TARGET_ARCH%"
827
828	; Exchange DLLs
829	${PrepareWRPFileEx} "" "$g_strSystemDir\dllcache\d3d8.dll"
830	${InstallFileEx} "" "$%PATH_OUT%\bin\additions\d3d8.dll" "$g_strSystemDir\dllcache\d3d8.dll" "$TEMP"
831	${PrepareWRPFileEx} "" "$g_strSystemDir\dllcache\d3d9.dll"
832	${InstallFileEx} "" "$%PATH_OUT%\bin\additions\d3d9.dll" "$g_strSystemDir\dllcache\d3d9.dll" "$TEMP"
833	${Else}
834	${LogVerbose} "DLL cache does not exist, skipping"
835	${EndIf}
836	${EndIf}
837
838	;
839	; Save original DLLs (only if msd3d*.dll does not exist) ...
840	;
841	SetOutPath $g_strSystemDir
842	${CopyFileEx} "" "$g_strSystemDir\d3d8.dll" "$g_strSystemDir\msd3d8.dll" "Microsoft Corporation" "$%BUILD_TARGET_ARCH%"
843	${CopyFileEx} "" "$g_strSystemDir\d3d9.dll" "$g_strSystemDir\msd3d9.dll" "Microsoft Corporation" "$%BUILD_TARGET_ARCH%"
844
845	; Exchange DLLs
846	${PrepareWRPFileEx} "" "$g_strSystemDir\d3d8.dll"
847	${InstallFileEx} "" "$%PATH_OUT%\bin\additions\d3d8.dll" "$g_strSystemDir\d3d8.dll" "$TEMP"
848	${PrepareWRPFileEx} "" "$g_strSystemDir\d3d9.dll"
849	${InstallFileEx} "" "$%PATH_OUT%\bin\additions\d3d9.dll" "$g_strSystemDir\d3d9.dll" "$TEMP"
850
851	!if $%BUILD_TARGET_ARCH% == "amd64"
852	; Only 64-bit installer:
853	; Also copy 32-bit DLLs on 64-bit Windows in SysWOW64 node
854	SetOutPath $g_strSysWow64
855	${LogVerbose} "Installing Direct3D support for 32-bit applications (SysWOW64: $g_strSysWow64) ..."
856	FILE "$%VBOX_PATH_ADDITIONS_WIN_X86%\VBoxD3D8.dll"
857	FILE "$%VBOX_PATH_ADDITIONS_WIN_X86%\VBoxD3D9.dll"
858	FILE "$%VBOX_PATH_ADDITIONS_WIN_X86%\wined3d.dll"
859
860	;
861	; Update DLL cache
862	;
863	${If} $g_bCapDllCache == "true"
864	${If} ${FileExists} "$g_strSysWow64\dllcache"
865	SetOutPath "$g_strSysWow64\dllcache"
866	${CopyFileEx} "" "$g_strSysWow64\dllcache\d3d8.dll" "$g_strSysWow64\dllcache\msd3d8.dll" "Microsoft Corporation" "x86"
867	${CopyFileEx} "" "$g_strSysWow64\dllcache\d3d9.dll" "$g_strSysWow64\dllcache\msd3d9.dll" "Microsoft Corporation" "x86"
868
869	; Exchange DLLs
870	${PrepareWRPFileEx} "" "$g_strSysWow64\dllcache\d3d8.dll"
871	${InstallFileEx} "" "$%VBOX_PATH_ADDITIONS_WIN_X86%\d3d8.dll" "$g_strSysWow64\dllcache\d3d8.dll" "$TEMP"
872	${PrepareWRPFileEx} "" "$g_strSysWow64\dllcache\d3d9.dll"
873	${InstallFileEx} "" "$%VBOX_PATH_ADDITIONS_WIN_X86%\d3d9.dll" "$g_strSysWow64\dllcache\d3d9.dll" "$TEMP"
874	${Else}
875	${LogVerbose} "DLL cache does not exist, skipping"
876	${EndIf}
877	${EndIf}
878
879	;
880	; Update original DLLs
881	;
882
883	; Save original DLLs (only if msd3d*.dll does not exist) ...
884	${CopyFileEx} "" "$g_strSysWow64\d3d8.dll" "$g_strSysWow64\msd3d8.dll" "Microsoft Corporation" "x86"
885	${CopyFileEx} "" "$g_strSysWow64\d3d9.dll" "$g_strSysWow64\msd3d9.dll" "Microsoft Corporation" "x86"
886
887	${PrepareWRPFileEx} "" "$g_strSysWow64\d3d8.dll"
888	${InstallFileEx} "" "$%VBOX_PATH_ADDITIONS_WIN_X86%\d3d8.dll" "$g_strSysWow64\d3d8.dll" "$TEMP"
889	${PrepareWRPFileEx} "" "$g_strSysWow64\d3d9.dll"
890	${InstallFileEx} "" "$%VBOX_PATH_ADDITIONS_WIN_X86%\d3d9.dll" "$g_strSysWow64\d3d9.dll" "$TEMP"
891
892	!endif ; amd64
893	Goto done
894
895	error:
896	; @todo
897	Goto exit
898
899	done:
900
901	!ifndef WFP_FILE_EXCEPTION
902	MessageBox MB_ICONINFORMATION\|MB_OK $(VBOX_WFP_WARN_REPLACE) /SD IDOK
903	!endif
904	Goto exit
905
906	exit:
907
908	SectionEnd
909
910	!ifdef USE_MUI
911	;Assign language strings to sections
912	!insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
913	!insertmacro MUI_DESCRIPTION_TEXT ${SEC01} $(VBOX_COMPONENT_MAIN_DESC)
914	!insertmacro MUI_DESCRIPTION_TEXT ${SEC02} $(VBOX_COMPONENT_AUTOLOGON_DESC)
915	!if $%VBOX_WITH_CROGL% == "1"
916	!insertmacro MUI_DESCRIPTION_TEXT ${SEC03} $(VBOX_COMPONENT_D3D_DESC)
917	!endif
918	!insertmacro MUI_FUNCTION_DESCRIPTION_END
919	!endif ; USE_MUI
920
921	Section -Content
922
923	WriteIniStr "$INSTDIR\${PRODUCT_NAME}.url" "InternetShortcut" "URL" "${PRODUCT_WEB_SITE}"
924
925	SectionEnd
926
927	Section -StartMenu
928
929	CreateDirectory "$SMPROGRAMS\${PRODUCT_NAME}"
930	CreateShortCut "$SMPROGRAMS\${PRODUCT_NAME}\Website.lnk" "$INSTDIR\${PRODUCT_NAME}.url" "" "$INSTDIR\iexplore.ico"
931	CreateShortCut "$SMPROGRAMS\${PRODUCT_NAME}\Uninstall.lnk" "$INSTDIR\uninst.exe"
932
933	SectionEnd
934
935	; This section is called after all the files are in place
936	Section -Post
937
938	!ifdef _DEBUG
939	${LogVerbose} "Doing post install ..."
940	!endif
941
942	!ifdef EXTERNAL_UNINSTALLER
943	SetOutPath "$INSTDIR"
944	FILE "$%PATH_TARGET%\uninst.exe"
945	!else
946	WriteUninstaller "$INSTDIR\uninst.exe"
947	!endif
948
949	; Write uninstaller in "Add / Remove programs"
950	WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayName" "$(^Name)"
951	WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "UninstallString" "$INSTDIR\uninst.exe"
952	WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayVersion" "${PRODUCT_VERSION}"
953	WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "URLInfoAbout" "${PRODUCT_WEB_SITE}"
954	WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "Publisher" "${PRODUCT_PUBLISHER}"
955
956	; Tune TcpWindowSize for a better network throughput
957	WriteRegDWORD HKLM "SYSTEM\CurrentControlSet\Services\Tcpip\Parameters" "TcpWindowSize" 64240
958
959	; Add Sun Ray client info keys
960	; Note: We only need 32-bit keys (HKLM\Software / HKLM\Software\Wow6432Node)
961	!if $%BUILD_TARGET_ARCH% == "amd64"
962	WriteRegStr HKLM "SOFTWARE\Wow6432Node\Oracle\Sun Ray\ClientInfoAgent\ReconnectActions" "" ""
963	WriteRegStr HKLM "SOFTWARE\Wow6432Node\Oracle\Sun Ray\ClientInfoAgent\DisconnectActions" "" ""
964	!else
965	WriteRegStr HKLM "SOFTWARE\Oracle\Sun Ray\ClientInfoAgent\ReconnectActions" "" ""
966	WriteRegStr HKLM "SOFTWARE\Oracle\Sun Ray\ClientInfoAgent\DisconnectActions" "" ""
967	!endif
968
969	${LogVerbose} "Installation completed."
970
971	SectionEnd
972
973	; !!! NOTE: This function has to be right under the last section; otherwise it does
974	; not get called! Don't ask me why ... !!!
975	Function .onSelChange
976
977	Push $0
978
979	; Handle selection of D3D component
980	SectionGetFlags ${SEC03} $0
981	${If} $0 == ${SF_SELECTED}
982
983	StrCpy $g_bWithD3D "true"
984
985	!if $%VBOX_WITH_WDDM% == "1"
986	; If we're able to use the WDDM driver just use it instead of the replaced
987	; D3D components below
988	${If} $g_bCapWDDM == "true"
989	;
990	; Temporary solution: Since WDDM is marked as experimental yet we notify the user
991	; that WDDM (Aero) support is available but not recommended for production use. He now
992	; can opt-in for installing WDDM or still go for the old (XPDM) way -- safe mode still required!
993	;
994	MessageBox MB_ICONQUESTION\|MB_YESNO $(VBOX_COMPONENT_D3D_OR_WDDM) /SD IDNO IDYES d3d_install
995	; Display an unconditional hint about needed VRAM sizes
996	; Note: We also could use the PCI configuration space (WMI: Win32_SystemSlot Class) for querying
997	; the current VRAM size, but let's keep it simple for now
998	MessageBox MB_ICONINFORMATION\|MB_OK $(VBOX_COMPONENT_D3D_HINT_VRAM) /SD IDOK
999	StrCpy $g_bWithWDDM "true"
1000	Goto exit
1001	${EndIf}
1002
1003	d3d_install:
1004
1005	!endif ; $%VBOX_WITH_WDDM% == "1"
1006
1007	${If} $g_bForceInstall != "true"
1008	; Do not install on < XP
1009	${If} $g_strWinVersion == "NT4"
1010	${OrIf} $g_strWinVersion == "2000"
1011	${OrIf} $g_strWinVersion == ""
1012	MessageBox MB_ICONINFORMATION\|MB_OK $(VBOX_COMPONENT_D3D_NOT_SUPPORTED) /SD IDOK
1013	Goto d3d_disable
1014	${EndIf}
1015	${EndIf}
1016
1017	; If force flag is set skip the safe mode check
1018	${If} $g_bForceInstall != "true"
1019	; If we're not in safe mode, print a warning and don't install D3D support
1020	${If} $g_iSystemMode == '0'
1021	MessageBox MB_ICONINFORMATION\|MB_OK $(VBOX_COMPONENT_D3D_NO_SM) /SD IDOK
1022	Goto d3d_disable
1023	${EndIf}
1024	${EndIf}
1025
1026	${Else} ; D3D unselected again
1027
1028	${If} $g_strWinVersion != "8" ; On Windows 8 WDDM is mandatory
1029	${AndIf} $g_strWinVersion != "8_1" ; ... also on Windows 8.1 / Windows 2012 Server R2
1030	${AndIf} $g_strWinVersion != "10" ; ... also on Windows 10
1031	StrCpy $g_bWithWDDM "false"
1032	${EndIf}
1033
1034	${EndIf}
1035	Goto exit
1036
1037	d3d_disable:
1038
1039	StrCpy $g_bWithD3D "false"
1040	IntOp $0 $0 & ${SECTION_OFF} ; Unselect section again
1041	SectionSetFlags ${SEC03} $0
1042	Goto exit
1043
1044	exit:
1045
1046	Pop $0
1047
1048	FunctionEnd
1049
1050	; This function is called when a critical error occurred, caused by
1051	; the Abort command
1052	Function .onInstFailed
1053
1054	${LogVerbose} "$(VBOX_ERROR_INST_FAILED)"
1055	MessageBox MB_ICONSTOP $(VBOX_ERROR_INST_FAILED) /SD IDOK
1056
1057	${If} $g_bPostInstallStatus == "true"
1058	${LogToVBoxTray} "2" "Error while installing ${PRODUCT_NAME}!"
1059	${EndIf}
1060
1061	; Set overall exit code
1062	SetErrorLevel 1
1063
1064	FunctionEnd
1065
1066	; This function is called when installation was successful!
1067	Function .onInstSuccess
1068
1069	${LogVerbose} "${PRODUCT_NAME} successfully installed"
1070
1071	${If} $g_bPostInstallStatus == "true"
1072	${LogToVBoxTray} "0" "${PRODUCT_NAME} successfully updated!"
1073	${EndIf}
1074
1075	SetErrorLevel 0
1076
1077	FunctionEnd
1078
1079	; This function is called at the very beginning of installer execution
1080	Function .onInit
1081
1082	Push $0
1083
1084	; Init values
1085	StrCpy $g_iSystemMode "0"
1086	StrCpy $g_strCurUser "<None>"
1087	StrCpy $g_strAddVerMaj "0"
1088	StrCpy $g_strAddVerMin "0"
1089	StrCpy $g_strAddVerBuild "0"
1090	StrCpy $g_strAddVerRev "0"
1091
1092	StrCpy $g_bIgnoreUnknownOpts "false"
1093	StrCpy $g_bLogEnable "false"
1094	StrCpy $g_bFakeWHQL "false"
1095	StrCpy $g_bForceInstall "false"
1096	StrCpy $g_bUninstall "false"
1097	StrCpy $g_bRebootOnExit "false"
1098	StrCpy $g_iScreenX "0"
1099	StrCpy $g_iScreenY "0"
1100	StrCpy $g_iScreenBpp "0"
1101	StrCpy $g_iSfOrder "0"
1102	StrCpy $g_bNoVBoxServiceExit "false"
1103	StrCpy $g_bNoVBoxTrayExit "false"
1104	StrCpy $g_bNoVideoDrv "false"
1105	StrCpy $g_bNoGuestDrv "false"
1106	StrCpy $g_bNoMouseDrv "false"
1107	StrCpy $g_bWithAutoLogon "false"
1108	StrCpy $g_bWithVBoxMMR "false"
1109	StrCpy $g_bWithD3D "false"
1110	StrCpy $g_bOnlyExtract "false"
1111	StrCpy $g_bWithWDDM "false"
1112	StrCpy $g_bCapDllCache "false"
1113	StrCpy $g_bCapWDDM "false"
1114	StrCpy $g_bPostInstallStatus "false"
1115
1116	; We need a special directory set to SysWOW64 because some
1117	; shell operations don't support file redirection (yet)
1118	StrCpy $g_strSysWow64 "$WINDIR\SysWOW64"
1119
1120	SetErrorLevel 0
1121	ClearErrors
1122
1123	!ifdef UNINSTALLER_ONLY
1124
1125	;
1126	; If UNINSTALLER_ONLY is defined, we're only interested in uninst.exe
1127	; so we can sign it
1128	;
1129	; Note that the Quit causes the exit status to be 2 instead of 0
1130	;
1131	WriteUninstaller "$%PATH_TARGET%\uninst.exe"
1132	Quit
1133
1134	!else
1135
1136	; Handle command line
1137	Call HandleCommandLine
1138
1139	; Check if there's already another instance of the installer is running -
1140	; important for preventing NT4 to spawn the installer twice
1141	System::Call 'kernel32::CreateMutexA(i 0, i 0, t "VBoxGuestInstaller") ?e'
1142	Pop $0
1143	${If} $0 != 0
1144	Quit
1145	${EndIf}
1146
1147	; Retrieve Windows version and store result in $g_strWinVersion
1148	Call GetWindowsVersionEx
1149	Pop $g_strWinVersion
1150
1151	; Retrieve capabilities
1152	Call CheckForCapabilities
1153
1154	; Get user Name
1155	AccessControl::GetCurrentUserName
1156	Pop $g_strCurUser
1157	${LogVerbose} "Current user: $g_strCurUser"
1158
1159	; Only extract files? This action can be called even from non-Admin users
1160	; and non-compatible architectures
1161	${If} $g_bOnlyExtract == "true"
1162	Call ExtractFiles
1163	MessageBox MB_OK\|MB_ICONINFORMATION $(VBOX_EXTRACTION_COMPLETE) /SD IDOK
1164	Quit
1165	${EndIf}
1166
1167	; Check for correct architecture
1168	Call CheckArchitecture
1169	Pop $0
1170	${If} $0 <> 0 ; Wrong architecture? Tell the world
1171	!if $%BUILD_TARGET_ARCH% == "amd64"
1172	MessageBox MB_ICONSTOP $(VBOX_NOTICE_ARCH_AMD64) /SD IDOK
1173	!else
1174	MessageBox MB_ICONSTOP $(VBOX_NOTICE_ARCH_X86) /SD IDOK
1175	!endif
1176	Abort "$(VBOX_NOTICE_ARCH_AMD64)"
1177	${EndIf}
1178
1179	; Has the user who calls us admin rights?
1180	UserInfo::GetAccountType
1181	Pop $0
1182	${If} $0 != "Admin"
1183	MessageBox MB_ICONSTOP $(VBOX_NOADMIN) /SD IDOK
1184	Abort
1185	${EndIf}
1186
1187	; Only uninstall?
1188	${If} $g_bUninstall == "true"
1189	Call Uninstall_Innotek
1190	Call Uninstall
1191	MessageBox MB_ICONINFORMATION\|MB_OK $(VBOX_UNINST_SUCCESS) /SD IDOK
1192	Quit
1193	${EndIf}
1194
1195	Call CheckForInstalledComponents
1196
1197	; Set section bits
1198	${If} $g_bWithAutoLogon == "true" ; Auto-logon support
1199	!insertmacro SelectSection ${SEC02}
1200	${EndIf}
1201	!if $%VBOX_WITH_CROGL% == "1"
1202	${If} $g_bWithD3D == "true" ; D3D support
1203	!insertmacro SelectSection ${SEC03}
1204	${EndIf}
1205	!endif
1206	${If} $g_bWithWDDM == "true" ; D3D / WDDM support
1207	!insertmacro SelectSection ${SEC03}
1208	${EndIf}
1209	; On Windows 8 / 8.1 / Windows Server 2012 R2 and newer we always select the 3D
1210	; section and disable it so that it cannot be deselected again
1211	${If} $g_strWinVersion == "8"
1212	${OrIf} $g_strWinVersion == "8_1"
1213	${OrIf} $g_strWinVersion == "10"
1214	IntOp $0 ${SF_SELECTED} \| ${SF_RO}
1215	SectionSetFlags ${SEC03} $0
1216	${EndIf}
1217
1218	!ifdef USE_MUI
1219	; Display language selection dialog (will be hidden in silent mode!)
1220	!ifdef VBOX_INSTALLER_ADD_LANGUAGES
1221	!insertmacro MUI_LANGDLL_DISPLAY
1222	!endif
1223	!endif
1224
1225	Call SetAppMode64
1226
1227	; Check for old additions
1228	Call CheckForOldGuestAdditions
1229	Call GetAdditionsVersion
1230
1231	; Due to some bug in NSIS the license page won't be displayed if we're in
1232	; 64-bit registry view, so as a workaround switch back to 32-bit (Wow6432Node)
1233	; mode for now
1234	Call SetAppMode32
1235
1236	!endif ; UNINSTALLER_ONLY
1237
1238	Pop $0
1239
1240	FunctionEnd
1241
1242	;
1243	; The uninstaller is built separately when doing code signing
1244	; For some reason NSIS still finds the Uninstall section even
1245	; when EXTERNAL_UNINSTALLER is defined. This causes a silly warning
1246	;
1247	!ifndef EXTERNAL_UNINSTALLER
1248
1249	Function un.onUninstSuccess
1250
1251	HideWindow
1252	MessageBox MB_ICONINFORMATION\|MB_OK $(VBOX_UNINST_SUCCESS) /SD IDOK
1253
1254	FunctionEnd
1255
1256	Function un.onInit
1257
1258	; Has the user who calls us admin rights?
1259	UserInfo::GetAccountType
1260	Pop $0
1261	${If} $0 != "Admin"
1262	MessageBox MB_ICONSTOP $(VBOX_NOADMIN) /SD IDOK
1263	Abort
1264	${EndIf}
1265
1266	MessageBox MB_ICONQUESTION\|MB_YESNO\|MB_DEFBUTTON2 $(VBOX_UNINST_CONFIRM) /SD IDYES IDYES proceed
1267	Quit
1268
1269	proceed:
1270
1271	Call un.SetAppMode64
1272
1273	; Set system directory
1274	StrCpy $g_strSystemDir "$SYSDIR"
1275
1276	; We need a special directory set to SysWOW64 because some
1277	; shell operations don't support file redirection (yet)
1278	StrCpy $g_strSysWow64 "$WINDIR\SysWOW64"
1279
1280	; Retrieve Windows version we're running on and store it in $g_strWinVersion
1281	Call un.GetWindowsVersionEx
1282	Pop $g_strWinVersion
1283
1284	; Retrieve capabilities
1285	Call un.CheckForCapabilities
1286
1287	FunctionEnd
1288
1289	Section Uninstall
1290
1291	!ifdef _DEBUG
1292	${LogEnable} "true"
1293	!endif
1294
1295	Call un.SetAppMode64
1296
1297	; Call the uninstall main function
1298	Call un.Uninstall
1299
1300	; ... and remove the local install directory
1301	Call un.UninstallInstDir
1302
1303	!ifndef _DEBUG
1304	SetAutoClose true
1305	MessageBox MB_ICONQUESTION\|MB_YESNO\|MB_DEFBUTTON2 $(VBOX_REBOOT_REQUIRED) /SD IDNO IDYES restart
1306	StrCmp $g_bRebootOnExit "true" restart
1307	!endif
1308
1309	Goto exit
1310
1311	restart:
1312
1313	${LogVerbose} "Rebooting ..."
1314	Reboot
1315
1316	exit:
1317
1318	SectionEnd
1319
1320	; !EXTERNAL_UNINSTALLER
1321	!endif
1322
1323	;Direct the output to our bin dir
1324	!cd "$%PATH_OUT%\bin\additions"

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

Original Format