VBoxGuestAdditionsW2KXP.nsh@ 106347

Last change on this file since 106347 was 106321, checked in by vboxsync, 4 months ago

Windows installers: Big revamp for removing all DIFxApp-related / DIFxApi-related code and build dependencies for the host and guest installers. bugref:10762

This implements an own framework (VBoxWinDrvInst and VBoxWinDrvStore) for installing Windows drivers and querying / handling the Windows driver store,
along with testcases for the Windows guest and host installers.

Property svn:eol-style set to native
Property svn:keywords set to Id Revision

File size: 30.0 KB

Line
1	; $Id: VBoxGuestAdditionsW2KXP.nsh 106321 2024-10-15 13:06:30Z vboxsync $
2	;; @file
3	; VBoxGuestAdditionsW2KXP.nsh - Guest Additions installation for Windows 2000/XP.
4	;
5
6	;
7	; Copyright (C) 2006-2024 Oracle and/or its affiliates.
8	;
9	; This file is part of VirtualBox base platform packages, as
10	; available from https://www.virtualbox.org.
11	;
12	; This program is free software; you can redistribute it and/or
13	; modify it under the terms of the GNU General Public License
14	; as published by the Free Software Foundation, in version 3 of the
15	; License.
16	;
17	; This program is distributed in the hope that it will be useful, but
18	; WITHOUT ANY WARRANTY; without even the implied warranty of
19	; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
20	; General Public License for more details.
21	;
22	; You should have received a copy of the GNU General Public License
23	; along with this program; if not, see <https://www.gnu.org/licenses>.
24	;
25	; SPDX-License-Identifier: GPL-3.0-only
26	;
27
28	Function W2K_SetVideoResolution
29
30	; NSIS only supports global vars, even in functions -- great
31	Var /GLOBAL i
32	Var /GLOBAL tmp
33	Var /GLOBAL tmppath
34	Var /GLOBAL dev_id
35	Var /GLOBAL dev_desc
36
37	; Check for all required parameters
38	StrCmp $g_iScreenX "0" exit
39	StrCmp $g_iScreenY "0" exit
40	StrCmp $g_iScreenBpp "0" exit
41
42	${LogVerbose} "Setting display parameters ($g_iScreenXx$g_iScreenY, $g_iScreenBpp BPP) ..."
43
44	; Enumerate all video devices (up to 32 at the moment, use key "MaxObjectNumber" key later)
45	${For} $i 0 32
46
47	ReadRegStr $tmp HKLM "HARDWARE\DEVICEMAP\VIDEO" "\Device\Video$i"
48	StrCmp $tmp "" dev_not_found
49
50	; Extract path to video settings
51	; Ex: \Registry\Machine\System\CurrentControlSet\Control\Video\{28B74D2B-F0A9-48E0-8028-D76F6BB1AE65}\0000
52	; Or: \Registry\Machine\System\CurrentControlSet\Control\Video\vboxvideo\Device0
53	; Result: Machine\System\CurrentControlSet\Control\Video\{28B74D2B-F0A9-48E0-8028-D76F6BB1AE65}\0000
54	Push "$tmp" ; String
55	Push "\" ; SubString
56	Push ">" ; SearchDirection
57	Push ">" ; StrInclusionDirection
58	Push "0" ; IncludeSubString
59	Push "2" ; Loops
60	Push "0" ; CaseSensitive
61	Call StrStrAdv
62	Pop $tmppath ; $1 only contains the full path
63	StrCmp $tmppath "" dev_not_found
64
65	; Get device description
66	ReadRegStr $dev_desc HKLM "$tmppath" "Device Description"
67	!ifdef _DEBUG
68	${LogVerbose} "Registry path: $tmppath"
69	${LogVerbose} "Registry path to device name: $temp"
70	!endif
71	${LogVerbose} "Detected video device: $dev_desc"
72
73	${If} $dev_desc == "VirtualBox Graphics Adapter"
74	${LogVerbose} "VirtualBox video device found!"
75	Goto dev_found
76	${EndIf}
77	${Next}
78	Goto dev_not_found
79
80	dev_found:
81
82	; If we're on Windows 2000, skip the ID detection ...
83	${If} $g_strWinVersion == "2000"
84	Goto change_res
85	${EndIf}
86	Goto dev_found_detect_id
87
88	dev_found_detect_id:
89
90	StrCpy $i 0 ; Start at index 0
91	${LogVerbose} "Detecting device ID ..."
92
93	dev_found_detect_id_loop:
94
95	; Resolve real path to hardware instance "{GUID}"
96	EnumRegKey $dev_id HKLM "SYSTEM\CurrentControlSet\Control\Video" $i
97	StrCmp $dev_id "" dev_not_found ; No more entries? Jump out
98	!ifdef _DEBUG
99	${LogVerbose} "Got device ID: $dev_id"
100	!endif
101	ReadRegStr $dev_desc HKLM "SYSTEM\CurrentControlSet\Control\Video\$dev_id\0000" "Device Description" ; Try to read device name
102	${If} $dev_desc == "VirtualBox Graphics Adapter"
103	${LogVerbose} "Device ID of $dev_desc: $dev_id"
104	Goto change_res
105	${EndIf}
106
107	IntOp $i $i + 1 ; Increment index
108	goto dev_found_detect_id_loop
109
110	dev_not_found:
111
112	${LogVerbose} "No VirtualBox video device (yet) detected! No custom mode set."
113	Goto exit
114
115	change_res:
116
117	!ifdef _DEBUG
118	${LogVerbose} "Device description: $dev_desc"
119	${LogVerbose} "Device ID: $dev_id"
120	!endif
121
122	Var /GLOBAL reg_path_device
123	Var /GLOBAL reg_path_monitor
124
125	${LogVerbose} "Custom mode set: Platform is Windows $g_strWinVersion"
126	${If} $g_strWinVersion == "2000"
127	${OrIf} $g_strWinVersion == "Vista"
128	StrCpy $reg_path_device "SYSTEM\CurrentControlSet\SERVICES\VBoxVideo\Device0"
129	StrCpy $reg_path_monitor "SYSTEM\CurrentControlSet\SERVICES\VBoxVideo\Device0\Mon00000001"
130	${ElseIf} $g_strWinVersion == "XP"
131	${OrIf} $g_strWinVersion == "7"
132	${OrIf} $g_strWinVersion == "8"
133	${OrIf} $g_strWinVersion == "8_1"
134	${OrIf} $g_strWinVersion == "10"
135	StrCpy $reg_path_device "SYSTEM\CurrentControlSet\Control\Video\$dev_id\0000"
136	StrCpy $reg_path_monitor "SYSTEM\CurrentControlSet\Control\VIDEO\$dev_id\0000\Mon00000001"
137	${Else}
138	${LogVerbose} "Custom mode set: Windows $g_strWinVersion not supported yet"
139	Goto exit
140	${EndIf}
141
142	; Write the new value in the adapter config (VBoxVideo.sys) using hex values in binary format
143	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" registry write HKLM $reg_path_device CustomXRes REG_BIN $g_iScreenX DWORD" 'non-zero-exitcode=abort'
144	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" registry write HKLM $reg_path_device CustomYRes REG_BIN $g_iScreenY DWORD" 'non-zero-exitcode=abort'
145	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" registry write HKLM $reg_path_device CustomBPP REG_BIN $g_iScreenBpp DWORD" 'non-zero-exitcode=abort'
146
147	; ... and tell Windows to use that mode on next start!
148	WriteRegDWORD HKCC $reg_path_device "DefaultSettings.XResolution" "$g_iScreenX"
149	WriteRegDWORD HKCC $reg_path_device "DefaultSettings.YResolution" "$g_iScreenY"
150	WriteRegDWORD HKCC $reg_path_device "DefaultSettings.BitsPerPixel" "$g_iScreenBpp"
151
152	WriteRegDWORD HKCC $reg_path_monitor "DefaultSettings.XResolution" "$g_iScreenX"
153	WriteRegDWORD HKCC $reg_path_monitor "DefaultSettings.YResolution" "$g_iScreenY"
154	WriteRegDWORD HKCC $reg_path_monitor "DefaultSettings.BitsPerPixel" "$g_iScreenBpp"
155
156	${LogVerbose} "Custom mode set to $g_iScreenXx$g_iScreenY, $g_iScreenBpp BPP on next restart."
157
158	exit:
159
160	FunctionEnd
161
162	!macro W2K_CleanupCerts un
163	;;
164	; Removes certificates and the certificate utility.
165	;
166	; Since the certificate collection depends on the build config and have
167	; changed over time, we always clean it up before installation.
168	;
169	Function ${un}W2K_CleanupCerts
170	Delete /REBOOTOK "$INSTDIR\cert\vbox.cer"
171	Delete /REBOOTOK "$INSTDIR\cert\vbox-root.cer"
172	Delete /REBOOTOK "$INSTDIR\cert\vbox-timestamp-root.cer"
173	Delete /REBOOTOK "$INSTDIR\cert\vbox-sha1.cer"
174	Delete /REBOOTOK "$INSTDIR\cert\vbox-sha1-root.cer"
175	Delete /REBOOTOK "$INSTDIR\cert\vbox-sha1-timestamp-root.cer"
176	Delete /REBOOTOK "$INSTDIR\cert\vbox-sha256.cer"
177	Delete /REBOOTOK "$INSTDIR\cert\vbox-sha256-root.cer"
178	Delete /REBOOTOK "$INSTDIR\cert\vbox-sha256-timestamp-root.cer"
179	Delete /REBOOTOK "$INSTDIR\cert\vbox-sha256-r3.cer"
180	Delete /REBOOTOK "$INSTDIR\cert\vbox-sha256-r3-root.cer"
181	Delete /REBOOTOK "$INSTDIR\cert\vbox-sha256-r3-timestamp-root.cer"
182	Delete /REBOOTOK "$INSTDIR\cert\vbox-legacy-timestamp-ca.cer"
183	Delete /REBOOTOK "$INSTDIR\cert\root-versign-pca3-g5.cer" ; only for a while during 7.0 beta phase
184	Delete /REBOOTOK "$INSTDIR\cert\root-digicert-assured-id.cer" ; ditto
185	Delete /REBOOTOK "$INSTDIR\cert\root-digicert-high-assurance-ev.cer" ; ditto
186	Delete /REBOOTOK "$INSTDIR\cert\VBoxCertUtil.exe"
187	RMDir /REBOOTOK "$INSTDIR\cert"
188	FunctionEnd
189	!macroend
190	!insertmacro W2K_CleanupCerts ""
191	!insertmacro W2K_CleanupCerts "un."
192
193
194	!macro W2K_CleanupObsoleteFiles un
195	;;
196	; Removes files we're no longer shipping.
197	;
198	; During installation this step should be taken before copy files over in case
199	; the list gets out of sync and we start shipping files on it. That way it
200	; doesn't much matter as the file will be restore afterwards.
201	;
202	Function ${un}W2K_CleanupObsoleteFiles
203	Delete /REBOOTOK "$INSTDIR\VBoxWHQLFake.exe" ; Removed in r152293 (runup to 7.0).
204	Delete /REBOOTOK "$INSTDIR\VBoxICD.dll" ; Removed in r151892 (runup to 7.0).
205	FunctionEnd
206	!macroend
207	!insertmacro W2K_CleanupObsoleteFiles ""
208	!insertmacro W2K_CleanupObsoleteFiles "un."
209
210
211	!ifdef VBOX_SIGN_ADDITIONS
212	;;
213	; Run VBoxCertUtil to install the given certificate if absent on the system.
214	;
215	; @param pop1 The certificate file.
216	; @param pop2 Short description.
217	;
218	Function W2K_InstallRootCert
219	; Prolog: Save $0 & $1 and move the parameters into them.
220	Push $0
221	Exch 2
222	Push $1
223	Exch 2
224	Pop $0 ; Filename
225	Pop $1 ; Description.
226
227	; Do the work.
228	${LogVerbose} "Installing $1 ('$0') if missing ..."
229	${CmdExecute} "$\"$INSTDIR\cert\VBoxCertUtil.exe$\" add-root --add-if-new $\"$INSTDIR\cert\$0$\"" 'non-zero-exitcode=abort'
230
231	; Epilog: Restore $0 & $1 (we return nothing).
232	Pop $2
233	Pop $1
234	Pop $0
235	FunctionEnd
236	!endif
237
238	Function W2K_Prepare
239	; Save registers
240	Push $R0
241	Push $R1
242	Push $R2
243	Push $R3
244	Push $R4
245
246	${If} $g_bNoVBoxServiceExit == "false"
247	; Stop / kill VBoxService
248	Call StopVBoxService
249	${EndIf}
250
251	${If} $g_bNoVBoxTrayExit == "false"
252	; Stop / kill VBoxTray
253	Call StopVBoxTray
254	${EndIf}
255
256	; Delete VBoxService from registry
257	DeleteRegValue HKLM "Software\Microsoft\Windows\CurrentVersion\Run" "VBoxService"
258
259	; Delete old VBoxService.exe from install directory (replaced by VBoxTray.exe)
260	Delete /REBOOTOK "$INSTDIR\VBoxService.exe"
261
262	; Ditch old certificates and stuff to avoid confusion if we now ship fewer / different files.
263	Call W2K_CleanupCerts
264
265	!ifdef VBOX_SIGN_ADDITIONS
266	;
267	; When installing signed GAs, we need to make sure that the associated root
268	; certs are present, we use VBoxCertUtil for this task.
269	;
270	${LogVerbose} "Installing VBoxCertUtil.exe ..."
271	SetOutPath "$INSTDIR\cert"
272	FILE "$%PATH_OUT%\bin\additions\VBoxCertUtil.exe"
273	!if "$%VBOX_GA_CERT_ROOT_SHA1%" != "none"
274	FILE "$%PATH_OUT%\bin\additions\$%VBOX_GA_CERT_ROOT_SHA1%"
275	!endif
276	!if "$%VBOX_GA_CERT_ROOT_SHA1_TS%" != "none"
277	FILE "$%PATH_OUT%\bin\additions\$%VBOX_GA_CERT_ROOT_SHA1_TS%"
278	!endif
279	!if "$%VBOX_GA_CERT_ROOT_SHA2%" != "none"
280	FILE "$%PATH_OUT%\bin\additions\$%VBOX_GA_CERT_ROOT_SHA2%"
281	!endif
282	!if "$%VBOX_GA_CERT_ROOT_SHA2_TS%" != "none"
283	FILE "$%PATH_OUT%\bin\additions\$%VBOX_GA_CERT_ROOT_SHA2_TS%"
284	!endif
285	!if "$%VBOX_GA_CERT_ROOT_SHA2_R3%" != "none"
286	FILE "$%PATH_OUT%\bin\additions\$%VBOX_GA_CERT_ROOT_SHA2_R3%"
287	!endif
288	!if "$%VBOX_GA_CERT_ROOT_SHA2_R3_TS%" != "none"
289	FILE "$%PATH_OUT%\bin\additions\$%VBOX_GA_CERT_ROOT_SHA2_R3_TS%"
290	!endif
291
292	;
293	; Install the certificates if missing.
294	;
295	!if "$%VBOX_GA_CERT_ROOT_SHA1%" != "none"
296	Push "SHA-1 root"
297	Push "$%VBOX_GA_CERT_ROOT_SHA1%"
298	Call W2K_InstallRootCert
299	!endif
300	!if "$%VBOX_GA_CERT_ROOT_SHA1_TS%" != "none"
301	!ifdef VBOX_WITH_VBOX_LEGACY_TS_CA
302	; If not explicitly specified, let the detected Windows version decide what
303	; to do. On guest OSes < Windows 10 we always go for the PreW10 security
304	; catalog files (.cat) and there we install our legacy timestamp CA by default.
305	${If} $g_bInstallTimestampCA == "unset"
306	${AndIf} $g_strWinVersion != "10"
307	StrCpy $g_bInstallTimestampCA "true"
308	${EndIf}
309	${If} $g_bInstallTimestampCA == "true"
310	Push "SHA-1 timestamp root"
311	Push "$%VBOX_GA_CERT_ROOT_SHA1_TS%"
312	Call W2K_InstallRootCert
313	${EndIf}
314	!else
315	Push "SHA-1 timestamp root"
316	Push "$%VBOX_GA_CERT_ROOT_SHA1_TS%"
317	Call W2K_InstallRootCert
318	!endif ; VBOX_WITH_VBOX_LEGACY_TS_CA
319	!endif
320
321	; XP sp3 and later can make use of SHA-2 certs. Windows 2000 cannot.
322	; Note that VBOX_GA_CERT_ROOT_SHA1 may be a SHA-2 cert, the hash algorithm
323	; refers to the windows signature structures not the certificate.
324	${If} $g_strWinVersion != "2000"
325	!if "$%VBOX_GA_CERT_ROOT_SHA2%" != "none"
326	Push "SHA-2 root"
327	Push "$%VBOX_GA_CERT_ROOT_SHA2%"
328	Call W2K_InstallRootCert
329	!endif
330	!if "$%VBOX_GA_CERT_ROOT_SHA2_TS%" != "none"
331	Push "SHA-2 timestamp root"
332	Push "$%VBOX_GA_CERT_ROOT_SHA2_TS%"
333	Call W2K_InstallRootCert
334	!endif
335	!if "$%VBOX_GA_CERT_ROOT_SHA2_R3%" != "none"
336	Push "SHA-2 ring-3 root"
337	Push "$%VBOX_GA_CERT_ROOT_SHA2_R3%"
338	Call W2K_InstallRootCert
339	!endif
340	!if "$%VBOX_GA_CERT_ROOT_SHA2_R3_TS%" != "none"
341	Push "SHA-2 ring-3 timestamp root"
342	Push "$%VBOX_GA_CERT_ROOT_SHA2_R3_TS%"
343	Call W2K_InstallRootCert
344	!endif
345	${EndIf}
346	!endif ; VBOX_SIGN_ADDITIONS
347
348	; Restore registers
349	Pop $R4
350	Pop $R3
351	Pop $R2
352	Pop $R1
353	Pop $R0
354	FunctionEnd
355
356	Function W2K_CopyFiles
357
358	Push $0
359	SetOutPath "$INSTDIR"
360
361	; Video driver
362	FILE "$%PATH_OUT%\bin\additions\VBoxVideo.sys"
363	FILE "$%PATH_OUT%\bin\additions\VBoxDisp.dll"
364
365	; Mouse driver
366	FILE "$%PATH_OUT%\bin\additions\VBoxMouse.sys"
367	FILE "$%PATH_OUT%\bin\additions\VBoxMouse.inf"
368	!ifdef VBOX_SIGN_ADDITIONS
369	${If} $g_strWinVersion == "10"
370	FILE "$%PATH_OUT%\bin\additions\VBoxMouse.cat"
371	${Else}
372	FILE "/oname=VBoxMouse.cat" "$%PATH_OUT%\bin\additions\VBoxMouse-PreW10.cat"
373	${EndIf}
374	!endif
375
376	; Guest driver
377	FILE "$%PATH_OUT%\bin\additions\VBoxGuest.sys"
378	FILE "$%PATH_OUT%\bin\additions\VBoxGuest.inf"
379	!if $%KBUILD_TARGET_ARCH% == "x86"
380	${If} $g_strEarlyNTDrvInfix != ""
381	FILE "$%PATH_OUT%\bin\additions\VBoxGuestEarlyNT.inf"
382	!ifdef VBOX_SIGN_ADDITIONS
383	FILE "$%PATH_OUT%\bin\additions\VBoxGuestEarlyNT.cat"
384	!endif
385	${EndIf}
386	!endif
387	!ifdef VBOX_SIGN_ADDITIONS
388	${If} $g_strWinVersion == "10"
389	FILE "$%PATH_OUT%\bin\additions\VBoxGuest.cat"
390	${Else}
391	FILE "/oname=VBoxGuest.cat" "$%PATH_OUT%\bin\additions\VBoxGuest-PreW10.cat"
392	${EndIf}
393	!endif
394
395	; Guest driver files
396	FILE "$%PATH_OUT%\bin\additions\VBoxTray.exe"
397	FILE "$%PATH_OUT%\bin\additions\VBoxControl.exe"
398
399	; Misc
400	!ifdef VBOX_WITH_ADDITIONS_SHIPPING_AUDIO_TEST
401	FILE "$%PATH_OUT%\bin\additions\VBoxAudioTest.exe"
402	!endif
403
404	SetOutPath $g_strSystemDir
405
406	; VBoxService
407	${If} $g_bNoVBoxServiceExit == "false"
408	; VBoxService has been terminated before, so just install the file
409	; in the regular way
410	FILE "$%PATH_OUT%\bin\additions\VBoxService.exe"
411	${Else}
412	; VBoxService is in use and wasn't terminated intentionally. So extract the
413	; new version into a temporary location and install it on next reboot
414	Push $0
415	ClearErrors
416	GetTempFileName $0
417	IfErrors 0 +3
418	${LogVerbose} "Error getting temp file for VBoxService.exe"
419	StrCpy "$0" "$INSTDIR\VBoxServiceTemp.exe"
420	${LogVerbose} "VBoxService is in use, will be installed on next reboot (from '$0')"
421	File "/oname=$0" "$%PATH_OUT%\bin\additions\VBoxService.exe"
422	IfErrors 0 +2
423	${LogVerbose} "Error copying VBoxService.exe to '$0'"
424	Rename /REBOOTOK "$0" "$g_strSystemDir\VBoxService.exe"
425	IfErrors 0 +2
426	${LogVerbose} "Error renaming '$0' to '$g_strSystemDir\VBoxService.exe'"
427	Pop $0
428	${EndIf}
429
430	!if $%VBOX_WITH_WDDM% == "1"
431	${If} $g_bWithWDDM == "true"
432	; WDDM Video driver
433	SetOutPath "$INSTDIR"
434
435	!ifdef VBOX_SIGN_ADDITIONS
436	${If} $g_strWinVersion == "10"
437	FILE "$%PATH_OUT%\bin\additions\VBoxWddm.cat"
438	${Else}
439	FILE "/oname=VBoxWddm.cat" "$%PATH_OUT%\bin\additions\VBoxWddm-PreW10.cat"
440	${EndIf}
441	!endif
442	FILE "$%PATH_OUT%\bin\additions\VBoxWddm.sys"
443	FILE "$%PATH_OUT%\bin\additions\VBoxWddm.inf"
444
445	FILE "$%PATH_OUT%\bin\additions\VBoxDispD3D.dll"
446	!if $%VBOX_WITH_WDDM_DX% == "1"
447	FILE "$%PATH_OUT%\bin\additions\VBoxDX.dll"
448	!endif
449	!if $%VBOX_WITH_MESA3D% == "1"
450	FILE "$%PATH_OUT%\bin\additions\VBoxNine.dll"
451	FILE "$%PATH_OUT%\bin\additions\VBoxSVGA.dll"
452	FILE "$%PATH_OUT%\bin\additions\VBoxGL.dll"
453	!endif
454
455	!if $%KBUILD_TARGET_ARCH% == "amd64"
456	FILE "$%PATH_OUT%\bin\additions\VBoxDispD3D-x86.dll"
457	!if $%VBOX_WITH_WDDM_DX% == "1"
458	FILE "$%PATH_OUT%\bin\additions\VBoxDX-x86.dll"
459	!endif
460	!if $%VBOX_WITH_MESA3D% == "1"
461	FILE "$%PATH_OUT%\bin\additions\VBoxNine-x86.dll"
462	FILE "$%PATH_OUT%\bin\additions\VBoxSVGA-x86.dll"
463	FILE "$%PATH_OUT%\bin\additions\VBoxGL-x86.dll"
464	!endif
465	!endif ; $%KBUILD_TARGET_ARCH% == "amd64"
466
467	${EndIf}
468	!endif ; $%VBOX_WITH_WDDM% == "1"
469
470	Pop $0
471
472	FunctionEnd
473
474
475	Function W2K_InstallFiles
476
477	; The Shared Folder IFS goes to the system directory
478	!if $%BUILD_TARGET_ARCH% == "x86"
479	; On x86 we have to use a different shared folder driver linked against an older RDBSS for Windows 7 and older.
480	${If} $g_strWinVersion == "2000"
481	${OrIf} $g_strWinVersion == "XP"
482	${OrIf} $g_strWinVersion == "2003"
483	${OrIf} $g_strWinVersion == "Vista"
484	${OrIf} $g_strWinVersion == "7"
485	!insertmacro ReplaceDLL "$%PATH_OUT%\bin\additions\VBoxSFW2K.sys" "$g_strSystemDir\drivers\VBoxSF.sys" "$INSTDIR"
486	${Else}
487	!insertmacro ReplaceDLL "$%PATH_OUT%\bin\additions\VBoxSF.sys" "$g_strSystemDir\drivers\VBoxSF.sys" "$INSTDIR"
488	${EndIf}
489	!else
490	!insertmacro ReplaceDLL "$%PATH_OUT%\bin\additions\VBoxSF.sys" "$g_strSystemDir\drivers\VBoxSF.sys" "$INSTDIR"
491	!endif
492
493	!insertmacro ReplaceDLL "$%PATH_OUT%\bin\additions\VBoxMRXNP.dll" "$g_strSystemDir\VBoxMRXNP.dll" "$INSTDIR"
494	AccessControl::GrantOnFile "$g_strSystemDir\VBoxMRXNP.dll" "(BU)" "GenericRead"
495	!if $%KBUILD_TARGET_ARCH% == "amd64"
496	; Only 64-bit installer: Copy the 32-bit DLL for 32 bit applications.
497	!insertmacro ReplaceDLL "$%PATH_OUT%\bin\additions\VBoxMRXNP-x86.dll" "$g_strSysWow64\VBoxMRXNP.dll" "$INSTDIR"
498	AccessControl::GrantOnFile "$g_strSysWow64\VBoxMRXNP.dll" "(BU)" "GenericRead"
499	!endif
500
501	; The VBoxTray hook DLL also goes to the system directory; it might be locked
502	!insertmacro ReplaceDLL "$%PATH_OUT%\bin\additions\VBoxHook.dll" "$g_strSystemDir\VBoxHook.dll" "$INSTDIR"
503	AccessControl::GrantOnFile "$g_strSystemDir\VBoxHook.dll" "(BU)" "GenericRead"
504
505	${LogVerbose} "Installing drivers ..."
506
507	Push $0 ; For fetching results
508
509	SetOutPath "$INSTDIR"
510
511	${If} $g_bNoGuestDrv == "false"
512	${LogVerbose} "Installing guest driver ..."
513	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" driver install $\"$INSTDIR\VBoxGuest$g_strEarlyNTDrvInfix.inf$\" $\"PCI\VEN_80EE&DEV_CAFE$\" $\"$INSTDIR\install_drivers.log$\"" 'non-zero-exitcode=abort'
514	${Else}
515	${LogVerbose} "Guest driver installation skipped!"
516	${EndIf}
517
518	${If} $g_bNoVideoDrv == "false"
519	${If} $g_bWithWDDM == "true"
520	${LogVerbose} "Installing WDDM video driver..."
521	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" driver install $\"$INSTDIR\VBoxWddm.inf$\" $\"$\" $\"$INSTDIR\install_drivers.log$\"" 'non-zero-exitcode=abort'
522	${Else}
523	${LogVerbose} "Installing video driver ..."
524	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" driver install $\"$INSTDIR\VBoxVideo$g_strEarlyNTDrvInfix.inf$\" $\"$\" $\"$INSTDIR\install_drivers.log$\"" 'non-zero-exitcode=abort'
525	${EndIf}
526	${Else}
527	${LogVerbose} "Video driver installation skipped!"
528	${EndIf}
529
530	;
531	; Mouse driver.
532	;
533	${If} $g_bNoMouseDrv == "false"
534	${LogVerbose} "Installing mouse driver ..."
535	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" driver executeinf $\"$INSTDIR\VBoxMouse.inf$\" $\"DefaultInstall.NT$%KBUILD_TARGET_ARCH%$\" $\"$INSTDIR\install_drivers.log$\"" 'non-zero-exitcode=abort'
536	${Else}
537	${LogVerbose} "Mouse driver installation skipped!"
538	${EndIf}
539
540	;
541	; Create the VBoxService service
542	; No need to stop/remove the service here! Do this only on uninstallation!
543	;
544	${LogVerbose} "Installing VirtualBox service ..."
545	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" service create $\"VBoxService$\" $\"VirtualBox Guest Additions Service$\" 16 2 $\"%SystemRoot%\System32\VBoxService.exe$\" $\"Base$\"" 'non-zero-exitcode=abort'
546
547	; Set service description
548	WriteRegStr HKLM "SYSTEM\CurrentControlSet\Services\VBoxService" "Description" "Manages VM runtime information, time synchronization, remote sysprep execution and miscellaneous utilities for guest operating systems."
549
550
551	;
552	; Shared folders.
553	;
554	${LogVerbose} "Installing Shared Folders service ..."
555
556	; Create the Shared Folders service ...
557	; No need to stop/remove the service here! Do this only on uninstallation!
558	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" service create $\"VBoxSF$\" $\"VirtualBox Shared Folders$\" 2 1 $\"\SystemRoot\System32\drivers\VBoxSF.sys$\" $\"NetworkProvider$\"" 'non-zero-exitcode=abort'
559
560	; ... and the link to the network provider
561	WriteRegStr HKLM "SYSTEM\CurrentControlSet\Services\VBoxSF\NetworkProvider" "DeviceName" "\Device\VBoxMiniRdr"
562	WriteRegStr HKLM "SYSTEM\CurrentControlSet\Services\VBoxSF\NetworkProvider" "Name" "VirtualBox Shared Folders"
563	WriteRegStr HKLM "SYSTEM\CurrentControlSet\Services\VBoxSF\NetworkProvider" "ProviderPath" "$SYSDIR\VBoxMRXNP.dll"
564
565	; Add default network providers (if not present or corrupted)
566	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" netprovider add WebClient" 'non-zero-exitcode=abort'
567	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" netprovider add LanmanWorkstation" 'non-zero-exitcode=abort'
568	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" netprovider add RDPNP" 'non-zero-exitcode=abort'
569
570	; Add the shared folders network provider
571	${LogVerbose} "Adding network provider (Order = $g_iSfOrder) ..."
572	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" netprovider add VBoxSF $g_iSfOrder" 'non-zero-exitcode=abort'
573
574
575	Pop $0
576
577	FunctionEnd
578
579	Function W2K_Main
580
581	SetOutPath "$INSTDIR"
582	SetOverwrite on
583
584	Call W2K_Prepare
585	Call W2K_CleanupObsoleteFiles
586	Call W2K_CopyFiles
587	Call W2K_InstallFiles
588	Call W2K_SetVideoResolution
589
590	FunctionEnd
591
592	!macro W2K_UninstallInstDir un
593	Function ${un}W2K_UninstallInstDir
594
595	Delete /REBOOTOK "$INSTDIR\VBoxVideo.sys"
596	Delete /REBOOTOK "$INSTDIR\VBoxVideo.inf"
597	Delete /REBOOTOK "$INSTDIR\VBoxVideo.cat"
598	Delete /REBOOTOK "$INSTDIR\VBoxVideoEarlyNT.inf"
599	Delete /REBOOTOK "$INSTDIR\VBoxVideoEarlyNT.cat"
600	Delete /REBOOTOK "$INSTDIR\VBoxDisp.dll"
601
602	Delete /REBOOTOK "$INSTDIR\VBoxMouse.sys"
603	Delete /REBOOTOK "$INSTDIR\VBoxMouse.inf"
604	Delete /REBOOTOK "$INSTDIR\VBoxMouse.cat"
605
606	Delete /REBOOTOK "$INSTDIR\VBoxTray.exe"
607
608	Delete /REBOOTOK "$INSTDIR\VBoxGuest.sys"
609	Delete /REBOOTOK "$INSTDIR\VBoxGuest.inf"
610	Delete /REBOOTOK "$INSTDIR\VBoxGuest.cat"
611	Delete /REBOOTOK "$INSTDIR\VBoxGuestEarlyNT.inf"
612	Delete /REBOOTOK "$INSTDIR\VBoxGuestEarlyNT.cat"
613
614	Delete /REBOOTOK "$INSTDIR\VBCoInst.dll" ; Deprecated, does not get installed anymore
615	Delete /REBOOTOK "$INSTDIR\VBoxControl.exe"
616	Delete /REBOOTOK "$INSTDIR\VBoxService.exe" ; Deprecated, does not get installed anymore
617
618	!if $%VBOX_WITH_WDDM% == "1"
619	Delete /REBOOTOK "$INSTDIR\VBoxWddm.cat"
620	Delete /REBOOTOK "$INSTDIR\VBoxWddm.sys"
621	Delete /REBOOTOK "$INSTDIR\VBoxWddm.inf"
622	; Obsolete files begin
623	Delete /REBOOTOK "$INSTDIR\VBoxVideoWddm.cat"
624	Delete /REBOOTOK "$INSTDIR\VBoxVideoWddm.sys"
625	Delete /REBOOTOK "$INSTDIR\VBoxVideoWddm.inf"
626	Delete /REBOOTOK "$INSTDIR\VBoxVideoW8.cat"
627	Delete /REBOOTOK "$INSTDIR\VBoxVideoW8.sys"
628	Delete /REBOOTOK "$INSTDIR\VBoxVideoW8.inf"
629	; Obsolete files end
630	Delete /REBOOTOK "$INSTDIR\VBoxDispD3D.dll"
631	!if $%VBOX_WITH_WDDM_DX% == "1"
632	Delete /REBOOTOK "$INSTDIR\VBoxDX.dll"
633	!endif
634	!if $%VBOX_WITH_MESA3D% == "1"
635	Delete /REBOOTOK "$INSTDIR\VBoxNine.dll"
636	Delete /REBOOTOK "$INSTDIR\VBoxSVGA.dll"
637	Delete /REBOOTOK "$INSTDIR\VBoxICD.dll"
638	Delete /REBOOTOK "$INSTDIR\VBoxGL.dll"
639	!endif
640
641	Delete /REBOOTOK "$INSTDIR\VBoxD3D9wddm.dll"
642	Delete /REBOOTOK "$INSTDIR\wined3dwddm.dll"
643	; Try to delete libWine in case it is there from old installation
644	Delete /REBOOTOK "$INSTDIR\libWine.dll"
645
646	!if $%KBUILD_TARGET_ARCH% == "amd64"
647	Delete /REBOOTOK "$INSTDIR\VBoxDispD3D-x86.dll"
648	!if $%VBOX_WITH_WDDM_DX% == "1"
649	Delete /REBOOTOK "$INSTDIR\VBoxDX-x86.dll"
650	!endif
651	!if $%VBOX_WITH_MESA3D% == "1"
652	Delete /REBOOTOK "$INSTDIR\VBoxNine-x86.dll"
653	Delete /REBOOTOK "$INSTDIR\VBoxSVGA-x86.dll"
654	Delete /REBOOTOK "$INSTDIR\VBoxICD-x86.dll"
655	Delete /REBOOTOK "$INSTDIR\VBoxGL-x86.dll"
656	!endif
657
658	Delete /REBOOTOK "$INSTDIR\VBoxD3D9wddm-x86.dll"
659	Delete /REBOOTOK "$INSTDIR\wined3dwddm-x86.dll"
660	!endif ; $%KBUILD_TARGET_ARCH% == "amd64"
661	!endif ; $%VBOX_WITH_WDDM% == "1"
662
663	; Certificates, utility and directory.
664	Call ${un}W2K_CleanupCerts
665
666	; Log files
667	Delete /REBOOTOK "$INSTDIR\install.log"
668	Delete /REBOOTOK "$INSTDIR\install_ui.log"
669	Delete /REBOOTOK "$INSTDIR\install_drivers.log"
670
671	; Obsolete stuff.
672	Call ${un}W2K_CleanupObsoleteFiles
673
674	FunctionEnd
675	!macroend
676	;!insertmacro W2K_UninstallInstDir "" - only .un version used
677	!insertmacro W2K_UninstallInstDir "un."
678
679	!macro W2K_Uninstall un
680	Function ${un}W2K_Uninstall
681
682	Push $0
683
684	; Remove VirtualBox video driver
685	${LogVerbose} "Uninstalling video driver ..."
686	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" driver uninstall $\"$INSTDIR\VBoxVideo$g_strEarlyNTDrvInfix.inf$\" $\"VBoxVideo*$\"" 'non-zero-exitcode=log'
687	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" service delete VBoxVideo" 'non-zero-exitcode=log'
688	Delete /REBOOTOK "$g_strSystemDir\drivers\VBoxVideo.sys"
689	Delete /REBOOTOK "$g_strSystemDir\VBoxDisp.dll"
690
691	; Remove video driver
692	!if $%VBOX_WITH_WDDM% == "1"
693
694	${LogVerbose} "Uninstalling WDDM video driver..."
695	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" driver uninstall $\"$INSTDIR\VBoxWddm.inf$\" $\"VBoxWddm*$\"" 'non-zero-exitcode=log'
696	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" service delete VBoxWddm" 'non-zero-exitcode=log'
697	;misha> @todo driver file removal (as well as service removal) should be done as driver package uninstall
698	; could be done with "VBoxDrvInst.exe /u", e.g. by passing additional arg to it denoting that driver package is to be uninstalled
699	Delete /REBOOTOK "$g_strSystemDir\drivers\VBoxWddm.sys"
700
701	; Obsolete files begin
702	${LogVerbose} "Uninstalling WDDM video driver for Windows 8..."
703	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" driver uninstall $\"$INSTDIR\VBoxVideoW8.inf$\" $\"VBoxVideoW8*$\"" 'non-zero-exitcode=log'
704	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" service delete VBoxVideoW8" 'non-zero-exitcode=log'
705	;misha> @todo driver file removal (as well as service removal) should be done as driver package uninstall
706	; could be done with "VBoxDrvInst.exe /u", e.g. by passing additional arg to it denoting that driver package is to be uninstalled
707	Delete /REBOOTOK "$g_strSystemDir\drivers\VBoxVideoW8.sys"
708
709	${LogVerbose} "Uninstalling WDDM video driver for Windows Vista and 7..."
710	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" driver uninstall $\"$INSTDIR\VBoxVideoWddm.inf$\" $\"VBoxVideoWddm*$\"" 'non-zero-exitcode=log'
711	; Always try to remove both VBoxVideoWddm & VBoxVideo services no matter what is installed currently
712	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" service delete VBoxVideoWddm" 'non-zero-exitcode=log'
713	;misha> @todo driver file removal (as well as service removal) should be done as driver package uninstall
714	; could be done with "VBoxDrvInst.exe /u", e.g. by passing additional arg to it denoting that driver package is to be uninstalled
715	Delete /REBOOTOK "$g_strSystemDir\drivers\VBoxVideoWddm.sys"
716	; Obsolete files end
717
718	Delete /REBOOTOK "$g_strSystemDir\VBoxDispD3D.dll"
719	!if $%KBUILD_TARGET_ARCH% == "amd64"
720	Delete /REBOOTOK "$g_strSysWow64\VBoxDispD3D-x86.dll"
721	!endif
722
723	!if $%VBOX_WITH_WDDM_DX% == "1"
724	Delete /REBOOTOK "$g_strSystemDir\VBoxDX.dll"
725	!if $%KBUILD_TARGET_ARCH% == "amd64"
726	Delete /REBOOTOK "$g_strSysWow64\VBoxDX-x86.dll"
727	!endif
728	!endif
729
730	!if $%VBOX_WITH_MESA3D% == "1"
731	Delete /REBOOTOK "$g_strSystemDir\VBoxNine.dll"
732	Delete /REBOOTOK "$g_strSystemDir\VBoxSVGA.dll"
733	Delete /REBOOTOK "$g_strSystemDir\VBoxICD.dll"
734	Delete /REBOOTOK "$g_strSystemDir\VBoxGL.dll"
735
736	!if $%KBUILD_TARGET_ARCH% == "amd64"
737	Delete /REBOOTOK "$g_strSysWow64\VBoxNine-x86.dll"
738	Delete /REBOOTOK "$g_strSysWow64\VBoxSVGA-x86.dll"
739	Delete /REBOOTOK "$g_strSysWow64\VBoxICD-x86.dll"
740	Delete /REBOOTOK "$g_strSysWow64\VBoxGL-x86.dll"
741	!endif
742	!endif
743	!endif ; $%VBOX_WITH_WDDM% == "1"
744
745	; Remove mouse driver
746	${LogVerbose} "Removing mouse driver ..."
747	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" driver uninstall $\"$INSTDIR\VBoxMouse.inf$\" $\"VBoxMouse*$\"" 'non-zero-exitcode=log'
748	; @todo Fix VBoxMouse.inf to also take care of the next line!
749	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" registry delmultisz $\"SYSTEM\CurrentControlSet\Control\Class\{4D36E96F-E325-11CE-BFC1-08002BE10318}$\" $\"UpperFilters$\" $\"VBoxMouse$\"" 'non-zero-exitcode=log'
750
751	; Delete the VBoxService service
752	Call ${un}StopVBoxService
753	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" service delete VBoxService" 'non-zero-exitcode=log'
754	DeleteRegValue HKLM "Software\Microsoft\Windows\CurrentVersion\Run" "VBoxService"
755	Delete /REBOOTOK "$g_strSystemDir\VBoxService.exe"
756
757	; VBoxGINA
758	Delete /REBOOTOK "$g_strSystemDir\VBoxGINA.dll"
759	ReadRegStr $0 HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\WinLogon" "GinaDLL"
760	${If} $0 == "VBoxGINA.dll"
761	${LogVerbose} "Removing auto-logon support ..."
762	DeleteRegValue HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\WinLogon" "GinaDLL"
763	${EndIf}
764	DeleteRegKey HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\WinLogon\Notify\VBoxGINA"
765
766	; Delete VBoxTray
767	Call ${un}StopVBoxTray
768	DeleteRegValue HKLM "Software\Microsoft\Windows\CurrentVersion\Run" "VBoxTray"
769
770	; Remove guest driver
771	${LogVerbose} "Removing guest driver ..."
772	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" driver uninstall $\"$INSTDIR\VBoxGuest$g_strEarlyNTDrvInfix.inf$\" $\"VBoxGuest*$\"" 'non-zero-exitcode=log'
773
774	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" service delete VBoxGuest" 'non-zero-exitcode=log'
775	Delete /REBOOTOK "$g_strSystemDir\drivers\VBoxGuest.sys"
776	Delete /REBOOTOK "$g_strSystemDir\VBCoInst.dll" ; Deprecated, does not get installed anymore
777	Delete /REBOOTOK "$g_strSystemDir\VBoxTray.exe"
778	Delete /REBOOTOK "$g_strSystemDir\VBoxHook.dll"
779	DeleteRegValue HKLM "Software\Microsoft\Windows\CurrentVersion\Run" "VBoxTray" ; Remove VBoxTray autorun
780	Delete /REBOOTOK "$g_strSystemDir\VBoxControl.exe"
781
782	; Remove shared folders driver
783	${LogVerbose} "Removing shared folders driver ..."
784	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" netprovider remove VBoxSF" 'non-zero-exitcode=log'
785	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" service delete VBoxSF" 'non-zero-exitcode=log'
786	Delete /REBOOTOK "$g_strSystemDir\VBoxMRXNP.dll" ; The network provider DLL will be locked
787	!if $%KBUILD_TARGET_ARCH% == "amd64"
788	; Only 64-bit installer: Also remove 32-bit DLLs on 64-bit target arch in Wow64 node
789	Delete /REBOOTOK "$g_strSysWow64\VBoxMRXNP.dll"
790	!endif ; amd64
791	Delete /REBOOTOK "$g_strSystemDir\drivers\VBoxSF.sys"
792
793	Pop $0
794
795	FunctionEnd
796	!macroend
797	!ifndef UNINSTALLER_ONLY
798	!insertmacro W2K_Uninstall ""
799	!endif
800	!insertmacro W2K_Uninstall "un."

Note: See TracBrowser for help on using the repository browser.

source: vbox/trunk/src/VBox/Additions/WINNT/Installer/VBoxGuestAdditionsW2KXP.nsh@ 106347

Download in other formats: