VBoxGuestAdditionsW2KXP.nsh@ 106844

Last change on this file since 106844 was 106844, checked in by vboxsync, 4 weeks ago
Add/Nt/Installer: Some quick adjustments to make packing work when targeting win.arm64. jiraref:VBP-1253
Property svn:eol-style set to `native` Property svn:keywords set to `Id Revision`
File size: 30.6 KB

Line
1	; $Id: VBoxGuestAdditionsW2KXP.nsh 106844 2024-11-06 02:00:42Z vboxsync $
2	;; @file
3	; VBoxGuestAdditionsW2KXP.nsh - Guest Additions installation for Windows 2000/XP.
4	;
5
6	;
7	; Copyright (C) 2006-2024 Oracle and/or its affiliates.
8	;
9	; This file is part of VirtualBox base platform packages, as
10	; available from https://www.virtualbox.org.
11	;
12	; This program is free software; you can redistribute it and/or
13	; modify it under the terms of the GNU General Public License
14	; as published by the Free Software Foundation, in version 3 of the
15	; License.
16	;
17	; This program is distributed in the hope that it will be useful, but
18	; WITHOUT ANY WARRANTY; without even the implied warranty of
19	; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
20	; General Public License for more details.
21	;
22	; You should have received a copy of the GNU General Public License
23	; along with this program; if not, see <https://www.gnu.org/licenses>.
24	;
25	; SPDX-License-Identifier: GPL-3.0-only
26	;
27
28	Function W2K_SetVideoResolution
29
30	; NSIS only supports global vars, even in functions -- great
31	Var /GLOBAL i
32	Var /GLOBAL tmp
33	Var /GLOBAL tmppath
34	Var /GLOBAL dev_id
35	Var /GLOBAL dev_desc
36
37	; Check for all required parameters
38	StrCmp $g_iScreenX "0" exit
39	StrCmp $g_iScreenY "0" exit
40	StrCmp $g_iScreenBpp "0" exit
41
42	${LogVerbose} "Setting display parameters ($g_iScreenXx$g_iScreenY, $g_iScreenBpp BPP) ..."
43
44	; Enumerate all video devices (up to 32 at the moment, use key "MaxObjectNumber" key later)
45	${For} $i 0 32
46
47	ReadRegStr $tmp HKLM "HARDWARE\DEVICEMAP\VIDEO" "\Device\Video$i"
48	StrCmp $tmp "" dev_not_found
49
50	; Extract path to video settings
51	; Ex: \Registry\Machine\System\CurrentControlSet\Control\Video\{28B74D2B-F0A9-48E0-8028-D76F6BB1AE65}\0000
52	; Or: \Registry\Machine\System\CurrentControlSet\Control\Video\vboxvideo\Device0
53	; Result: Machine\System\CurrentControlSet\Control\Video\{28B74D2B-F0A9-48E0-8028-D76F6BB1AE65}\0000
54	Push "$tmp" ; String
55	Push "\" ; SubString
56	Push ">" ; SearchDirection
57	Push ">" ; StrInclusionDirection
58	Push "0" ; IncludeSubString
59	Push "2" ; Loops
60	Push "0" ; CaseSensitive
61	Call StrStrAdv
62	Pop $tmppath ; $1 only contains the full path
63	StrCmp $tmppath "" dev_not_found
64
65	; Get device description
66	ReadRegStr $dev_desc HKLM "$tmppath" "Device Description"
67	!ifdef _DEBUG
68	${LogVerbose} "Registry path: $tmppath"
69	${LogVerbose} "Registry path to device name: $temp"
70	!endif
71	${LogVerbose} "Detected video device: $dev_desc"
72
73	${If} $dev_desc == "VirtualBox Graphics Adapter"
74	${LogVerbose} "VirtualBox video device found!"
75	Goto dev_found
76	${EndIf}
77	${Next}
78	Goto dev_not_found
79
80	dev_found:
81
82	; If we're on Windows 2000, skip the ID detection ...
83	${If} $g_strWinVersion == "2000"
84	Goto change_res
85	${EndIf}
86	Goto dev_found_detect_id
87
88	dev_found_detect_id:
89
90	StrCpy $i 0 ; Start at index 0
91	${LogVerbose} "Detecting device ID ..."
92
93	dev_found_detect_id_loop:
94
95	; Resolve real path to hardware instance "{GUID}"
96	EnumRegKey $dev_id HKLM "SYSTEM\CurrentControlSet\Control\Video" $i
97	StrCmp $dev_id "" dev_not_found ; No more entries? Jump out
98	!ifdef _DEBUG
99	${LogVerbose} "Got device ID: $dev_id"
100	!endif
101	ReadRegStr $dev_desc HKLM "SYSTEM\CurrentControlSet\Control\Video\$dev_id\0000" "Device Description" ; Try to read device name
102	${If} $dev_desc == "VirtualBox Graphics Adapter"
103	${LogVerbose} "Device ID of $dev_desc: $dev_id"
104	Goto change_res
105	${EndIf}
106
107	IntOp $i $i + 1 ; Increment index
108	goto dev_found_detect_id_loop
109
110	dev_not_found:
111
112	${LogVerbose} "No VirtualBox video device (yet) detected! No custom mode set."
113	Goto exit
114
115	change_res:
116
117	!ifdef _DEBUG
118	${LogVerbose} "Device description: $dev_desc"
119	${LogVerbose} "Device ID: $dev_id"
120	!endif
121
122	Var /GLOBAL reg_path_device
123	Var /GLOBAL reg_path_monitor
124
125	${LogVerbose} "Custom mode set: Platform is Windows $g_strWinVersion"
126	${If} $g_strWinVersion == "2000"
127	${OrIf} $g_strWinVersion == "Vista"
128	StrCpy $reg_path_device "SYSTEM\CurrentControlSet\SERVICES\VBoxVideo\Device0"
129	StrCpy $reg_path_monitor "SYSTEM\CurrentControlSet\SERVICES\VBoxVideo\Device0\Mon00000001"
130	${ElseIf} $g_strWinVersion == "XP"
131	${OrIf} $g_strWinVersion == "7"
132	${OrIf} $g_strWinVersion == "8"
133	${OrIf} $g_strWinVersion == "8_1"
134	${OrIf} $g_strWinVersion == "10"
135	StrCpy $reg_path_device "SYSTEM\CurrentControlSet\Control\Video\$dev_id\0000"
136	StrCpy $reg_path_monitor "SYSTEM\CurrentControlSet\Control\VIDEO\$dev_id\0000\Mon00000001"
137	${Else}
138	${LogVerbose} "Custom mode set: Windows $g_strWinVersion not supported yet"
139	Goto exit
140	${EndIf}
141
142	; Write the new value in the adapter config (VBoxVideo.sys) using hex values in binary format
143	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" registry write HKLM $reg_path_device CustomXRes REG_BIN $g_iScreenX DWORD" 'non-zero-exitcode=abort'
144	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" registry write HKLM $reg_path_device CustomYRes REG_BIN $g_iScreenY DWORD" 'non-zero-exitcode=abort'
145	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" registry write HKLM $reg_path_device CustomBPP REG_BIN $g_iScreenBpp DWORD" 'non-zero-exitcode=abort'
146
147	; ... and tell Windows to use that mode on next start!
148	WriteRegDWORD HKCC $reg_path_device "DefaultSettings.XResolution" "$g_iScreenX"
149	WriteRegDWORD HKCC $reg_path_device "DefaultSettings.YResolution" "$g_iScreenY"
150	WriteRegDWORD HKCC $reg_path_device "DefaultSettings.BitsPerPixel" "$g_iScreenBpp"
151
152	WriteRegDWORD HKCC $reg_path_monitor "DefaultSettings.XResolution" "$g_iScreenX"
153	WriteRegDWORD HKCC $reg_path_monitor "DefaultSettings.YResolution" "$g_iScreenY"
154	WriteRegDWORD HKCC $reg_path_monitor "DefaultSettings.BitsPerPixel" "$g_iScreenBpp"
155
156	${LogVerbose} "Custom mode set to $g_iScreenXx$g_iScreenY, $g_iScreenBpp BPP on next restart."
157
158	exit:
159
160	FunctionEnd
161
162	!macro W2K_CleanupCerts un
163	;;
164	; Removes certificates and the certificate utility.
165	;
166	; Since the certificate collection depends on the build config and have
167	; changed over time, we always clean it up before installation.
168	;
169	Function ${un}W2K_CleanupCerts
170	Delete /REBOOTOK "$INSTDIR\cert\vbox.cer"
171	Delete /REBOOTOK "$INSTDIR\cert\vbox-root.cer"
172	Delete /REBOOTOK "$INSTDIR\cert\vbox-timestamp-root.cer"
173	Delete /REBOOTOK "$INSTDIR\cert\vbox-sha1.cer"
174	Delete /REBOOTOK "$INSTDIR\cert\vbox-sha1-root.cer"
175	Delete /REBOOTOK "$INSTDIR\cert\vbox-sha1-timestamp-root.cer"
176	Delete /REBOOTOK "$INSTDIR\cert\vbox-sha256.cer"
177	Delete /REBOOTOK "$INSTDIR\cert\vbox-sha256-root.cer"
178	Delete /REBOOTOK "$INSTDIR\cert\vbox-sha256-timestamp-root.cer"
179	Delete /REBOOTOK "$INSTDIR\cert\vbox-sha256-r3.cer"
180	Delete /REBOOTOK "$INSTDIR\cert\vbox-sha256-r3-root.cer"
181	Delete /REBOOTOK "$INSTDIR\cert\vbox-sha256-r3-timestamp-root.cer"
182	Delete /REBOOTOK "$INSTDIR\cert\vbox-legacy-timestamp-ca.cer"
183	Delete /REBOOTOK "$INSTDIR\cert\root-versign-pca3-g5.cer" ; only for a while during 7.0 beta phase
184	Delete /REBOOTOK "$INSTDIR\cert\root-digicert-assured-id.cer" ; ditto
185	Delete /REBOOTOK "$INSTDIR\cert\root-digicert-high-assurance-ev.cer" ; ditto
186	Delete /REBOOTOK "$INSTDIR\cert\VBoxCertUtil.exe"
187	RMDir /REBOOTOK "$INSTDIR\cert"
188	FunctionEnd
189	!macroend
190	!insertmacro W2K_CleanupCerts ""
191	!insertmacro W2K_CleanupCerts "un."
192
193
194	!macro W2K_CleanupObsoleteFiles un
195	;;
196	; Removes files we're no longer shipping.
197	;
198	; During installation this step should be taken before copy files over in case
199	; the list gets out of sync and we start shipping files on it. That way it
200	; doesn't much matter as the file will be restore afterwards.
201	;
202	Function ${un}W2K_CleanupObsoleteFiles
203	Delete /REBOOTOK "$INSTDIR\VBoxWHQLFake.exe" ; Removed in r152293 (runup to 7.0).
204	Delete /REBOOTOK "$INSTDIR\VBoxICD.dll" ; Removed in r151892 (runup to 7.0).
205	FunctionEnd
206	!macroend
207	!insertmacro W2K_CleanupObsoleteFiles ""
208	!insertmacro W2K_CleanupObsoleteFiles "un."
209
210
211	!ifdef VBOX_SIGN_ADDITIONS
212	;;
213	; Run VBoxCertUtil to install the given certificate if absent on the system.
214	;
215	; @param pop1 The certificate file.
216	; @param pop2 Short description.
217	;
218	Function W2K_InstallRootCert
219	; Prolog: Save $0 & $1 and move the parameters into them.
220	Push $0
221	Exch 2
222	Push $1
223	Exch 2
224	Pop $0 ; Filename
225	Pop $1 ; Description.
226
227	; Do the work.
228	${LogVerbose} "Installing $1 ('$0') if missing ..."
229	${CmdExecute} "$\"$INSTDIR\cert\VBoxCertUtil.exe$\" add-root --add-if-new $\"$INSTDIR\cert\$0$\"" 'non-zero-exitcode=abort'
230
231	; Epilog: Restore $0 & $1 (we return nothing).
232	Pop $2
233	Pop $1
234	Pop $0
235	FunctionEnd
236	!endif
237
238	Function W2K_Prepare
239	; Save registers
240	Push $R0
241	Push $R1
242	Push $R2
243	Push $R3
244	Push $R4
245
246	${If} $g_bNoVBoxServiceExit == "false"
247	; Stop / kill VBoxService
248	Call StopVBoxService
249	${EndIf}
250
251	${If} $g_bNoVBoxTrayExit == "false"
252	; Stop / kill VBoxTray
253	Call StopVBoxTray
254	${EndIf}
255
256	; Delete VBoxService from registry
257	DeleteRegValue HKLM "Software\Microsoft\Windows\CurrentVersion\Run" "VBoxService"
258
259	; Delete old VBoxService.exe from install directory (replaced by VBoxTray.exe)
260	Delete /REBOOTOK "$INSTDIR\VBoxService.exe"
261
262	; Ditch old certificates and stuff to avoid confusion if we now ship fewer / different files.
263	Call W2K_CleanupCerts
264
265	!ifdef VBOX_SIGN_ADDITIONS
266	;
267	; When installing signed GAs, we need to make sure that the associated root
268	; certs are present, we use VBoxCertUtil for this task.
269	;
270	${LogVerbose} "Installing VBoxCertUtil.exe ..."
271	SetOutPath "$INSTDIR\cert"
272	FILE "$%PATH_OUT%\bin\additions\VBoxCertUtil.exe"
273	!if "$%VBOX_GA_CERT_ROOT_SHA1%" != "none"
274	FILE "$%PATH_OUT%\bin\additions\$%VBOX_GA_CERT_ROOT_SHA1%"
275	!endif
276	!if "$%VBOX_GA_CERT_ROOT_SHA1_TS%" != "none"
277	FILE "$%PATH_OUT%\bin\additions\$%VBOX_GA_CERT_ROOT_SHA1_TS%"
278	!endif
279	!if "$%VBOX_GA_CERT_ROOT_SHA2%" != "none"
280	FILE "$%PATH_OUT%\bin\additions\$%VBOX_GA_CERT_ROOT_SHA2%"
281	!endif
282	!if "$%VBOX_GA_CERT_ROOT_SHA2_TS%" != "none"
283	FILE "$%PATH_OUT%\bin\additions\$%VBOX_GA_CERT_ROOT_SHA2_TS%"
284	!endif
285	!if "$%VBOX_GA_CERT_ROOT_SHA2_R3%" != "none"
286	FILE "$%PATH_OUT%\bin\additions\$%VBOX_GA_CERT_ROOT_SHA2_R3%"
287	!endif
288	!if "$%VBOX_GA_CERT_ROOT_SHA2_R3_TS%" != "none"
289	FILE "$%PATH_OUT%\bin\additions\$%VBOX_GA_CERT_ROOT_SHA2_R3_TS%"
290	!endif
291
292	;
293	; Install the certificates if missing.
294	;
295	!if "$%VBOX_GA_CERT_ROOT_SHA1%" != "none"
296	Push "SHA-1 root"
297	Push "$%VBOX_GA_CERT_ROOT_SHA1%"
298	Call W2K_InstallRootCert
299	!endif
300	!if "$%VBOX_GA_CERT_ROOT_SHA1_TS%" != "none"
301	!ifdef VBOX_WITH_VBOX_LEGACY_TS_CA
302	; If not explicitly specified, let the detected Windows version decide what
303	; to do. On guest OSes < Windows 10 we always go for the PreW10 security
304	; catalog files (.cat) and there we install our legacy timestamp CA by default.
305	${If} $g_bInstallTimestampCA == "unset"
306	${AndIf} $g_strWinVersion != "10"
307	StrCpy $g_bInstallTimestampCA "true"
308	${EndIf}
309	${If} $g_bInstallTimestampCA == "true"
310	Push "SHA-1 timestamp root"
311	Push "$%VBOX_GA_CERT_ROOT_SHA1_TS%"
312	Call W2K_InstallRootCert
313	${EndIf}
314	!else
315	Push "SHA-1 timestamp root"
316	Push "$%VBOX_GA_CERT_ROOT_SHA1_TS%"
317	Call W2K_InstallRootCert
318	!endif ; VBOX_WITH_VBOX_LEGACY_TS_CA
319	!endif
320
321	; XP sp3 and later can make use of SHA-2 certs. Windows 2000 cannot.
322	; Note that VBOX_GA_CERT_ROOT_SHA1 may be a SHA-2 cert, the hash algorithm
323	; refers to the windows signature structures not the certificate.
324	${If} $g_strWinVersion != "2000"
325	!if "$%VBOX_GA_CERT_ROOT_SHA2%" != "none"
326	Push "SHA-2 root"
327	Push "$%VBOX_GA_CERT_ROOT_SHA2%"
328	Call W2K_InstallRootCert
329	!endif
330	!if "$%VBOX_GA_CERT_ROOT_SHA2_TS%" != "none"
331	Push "SHA-2 timestamp root"
332	Push "$%VBOX_GA_CERT_ROOT_SHA2_TS%"
333	Call W2K_InstallRootCert
334	!endif
335	!if "$%VBOX_GA_CERT_ROOT_SHA2_R3%" != "none"
336	Push "SHA-2 ring-3 root"
337	Push "$%VBOX_GA_CERT_ROOT_SHA2_R3%"
338	Call W2K_InstallRootCert
339	!endif
340	!if "$%VBOX_GA_CERT_ROOT_SHA2_R3_TS%" != "none"
341	Push "SHA-2 ring-3 timestamp root"
342	Push "$%VBOX_GA_CERT_ROOT_SHA2_R3_TS%"
343	Call W2K_InstallRootCert
344	!endif
345	${EndIf}
346	!endif ; VBOX_SIGN_ADDITIONS
347
348	; Restore registers
349	Pop $R4
350	Pop $R3
351	Pop $R2
352	Pop $R1
353	Pop $R0
354	FunctionEnd
355
356	Function W2K_CopyFiles
357
358	Push $0
359	SetOutPath "$INSTDIR"
360
361	!if $%KBUILD_TARGET_ARCH% != "arm64" ;; @todo win.arm64: Make VBoxVideo and friends build on arm.
362	; Video driver
363	FILE "$%PATH_OUT%\bin\additions\VBoxVideo.sys"
364	FILE "$%PATH_OUT%\bin\additions\VBoxDisp.dll"
365	!endif ; $%KBUILD_TARGET_ARCH% != "arm64"
366
367	; Mouse driver
368	FILE "$%PATH_OUT%\bin\additions\VBoxMouse.sys"
369	FILE "$%PATH_OUT%\bin\additions\VBoxMouse.inf"
370	!ifdef VBOX_SIGN_ADDITIONS
371	!if $%KBUILD_TARGET_ARCH% == "arm64"
372	FILE "$%PATH_OUT%\bin\additions\VBoxMouse.cat"
373	!else
374	${If} $g_strWinVersion == "10"
375	FILE "$%PATH_OUT%\bin\additions\VBoxMouse.cat"
376	${Else}
377	FILE "/oname=VBoxMouse.cat" "$%PATH_OUT%\bin\additions\VBoxMouse-PreW10.cat"
378	${EndIf}
379	!endif
380	!endif
381
382	; Guest driver
383	FILE "$%PATH_OUT%\bin\additions\VBoxGuest.sys"
384	FILE "$%PATH_OUT%\bin\additions\VBoxGuest.inf"
385	!if $%KBUILD_TARGET_ARCH% == "x86"
386	${If} $g_strEarlyNTDrvInfix != ""
387	FILE "$%PATH_OUT%\bin\additions\VBoxGuestEarlyNT.inf"
388	!ifdef VBOX_SIGN_ADDITIONS
389	FILE "$%PATH_OUT%\bin\additions\VBoxGuestEarlyNT.cat"
390	!endif
391	${EndIf}
392	!endif
393	!ifdef VBOX_SIGN_ADDITIONS
394	!if $%KBUILD_TARGET_ARCH% == "arm64"
395	FILE "$%PATH_OUT%\bin\additions\VBoxGuest.cat"
396	!else
397	${If} $g_strWinVersion == "10"
398	FILE "$%PATH_OUT%\bin\additions\VBoxGuest.cat"
399	${Else}
400	FILE "/oname=VBoxGuest.cat" "$%PATH_OUT%\bin\additions\VBoxGuest-PreW10.cat"
401	${EndIf}
402	!endif
403	!endif
404
405	; Guest driver files
406	FILE "$%PATH_OUT%\bin\additions\VBoxTray.exe"
407	FILE "$%PATH_OUT%\bin\additions\VBoxControl.exe"
408
409	; Misc
410	!ifdef VBOX_WITH_ADDITIONS_SHIPPING_AUDIO_TEST
411	FILE "$%PATH_OUT%\bin\additions\VBoxAudioTest.exe"
412	!endif
413
414	SetOutPath $g_strSystemDir
415
416	; VBoxService
417	${If} $g_bNoVBoxServiceExit == "false"
418	; VBoxService has been terminated before, so just install the file
419	; in the regular way
420	FILE "$%PATH_OUT%\bin\additions\VBoxService.exe"
421	${Else}
422	; VBoxService is in use and wasn't terminated intentionally. So extract the
423	; new version into a temporary location and install it on next reboot
424	Push $0
425	ClearErrors
426	GetTempFileName $0
427	IfErrors 0 +3
428	${LogVerbose} "Error getting temp file for VBoxService.exe"
429	StrCpy "$0" "$INSTDIR\VBoxServiceTemp.exe"
430	${LogVerbose} "VBoxService is in use, will be installed on next reboot (from '$0')"
431	File "/oname=$0" "$%PATH_OUT%\bin\additions\VBoxService.exe"
432	IfErrors 0 +2
433	${LogVerbose} "Error copying VBoxService.exe to '$0'"
434	Rename /REBOOTOK "$0" "$g_strSystemDir\VBoxService.exe"
435	IfErrors 0 +2
436	${LogVerbose} "Error renaming '$0' to '$g_strSystemDir\VBoxService.exe'"
437	Pop $0
438	${EndIf}
439
440	!if $%VBOX_WITH_WDDM% == "1"
441	${If} $g_bWithWDDM == "true"
442	; WDDM Video driver
443	SetOutPath "$INSTDIR"
444
445	!ifdef VBOX_SIGN_ADDITIONS
446	!if $%KBUILD_TARGET_ARCH% == "arm64"
447	FILE "$%PATH_OUT%\bin\additions\VBoxWddm.cat"
448	!else
449	${If} $g_strWinVersion == "10"
450	FILE "$%PATH_OUT%\bin\additions\VBoxWddm.cat"
451	${Else}
452	FILE "/oname=VBoxWddm.cat" "$%PATH_OUT%\bin\additions\VBoxWddm-PreW10.cat"
453	${EndIf}
454	!endif
455	!endif
456	FILE "$%PATH_OUT%\bin\additions\VBoxWddm.sys"
457	FILE "$%PATH_OUT%\bin\additions\VBoxWddm.inf"
458
459	FILE "$%PATH_OUT%\bin\additions\VBoxDispD3D.dll"
460	!if $%VBOX_WITH_WDDM_DX% == "1"
461	FILE "$%PATH_OUT%\bin\additions\VBoxDX.dll"
462	!endif
463	!if $%VBOX_WITH_MESA3D% == "1"
464	FILE "$%PATH_OUT%\bin\additions\VBoxNine.dll"
465	FILE "$%PATH_OUT%\bin\additions\VBoxSVGA.dll"
466	FILE "$%PATH_OUT%\bin\additions\VBoxGL.dll"
467	!endif
468
469	!if $%KBUILD_TARGET_ARCH% == "amd64"
470	FILE "$%PATH_OUT%\bin\additions\VBoxDispD3D-x86.dll"
471	!if $%VBOX_WITH_WDDM_DX% == "1"
472	FILE "$%PATH_OUT%\bin\additions\VBoxDX-x86.dll"
473	!endif
474	!if $%VBOX_WITH_MESA3D% == "1"
475	FILE "$%PATH_OUT%\bin\additions\VBoxNine-x86.dll"
476	FILE "$%PATH_OUT%\bin\additions\VBoxSVGA-x86.dll"
477	FILE "$%PATH_OUT%\bin\additions\VBoxGL-x86.dll"
478	!endif
479	!endif ; $%KBUILD_TARGET_ARCH% == "amd64"
480
481	${EndIf}
482	!endif ; $%VBOX_WITH_WDDM% == "1"
483
484	Pop $0
485
486	FunctionEnd
487
488
489	Function W2K_InstallFiles
490
491	; The Shared Folder IFS goes to the system directory
492	!if $%BUILD_TARGET_ARCH% == "x86"
493	; On x86 we have to use a different shared folder driver linked against an older RDBSS for Windows 7 and older.
494	${If} $g_strWinVersion == "2000"
495	${OrIf} $g_strWinVersion == "XP"
496	${OrIf} $g_strWinVersion == "2003"
497	${OrIf} $g_strWinVersion == "Vista"
498	${OrIf} $g_strWinVersion == "7"
499	!insertmacro ReplaceDLL "$%PATH_OUT%\bin\additions\VBoxSFW2K.sys" "$g_strSystemDir\drivers\VBoxSF.sys" "$INSTDIR"
500	${Else}
501	!insertmacro ReplaceDLL "$%PATH_OUT%\bin\additions\VBoxSF.sys" "$g_strSystemDir\drivers\VBoxSF.sys" "$INSTDIR"
502	${EndIf}
503	!else
504	!insertmacro ReplaceDLL "$%PATH_OUT%\bin\additions\VBoxSF.sys" "$g_strSystemDir\drivers\VBoxSF.sys" "$INSTDIR"
505	!endif
506
507	!insertmacro ReplaceDLL "$%PATH_OUT%\bin\additions\VBoxMRXNP.dll" "$g_strSystemDir\VBoxMRXNP.dll" "$INSTDIR"
508	AccessControl::GrantOnFile "$g_strSystemDir\VBoxMRXNP.dll" "(BU)" "GenericRead"
509	!if $%KBUILD_TARGET_ARCH% == "amd64"
510	; Only 64-bit installer: Copy the 32-bit DLL for 32 bit applications.
511	!insertmacro ReplaceDLL "$%PATH_OUT%\bin\additions\VBoxMRXNP-x86.dll" "$g_strSysWow64\VBoxMRXNP.dll" "$INSTDIR"
512	AccessControl::GrantOnFile "$g_strSysWow64\VBoxMRXNP.dll" "(BU)" "GenericRead"
513	!endif
514
515	; The VBoxTray hook DLL also goes to the system directory; it might be locked
516	!insertmacro ReplaceDLL "$%PATH_OUT%\bin\additions\VBoxHook.dll" "$g_strSystemDir\VBoxHook.dll" "$INSTDIR"
517	AccessControl::GrantOnFile "$g_strSystemDir\VBoxHook.dll" "(BU)" "GenericRead"
518
519	${LogVerbose} "Installing drivers ..."
520
521	Push $0 ; For fetching results
522
523	SetOutPath "$INSTDIR"
524
525	${If} $g_bNoGuestDrv == "false"
526	${LogVerbose} "Installing guest driver ..."
527	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" driver install $\"$INSTDIR\VBoxGuest$g_strEarlyNTDrvInfix.inf$\" $\"PCI\VEN_80EE&DEV_CAFE$\" $\"$INSTDIR\install_drivers.log$\"" 'non-zero-exitcode=abort'
528	${Else}
529	${LogVerbose} "Guest driver installation skipped!"
530	${EndIf}
531
532	!if $%KBUILD_TARGET_ARCH% != "arm64" ;; @todo win.arm64: Make VBoxVideo and friends build on arm.
533	${If} $g_bNoVideoDrv == "false"
534	${If} $g_bWithWDDM == "true"
535	${LogVerbose} "Installing WDDM video driver..."
536	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" driver install $\"$INSTDIR\VBoxWddm.inf$\" $\"$\" $\"$INSTDIR\install_drivers.log$\"" 'non-zero-exitcode=abort'
537	${Else}
538	${LogVerbose} "Installing video driver ..."
539	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" driver install $\"$INSTDIR\VBoxVideo$g_strEarlyNTDrvInfix.inf$\" $\"$\" $\"$INSTDIR\install_drivers.log$\"" 'non-zero-exitcode=abort'
540	${EndIf}
541	${Else}
542	${LogVerbose} "Video driver installation skipped!"
543	${EndIf}
544	!endif ; $%KBUILD_TARGET_ARCH% != "arm64"
545
546	;
547	; Mouse driver.
548	;
549	${If} $g_bNoMouseDrv == "false"
550	${LogVerbose} "Installing mouse driver ..."
551	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" driver executeinf $\"$INSTDIR\VBoxMouse.inf$\" $\"DefaultInstall.NT$%KBUILD_TARGET_ARCH%$\" $\"$INSTDIR\install_drivers.log$\"" 'non-zero-exitcode=abort'
552	${Else}
553	${LogVerbose} "Mouse driver installation skipped!"
554	${EndIf}
555
556	;
557	; Create the VBoxService service
558	; No need to stop/remove the service here! Do this only on uninstallation!
559	;
560	${LogVerbose} "Installing VirtualBox service ..."
561	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" service create $\"VBoxService$\" $\"VirtualBox Guest Additions Service$\" 16 2 $\"%SystemRoot%\System32\VBoxService.exe$\" $\"Base$\"" 'non-zero-exitcode=abort'
562
563	; Set service description
564	WriteRegStr HKLM "SYSTEM\CurrentControlSet\Services\VBoxService" "Description" "Manages VM runtime information, time synchronization, remote sysprep execution and miscellaneous utilities for guest operating systems."
565
566
567	;
568	; Shared folders.
569	;
570	${LogVerbose} "Installing Shared Folders service ..."
571
572	; Create the Shared Folders service ...
573	; No need to stop/remove the service here! Do this only on uninstallation!
574	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" service create $\"VBoxSF$\" $\"VirtualBox Shared Folders$\" 2 1 $\"\SystemRoot\System32\drivers\VBoxSF.sys$\" $\"NetworkProvider$\"" 'non-zero-exitcode=abort'
575
576	; ... and the link to the network provider
577	WriteRegStr HKLM "SYSTEM\CurrentControlSet\Services\VBoxSF\NetworkProvider" "DeviceName" "\Device\VBoxMiniRdr"
578	WriteRegStr HKLM "SYSTEM\CurrentControlSet\Services\VBoxSF\NetworkProvider" "Name" "VirtualBox Shared Folders"
579	WriteRegStr HKLM "SYSTEM\CurrentControlSet\Services\VBoxSF\NetworkProvider" "ProviderPath" "$SYSDIR\VBoxMRXNP.dll"
580
581	; Add default network providers (if not present or corrupted)
582	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" netprovider add WebClient" 'non-zero-exitcode=abort'
583	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" netprovider add LanmanWorkstation" 'non-zero-exitcode=abort'
584	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" netprovider add RDPNP" 'non-zero-exitcode=abort'
585
586	; Add the shared folders network provider
587	${LogVerbose} "Adding network provider (Order = $g_iSfOrder) ..."
588	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" netprovider add VBoxSF $g_iSfOrder" 'non-zero-exitcode=abort'
589
590
591	Pop $0
592
593	FunctionEnd
594
595	Function W2K_Main
596
597	SetOutPath "$INSTDIR"
598	SetOverwrite on
599
600	Call W2K_Prepare
601	Call W2K_CleanupObsoleteFiles
602	Call W2K_CopyFiles
603	Call W2K_InstallFiles
604	Call W2K_SetVideoResolution
605
606	FunctionEnd
607
608	!macro W2K_UninstallInstDir un
609	Function ${un}W2K_UninstallInstDir
610
611	Delete /REBOOTOK "$INSTDIR\VBoxVideo.sys"
612	Delete /REBOOTOK "$INSTDIR\VBoxVideo.inf"
613	Delete /REBOOTOK "$INSTDIR\VBoxVideo.cat"
614	Delete /REBOOTOK "$INSTDIR\VBoxVideoEarlyNT.inf"
615	Delete /REBOOTOK "$INSTDIR\VBoxVideoEarlyNT.cat"
616	Delete /REBOOTOK "$INSTDIR\VBoxDisp.dll"
617
618	Delete /REBOOTOK "$INSTDIR\VBoxMouse.sys"
619	Delete /REBOOTOK "$INSTDIR\VBoxMouse.inf"
620	Delete /REBOOTOK "$INSTDIR\VBoxMouse.cat"
621
622	Delete /REBOOTOK "$INSTDIR\VBoxTray.exe"
623
624	Delete /REBOOTOK "$INSTDIR\VBoxGuest.sys"
625	Delete /REBOOTOK "$INSTDIR\VBoxGuest.inf"
626	Delete /REBOOTOK "$INSTDIR\VBoxGuest.cat"
627	Delete /REBOOTOK "$INSTDIR\VBoxGuestEarlyNT.inf"
628	Delete /REBOOTOK "$INSTDIR\VBoxGuestEarlyNT.cat"
629
630	Delete /REBOOTOK "$INSTDIR\VBCoInst.dll" ; Deprecated, does not get installed anymore
631	Delete /REBOOTOK "$INSTDIR\VBoxControl.exe"
632	Delete /REBOOTOK "$INSTDIR\VBoxService.exe" ; Deprecated, does not get installed anymore
633
634	!if $%VBOX_WITH_WDDM% == "1"
635	Delete /REBOOTOK "$INSTDIR\VBoxWddm.cat"
636	Delete /REBOOTOK "$INSTDIR\VBoxWddm.sys"
637	Delete /REBOOTOK "$INSTDIR\VBoxWddm.inf"
638	; Obsolete files begin
639	Delete /REBOOTOK "$INSTDIR\VBoxVideoWddm.cat"
640	Delete /REBOOTOK "$INSTDIR\VBoxVideoWddm.sys"
641	Delete /REBOOTOK "$INSTDIR\VBoxVideoWddm.inf"
642	Delete /REBOOTOK "$INSTDIR\VBoxVideoW8.cat"
643	Delete /REBOOTOK "$INSTDIR\VBoxVideoW8.sys"
644	Delete /REBOOTOK "$INSTDIR\VBoxVideoW8.inf"
645	; Obsolete files end
646	Delete /REBOOTOK "$INSTDIR\VBoxDispD3D.dll"
647	!if $%VBOX_WITH_WDDM_DX% == "1"
648	Delete /REBOOTOK "$INSTDIR\VBoxDX.dll"
649	!endif
650	!if $%VBOX_WITH_MESA3D% == "1"
651	Delete /REBOOTOK "$INSTDIR\VBoxNine.dll"
652	Delete /REBOOTOK "$INSTDIR\VBoxSVGA.dll"
653	Delete /REBOOTOK "$INSTDIR\VBoxICD.dll"
654	Delete /REBOOTOK "$INSTDIR\VBoxGL.dll"
655	!endif
656
657	Delete /REBOOTOK "$INSTDIR\VBoxD3D9wddm.dll"
658	Delete /REBOOTOK "$INSTDIR\wined3dwddm.dll"
659	; Try to delete libWine in case it is there from old installation
660	Delete /REBOOTOK "$INSTDIR\libWine.dll"
661
662	!if $%KBUILD_TARGET_ARCH% == "amd64"
663	Delete /REBOOTOK "$INSTDIR\VBoxDispD3D-x86.dll"
664	!if $%VBOX_WITH_WDDM_DX% == "1"
665	Delete /REBOOTOK "$INSTDIR\VBoxDX-x86.dll"
666	!endif
667	!if $%VBOX_WITH_MESA3D% == "1"
668	Delete /REBOOTOK "$INSTDIR\VBoxNine-x86.dll"
669	Delete /REBOOTOK "$INSTDIR\VBoxSVGA-x86.dll"
670	Delete /REBOOTOK "$INSTDIR\VBoxICD-x86.dll"
671	Delete /REBOOTOK "$INSTDIR\VBoxGL-x86.dll"
672	!endif
673
674	Delete /REBOOTOK "$INSTDIR\VBoxD3D9wddm-x86.dll"
675	Delete /REBOOTOK "$INSTDIR\wined3dwddm-x86.dll"
676	!endif ; $%KBUILD_TARGET_ARCH% == "amd64"
677	!endif ; $%VBOX_WITH_WDDM% == "1"
678
679	; Certificates, utility and directory.
680	Call ${un}W2K_CleanupCerts
681
682	; Log files
683	Delete /REBOOTOK "$INSTDIR\install.log"
684	Delete /REBOOTOK "$INSTDIR\install_ui.log"
685	Delete /REBOOTOK "$INSTDIR\install_drivers.log"
686
687	; Obsolete stuff.
688	Call ${un}W2K_CleanupObsoleteFiles
689
690	FunctionEnd
691	!macroend
692	;!insertmacro W2K_UninstallInstDir "" - only .un version used
693	!insertmacro W2K_UninstallInstDir "un."
694
695	!macro W2K_Uninstall un
696	Function ${un}W2K_Uninstall
697
698	Push $0
699
700	; Remove VirtualBox video driver
701	${LogVerbose} "Uninstalling video driver ..."
702	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" driver uninstall $\"$INSTDIR\VBoxVideo$g_strEarlyNTDrvInfix.inf$\" $\"VBoxVideo*$\"" 'non-zero-exitcode=log'
703	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" service delete VBoxVideo" 'non-zero-exitcode=log'
704	Delete /REBOOTOK "$g_strSystemDir\drivers\VBoxVideo.sys"
705	Delete /REBOOTOK "$g_strSystemDir\VBoxDisp.dll"
706
707	; Remove video driver
708	!if $%VBOX_WITH_WDDM% == "1"
709
710	${LogVerbose} "Uninstalling WDDM video driver..."
711	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" driver uninstall $\"$INSTDIR\VBoxWddm.inf$\" $\"VBoxWddm*$\"" 'non-zero-exitcode=log'
712	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" service delete VBoxWddm" 'non-zero-exitcode=log'
713	;misha> @todo driver file removal (as well as service removal) should be done as driver package uninstall
714	; could be done with "VBoxDrvInst.exe /u", e.g. by passing additional arg to it denoting that driver package is to be uninstalled
715	Delete /REBOOTOK "$g_strSystemDir\drivers\VBoxWddm.sys"
716
717	; Obsolete files begin
718	${LogVerbose} "Uninstalling WDDM video driver for Windows 8..."
719	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" driver uninstall $\"$INSTDIR\VBoxVideoW8.inf$\" $\"VBoxVideoW8*$\"" 'non-zero-exitcode=log'
720	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" service delete VBoxVideoW8" 'non-zero-exitcode=log'
721	;misha> @todo driver file removal (as well as service removal) should be done as driver package uninstall
722	; could be done with "VBoxDrvInst.exe /u", e.g. by passing additional arg to it denoting that driver package is to be uninstalled
723	Delete /REBOOTOK "$g_strSystemDir\drivers\VBoxVideoW8.sys"
724
725	${LogVerbose} "Uninstalling WDDM video driver for Windows Vista and 7..."
726	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" driver uninstall $\"$INSTDIR\VBoxVideoWddm.inf$\" $\"VBoxVideoWddm*$\"" 'non-zero-exitcode=log'
727	; Always try to remove both VBoxVideoWddm & VBoxVideo services no matter what is installed currently
728	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" service delete VBoxVideoWddm" 'non-zero-exitcode=log'
729	;misha> @todo driver file removal (as well as service removal) should be done as driver package uninstall
730	; could be done with "VBoxDrvInst.exe /u", e.g. by passing additional arg to it denoting that driver package is to be uninstalled
731	Delete /REBOOTOK "$g_strSystemDir\drivers\VBoxVideoWddm.sys"
732	; Obsolete files end
733
734	Delete /REBOOTOK "$g_strSystemDir\VBoxDispD3D.dll"
735	!if $%KBUILD_TARGET_ARCH% == "amd64"
736	Delete /REBOOTOK "$g_strSysWow64\VBoxDispD3D-x86.dll"
737	!endif
738
739	!if $%VBOX_WITH_WDDM_DX% == "1"
740	Delete /REBOOTOK "$g_strSystemDir\VBoxDX.dll"
741	!if $%KBUILD_TARGET_ARCH% == "amd64"
742	Delete /REBOOTOK "$g_strSysWow64\VBoxDX-x86.dll"
743	!endif
744	!endif
745
746	!if $%VBOX_WITH_MESA3D% == "1"
747	Delete /REBOOTOK "$g_strSystemDir\VBoxNine.dll"
748	Delete /REBOOTOK "$g_strSystemDir\VBoxSVGA.dll"
749	Delete /REBOOTOK "$g_strSystemDir\VBoxICD.dll"
750	Delete /REBOOTOK "$g_strSystemDir\VBoxGL.dll"
751
752	!if $%KBUILD_TARGET_ARCH% == "amd64"
753	Delete /REBOOTOK "$g_strSysWow64\VBoxNine-x86.dll"
754	Delete /REBOOTOK "$g_strSysWow64\VBoxSVGA-x86.dll"
755	Delete /REBOOTOK "$g_strSysWow64\VBoxICD-x86.dll"
756	Delete /REBOOTOK "$g_strSysWow64\VBoxGL-x86.dll"
757	!endif
758	!endif
759	!endif ; $%VBOX_WITH_WDDM% == "1"
760
761	; Remove mouse driver
762	${LogVerbose} "Removing mouse driver ..."
763	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" driver uninstall $\"$INSTDIR\VBoxMouse.inf$\" $\"VBoxMouse*$\"" 'non-zero-exitcode=log'
764	; @todo Fix VBoxMouse.inf to also take care of the next line!
765	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" registry delmultisz $\"SYSTEM\CurrentControlSet\Control\Class\{4D36E96F-E325-11CE-BFC1-08002BE10318}$\" $\"UpperFilters$\" $\"VBoxMouse$\"" 'non-zero-exitcode=log'
766
767	; Delete the VBoxService service
768	Call ${un}StopVBoxService
769	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" service delete VBoxService" 'non-zero-exitcode=log'
770	DeleteRegValue HKLM "Software\Microsoft\Windows\CurrentVersion\Run" "VBoxService"
771	Delete /REBOOTOK "$g_strSystemDir\VBoxService.exe"
772
773	; VBoxGINA
774	Delete /REBOOTOK "$g_strSystemDir\VBoxGINA.dll"
775	ReadRegStr $0 HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\WinLogon" "GinaDLL"
776	${If} $0 == "VBoxGINA.dll"
777	${LogVerbose} "Removing auto-logon support ..."
778	DeleteRegValue HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\WinLogon" "GinaDLL"
779	${EndIf}
780	DeleteRegKey HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\WinLogon\Notify\VBoxGINA"
781
782	; Delete VBoxTray
783	Call ${un}StopVBoxTray
784	DeleteRegValue HKLM "Software\Microsoft\Windows\CurrentVersion\Run" "VBoxTray"
785
786	; Remove guest driver
787	${LogVerbose} "Removing guest driver ..."
788	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" driver uninstall $\"$INSTDIR\VBoxGuest$g_strEarlyNTDrvInfix.inf$\" $\"VBoxGuest*$\"" 'non-zero-exitcode=log'
789
790	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" service delete VBoxGuest" 'non-zero-exitcode=log'
791	Delete /REBOOTOK "$g_strSystemDir\drivers\VBoxGuest.sys"
792	Delete /REBOOTOK "$g_strSystemDir\VBCoInst.dll" ; Deprecated, does not get installed anymore
793	Delete /REBOOTOK "$g_strSystemDir\VBoxTray.exe"
794	Delete /REBOOTOK "$g_strSystemDir\VBoxHook.dll"
795	DeleteRegValue HKLM "Software\Microsoft\Windows\CurrentVersion\Run" "VBoxTray" ; Remove VBoxTray autorun
796	Delete /REBOOTOK "$g_strSystemDir\VBoxControl.exe"
797
798	; Remove shared folders driver
799	${LogVerbose} "Removing shared folders driver ..."
800	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" netprovider remove VBoxSF" 'non-zero-exitcode=log'
801	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" service delete VBoxSF" 'non-zero-exitcode=log'
802	Delete /REBOOTOK "$g_strSystemDir\VBoxMRXNP.dll" ; The network provider DLL will be locked
803	!if $%KBUILD_TARGET_ARCH% == "amd64"
804	; Only 64-bit installer: Also remove 32-bit DLLs on 64-bit target arch in Wow64 node
805	Delete /REBOOTOK "$g_strSysWow64\VBoxMRXNP.dll"
806	!endif ; amd64
807	Delete /REBOOTOK "$g_strSystemDir\drivers\VBoxSF.sys"
808
809	Pop $0
810
811	FunctionEnd
812	!macroend
813	!ifndef UNINSTALLER_ONLY
814	!insertmacro W2K_Uninstall ""
815	!endif
816	!insertmacro W2K_Uninstall "un."

Note: See TracBrowser for help on using the repository browser.

source: vbox/trunk/src/VBox/Additions/WINNT/Installer/VBoxGuestAdditionsW2KXP.nsh@ 106844

Download in other formats: