PackDriversForSubmission.cmd@ 106031

Last change on this file since 106031 was 104863, checked in by vboxsync, 6 months ago
Config.kmk, ExtPacks/Puel, Installer/win, ValidationKit, tools/bin: bugref:10690: Rebranding ExtPack; No webtools, they will go as separate commit.
Property svn:eol-style set to `CRLF` Property svn:keywords set to `Author Date Id Revision`
File size: 15.6 KB

Line
1	@echo off
2	rem $Id: PackDriversForSubmission.cmd 104863 2024-06-06 14:29:21Z vboxsync $
3	rem rem @file
4	rem Windows NT batch script for preparing for signing submission.
5	rem
6
7	rem
8	rem Copyright (C) 2018-2023 Oracle and/or its affiliates.
9	rem
10	rem This file is part of VirtualBox base platform packages, as
11	rem available from https://www.virtualbox.org.
12	rem
13	rem This program is free software; you can redistribute it and/or
14	rem modify it under the terms of the GNU General Public License
15	rem as published by the Free Software Foundation, in version 3 of the
16	rem License.
17	rem
18	rem This program is distributed in the hope that it will be useful, but
19	rem WITHOUT ANY WARRANTY; without even the implied warranty of
20	rem MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
21	rem General Public License for more details.
22	rem
23	rem You should have received a copy of the GNU General Public License
24	rem along with this program; if not, see <https://www.gnu.org/licenses>.
25	rem
26	rem SPDX-License-Identifier: GPL-3.0-only
27	rem
28
29
30	setlocal ENABLEEXTENSIONS
31	setlocal
32
33	rem
34	rem Parse arguments.
35	rem
36	set _MY_OPT_BINDIR=..\bin
37	set _MY_OPT_PDBDIR=
38	set _MY_OPT_GADIR=
39	set _MY_OPT_WITH_MAIN=1
40	set _MY_OPT_WITH_PDB=1
41	set _MY_OPT_EXTPACK=
42	set _MY_OPT_NO_EXTRACT=0
43	set _MY_OPT_WITH_EXTPACK=1
44	set _MY_OPT_WITH_GA=0
45	set _MY_OPT_OUTPUT=
46	set _MY_OPT_DDF_FILE=
47	set _MY_OPT_ARCH=amd64
48
49	:argument_loop
50	if ".%1" == "." goto no_more_arguments
51
52	if ".%1" == ".-h" goto opt_h
53	if ".%1" == ".-?" goto opt_h
54	if ".%1" == "./h" goto opt_h
55	if ".%1" == "./H" goto opt_h
56	if ".%1" == "./?" goto opt_h
57	if ".%1" == ".-help" goto opt_h
58	if ".%1" == ".--help" goto opt_h
59
60	if ".%1" == ".-a" goto opt_a
61	if ".%1" == ".--arch" goto opt_a
62	if ".%1" == ".-b" goto opt_b
63	if ".%1" == ".--bindir" goto opt_b
64	if ".%1" == ".-d" goto opt_d
65	if ".%1" == ".--ddf" goto opt_d
66	if ".%1" == ".-e" goto opt_e
67	if ".%1" == ".--extpack" goto opt_e
68	if ".%1" == ".--no-main" goto opt_m
69	if ".%1" == ".-n" goto opt_n
70	if ".%1" == ".--no-pdb" goto opt_n
71	if ".%1" == ".-o" goto opt_o
72	if ".%1" == ".--output" goto opt_o
73	if ".%1" == ".-p" goto opt_p
74	if ".%1" == ".--pdb" goto opt_p
75	if ".%1" == ".-t" goto opt_p
76	if ".%1" == ".--no-extract" goto opt_t
77	if ".%1" == ".-x" goto opt_x
78	if ".%1" == ".--no-extpack" goto opt_x
79	if ".%1" == ".-g" goto opt_g
80	if ".%1" == ".--ga" goto opt_g
81	if ".%1" == ".--additions" goto opt_g
82	echo syntax error: Unknown option: %1
83	echo Try --help to list valid options.
84	goto end_failed
85
86	:argument_loop_next_with_value
87	shift
88	shift
89	goto argument_loop
90
91	:opt_a
92	if ".%~2" == "." goto syntax_error_missing_value
93	if not "%2" == "x86" if not "%2" == "amd64" goto syntax_error_unknown_arch
94	set _MY_OPT_ARCH=%~2
95	goto argument_loop_next_with_value
96
97	:opt_b
98	if ".%~2" == "." goto syntax_error_missing_value
99	set _MY_OPT_BINDIR=%~2
100	goto argument_loop_next_with_value
101
102	:opt_d
103	if ".%~2" == "." goto syntax_error_missing_value
104	set _MY_OPT_DDF_FILE=%~2
105	goto argument_loop_next_with_value
106
107	:opt_e
108	if ".%~2" == "." goto syntax_error_missing_value
109	set _MY_OPT_EXTPACK=%~2
110	goto argument_loop_next_with_value
111
112	:opt_h
113	echo This script creates a .cab file containing all drivers needing blessing from
114	echo Microsoft to run on recent Windows 10 installations.
115	echo .
116	echo Usage: PackDriversForSubmission.cmd [-b bindir] [-p pdbdir] [--no-main] [-n/--no-pdb] [-e expack]
117	echo [-x/--no-extpack] [-g/--ga/--additions] [-o output.cab] [-p output.ddf] [-a x86/amd64]
118	echo .
119	echo Warning! This script should normally be invoked from the repack directory w/o any parameters.
120	goto end_failed
121
122	:opt_m
123	set _MY_OPT_WITH_MAIN=0
124	shift
125	goto argument_loop
126
127	:opt_n
128	set _MY_OPT_WITH_PDB=0
129	shift
130	goto argument_loop
131
132	:opt_p
133	if ".%~2" == "." goto syntax_error_missing_value
134	set _MY_OPT_PDBDIR=%~2
135	goto argument_loop_next_with_value
136
137	:opt_o
138	if ".%~2" == "." goto syntax_error_missing_value
139	set _MY_OPT_OUTPUT=%~2
140	goto argument_loop_next_with_value
141
142	:opt_t
143	set _MY_OPT_NO_EXTRACT=1
144	shift
145	goto argument_loop
146
147	:opt_x
148	set _MY_OPT_WITH_EXTPACK=0
149	shift
150	goto argument_loop
151
152	:opt_g
153	set _MY_OPT_WITH_GA=1
154	shift
155	goto argument_loop
156
157	:syntax_error_missing_value
158	echo syntax error: missing or empty option value after %1
159	goto end_failed
160
161	:syntax_error_unknown_arch
162	echo syntax error: Unknown architecture: %2
163	goto end_failed
164
165	:error_bindir_does_not_exist
166	echo syntax error: Specified BIN directory does not exist: "%_MY_OPT_BINDIR%"
167	goto end_failed
168
169	:error_pdbdir_does_not_exist
170	echo syntax error: Specified PDB directory does not exist: "%_MY_OPT_PDBDIR%"
171	goto end_failed
172
173	:error_extpack_does_not_exist
174	echo syntax error: Specified extension pack does not exist: "%_MY_OPT_EXTPACK%"
175	goto end_failed
176
177	:error_additions_does_not_exist
178	echo syntax error: Specified guest additions does not exist: "%_MY_OPT_GADIR%"
179	goto end_failed
180
181
182	:error_output_exists
183	echo error: The output file already exist: "%_MY_OPT_OUTPUT%"
184	goto end_failed
185
186	:error_ddf_exists
187	echo error: The DDF file already exist: "%_MY_OPT_DDF_FILE%"
188	goto end_failed
189
190	:no_more_arguments
191	rem validate specified options
192	if not exist "%_MY_OPT_BINDIR%" goto error_bindir_does_not_exist
193
194	if "%_MY_OPT_WITH_PDB%" == "0" goto no_pdbdir_validation
195	if ".%_MY_OPT_PDBDIR%" == "." set _MY_OPT_PDBDIR=%_MY_OPT_BINDIR%\..\stage\debug\bin
196	if not exist "%_MY_OPT_PDBDIR%" goto error_pdbdir_does_not_exist
197	:no_pdbdir_validation
198
199	if "%_MY_OPT_WITH_EXTPACK%" == "0" goto no_extpack_validation
200	if "%_MY_OPT_NO_EXTRACT%" == "1" goto no_extpack_validation
201	if ".%_MY_OPT_EXTPACK%" == "." set _MY_OPT_EXTPACK=%_MY_OPT_BINDIR%\Oracle_VirtualBox_Extension_Pack.vbox-extpack
202	if not exist "%_MY_OPT_EXTPACK%" goto error_extpack_does_not_exist
203	:no_extpack_validation
204
205	if "%_MY_OPT_WITH_GA%" == "0" goto no_additions_validation
206	if ".%_MY_OPT_GADIR%" == "." set _MY_OPT_GADIR=%_MY_OPT_BINDIR%\additions
207	if not exist "%_MY_OPT_GADIR%" goto error_additions_does_not_exist
208	:no_additions_validation
209
210	if ".%_MY_OPT_OUTPUT%" == "." set _MY_OPT_OUTPUT=VBoxDrivers-@VBOX_VERSION_STRING@r@VBOX_SVN_REV@-%_MY_OPT_ARCH%.cab
211	if exist "%_MY_OPT_OUTPUT%" goto error_output_exists
212
213	if ".%_MY_OPT_DDF_FILE%" == "." set _MY_OPT_DDF_FILE=%_MY_OPT_OUTPUT%.ddf
214	if exist "%_MY_OPT_DDF_FILE%" goto error_ddf_exists
215
216
217	rem
218	rem Unpack the extension pack.
219	rem We unpack it into the bin directory in the usual location.
220	rem
221	rem Note! Modify the path a little to ensure windows utilities are used before
222	rem cygwin ones, and that we can use stuff from bin\tools if we like.
223	rem
224	set PATH=%SystemRoot%\System32;%PATH%;%_MY_OPT_BINDIR%
225	if "%_MY_OPT_WITH_EXTPACK%" == "0" goto no_extpack_unpack
226	set _MY_EXTPACK_DIR=%_MY_OPT_BINDIR%\ExtensionPacks\Oracle_VirtualBox_Extension_Pack
227	if not exist "%_MY_OPT_BINDIR%\ExtensionPacks" ( mkdir "%_MY_OPT_BINDIR%\ExtensionPacks" \|\| goto end_failed )
228	if not exist "%_MY_EXTPACK_DIR%" ( mkdir "%_MY_EXTPACK_DIR%" \|\| goto end_failed )
229	if "%_MY_OPT_NO_EXTRACT%" == "1" goto no_extpack_unpack
230	"%_MY_OPT_BINDIR%\tools\RTTar.exe" -xzf "%_MY_OPT_EXTPACK%" -C "%_MY_EXTPACK_DIR%" \|\| goto end_failed
231	:no_extpack_unpack
232
233	rem
234	rem Create the DDF file for makecab.
235	rem
236	echo .OPTION EXPLICIT> "%_MY_OPT_DDF_FILE%" \|\| goto end_failed
237	echo .Set CabinetFileCountThreshold=0 >> "%_MY_OPT_DDF_FILE%"
238	echo .Set FolderFileCountThreshold=0 >> "%_MY_OPT_DDF_FILE%"
239	echo .Set FolderSizeThreshold=0 >> "%_MY_OPT_DDF_FILE%"
240	echo .Set MaxCabinetSize=0 >> "%_MY_OPT_DDF_FILE%"
241	echo .Set MaxDiskFileCount=0 >> "%_MY_OPT_DDF_FILE%"
242	echo .Set MaxDiskSize=0 >> "%_MY_OPT_DDF_FILE%"
243	echo .Set Cabinet=on>> "%_MY_OPT_DDF_FILE%"
244	echo .Set CompressionType=MSZIP>> "%_MY_OPT_DDF_FILE%"
245	echo .Set Compress=on>> "%_MY_OPT_DDF_FILE%"
246	echo .Set DiskDirectoryTemplate= >> "%_MY_OPT_DDF_FILE%"
247	echo .Set CabinetNameTemplate=%_MY_OPT_OUTPUT%>> "%_MY_OPT_DDF_FILE%"
248	echo .Set InfFileName=%_MY_OPT_OUTPUT%.inf>> "%_MY_OPT_DDF_FILE%"
249	echo .Set RptFileName=%_MY_OPT_OUTPUT%.rpt>> "%_MY_OPT_DDF_FILE%"
250
251	if %_MY_OPT_WITH_MAIN% == 0 goto skip_main_package
252	echo .Set DestinationDir=VBoxSup>> "%_MY_OPT_DDF_FILE%"
253	echo %_MY_OPT_BINDIR%\VBoxSup.inf VBoxSup.inf>> "%_MY_OPT_DDF_FILE%"
254	echo %_MY_OPT_BINDIR%\VBoxSup.sys VBoxSup.sys>> "%_MY_OPT_DDF_FILE%"
255	if "%_MY_OPT_WITH_PDB%" == "1" echo %_MY_OPT_PDBDIR%\VBoxSup.pdb VBoxSup.pdb>> "%_MY_OPT_DDF_FILE%"
256
257	echo .Set DestinationDir=VBoxNetAdp6>> "%_MY_OPT_DDF_FILE%"
258	echo %_MY_OPT_BINDIR%\VBoxNetAdp6.inf VBoxNetAdp6.inf>> "%_MY_OPT_DDF_FILE%"
259	echo %_MY_OPT_BINDIR%\VBoxNetAdp6.sys VBoxNetAdp6.sys>> "%_MY_OPT_DDF_FILE%"
260	if "%_MY_OPT_WITH_PDB%" == "1" echo %_MY_OPT_PDBDIR%\VBoxNetAdp6.pdb VBoxNetAdp6.pdb>> "%_MY_OPT_DDF_FILE%"
261
262	echo .Set DestinationDir=VBoxNetLwf>> "%_MY_OPT_DDF_FILE%"
263	echo %_MY_OPT_BINDIR%\VBoxNetLwf.inf VBoxNetLwf.inf>> "%_MY_OPT_DDF_FILE%"
264	echo %_MY_OPT_BINDIR%\VBoxNetLwf.sys VBoxNetLwf.sys>> "%_MY_OPT_DDF_FILE%"
265	if "%_MY_OPT_WITH_PDB%" == "1" echo %_MY_OPT_PDBDIR%\VBoxNetLwf.pdb VBoxNetLwf.pdb>> "%_MY_OPT_DDF_FILE%"
266
267	echo .Set DestinationDir=VBoxUSB>> "%_MY_OPT_DDF_FILE%"
268	echo %_MY_OPT_BINDIR%\VBoxUSB.inf VBoxUSB.inf>> "%_MY_OPT_DDF_FILE%"
269	echo %_MY_OPT_BINDIR%\VBoxUSB.sys VBoxUSB.sys>> "%_MY_OPT_DDF_FILE%"
270	if "%_MY_OPT_WITH_PDB%" == "1" echo %_MY_OPT_PDBDIR%\VBoxUSB.pdb VBoxUSB.pdb>> "%_MY_OPT_DDF_FILE%"
271
272	echo .Set DestinationDir=VBoxUSBMon>> "%_MY_OPT_DDF_FILE%"
273	echo %_MY_OPT_BINDIR%\VBoxUSBMon.inf VBoxUSBMon.inf>> "%_MY_OPT_DDF_FILE%"
274	echo %_MY_OPT_BINDIR%\VBoxUSBMon.sys VBoxUSBMon.sys>> "%_MY_OPT_DDF_FILE%"
275	if "%_MY_OPT_WITH_PDB%" == "1" echo %_MY_OPT_PDBDIR%\VBoxUSBMon.pdb VBoxUSBMon.pdb>> "%_MY_OPT_DDF_FILE%"
276
277	echo .Set DestinationDir=VMMR0>> "%_MY_OPT_DDF_FILE%"
278	echo .\VMMR0.inf VMMR0.inf>> "%_MY_OPT_DDF_FILE%"
279	echo %_MY_OPT_BINDIR%\VMMR0.r0 VMMR0.r0>> "%_MY_OPT_DDF_FILE%"
280	if "%_MY_OPT_WITH_PDB%" == "1" echo %_MY_OPT_PDBDIR%\VMMR0.pdb VMMR0.pdb>> "%_MY_OPT_DDF_FILE%"
281	echo %_MY_OPT_BINDIR%\VBoxDDR0.r0 VBoxDDR0.r0>> "%_MY_OPT_DDF_FILE%"
282	if "%_MY_OPT_WITH_PDB%" == "1" echo %_MY_OPT_PDBDIR%\VBoxDDR0.pdb VBoxDDR0.pdb>> "%_MY_OPT_DDF_FILE%"
283	:skip_main_package
284
285	if "%_MY_OPT_WITH_EXTPACK%" == "0" goto no_extpack_ddf
286	echo .Set DestinationDir=VBoxExtPackPuel>> "%_MY_OPT_DDF_FILE%"
287	echo .\VBoxExtPackPuel.inf VBoxExtPackPuel.inf>> "%_MY_OPT_DDF_FILE%"
288	rem echo %_MY_EXTPACK_DIR%\win.%_MY_OPT_ARCH%\VBoxEhciR0.r0 VBoxEhciR0.r0>> "%_MY_OPT_DDF_FILE%"
289	echo %_MY_EXTPACK_DIR%\win.%_MY_OPT_ARCH%\VBoxNvmeR0.r0 VBoxNvmeR0.r0>> "%_MY_OPT_DDF_FILE%"
290	rem echo %_MY_EXTPACK_DIR%\win.%_MY_OPT_ARCH%\VBoxPciRawR0.r0 VBoxPciRawR0.r0>> "%_MY_OPT_DDF_FILE%"
291	:no_extpack_ddf
292
293	if "%_MY_OPT_WITH_GA%" == "0" goto no_additions_ddf
294	echo .Set DestinationDir=VBoxGuestAdditions>> "%_MY_OPT_DDF_FILE%"
295	echo %_MY_OPT_GADIR%\VBoxGuest.inf>> "%_MY_OPT_DDF_FILE%"
296	echo %_MY_OPT_GADIR%\VBoxGuest.sys>> "%_MY_OPT_DDF_FILE%"
297	echo %_MY_OPT_GADIR%\VBoxTray.exe>> "%_MY_OPT_DDF_FILE%"
298	echo %_MY_OPT_GADIR%\VBoxControl.exe>> "%_MY_OPT_DDF_FILE%"
299	echo %_MY_OPT_GADIR%\VBoxMouse.inf>> "%_MY_OPT_DDF_FILE%"
300	echo %_MY_OPT_GADIR%\VBoxMouse.sys>> "%_MY_OPT_DDF_FILE%"
301	rem VBoxVideo files are excluded from attestation signing.
302	rem echo %_MY_OPT_GADIR%\VBoxVideo.inf>> "%_MY_OPT_DDF_FILE%"
303	rem echo %_MY_OPT_GADIR%\VBoxVideo.sys>> "%_MY_OPT_DDF_FILE%"
304	echo %_MY_OPT_GADIR%\VBoxWddm.inf>> "%_MY_OPT_DDF_FILE%"
305	echo %_MY_OPT_GADIR%\VBoxWddm.sys>> "%_MY_OPT_DDF_FILE%"
306	echo %_MY_OPT_GADIR%\VBoxDX.dll>> "%_MY_OPT_DDF_FILE%"
307	echo %_MY_OPT_GADIR%\VBoxDisp.dll>> "%_MY_OPT_DDF_FILE%"
308	echo %_MY_OPT_GADIR%\VBoxDispD3D.dll>> "%_MY_OPT_DDF_FILE%"
309	echo %_MY_OPT_GADIR%\VBoxNine.dll>> "%_MY_OPT_DDF_FILE%"
310	echo %_MY_OPT_GADIR%\VBoxSVGA.dll>> "%_MY_OPT_DDF_FILE%"
311	echo %_MY_OPT_GADIR%\VBoxGL.dll>> "%_MY_OPT_DDF_FILE%"
312	echo %_MY_OPT_GADIR%\VBoxMRXNP.dll>> "%_MY_OPT_DDF_FILE%"
313	echo %_MY_OPT_GADIR%\VBoxSF.sys>> "%_MY_OPT_DDF_FILE%"
314	if ".%_MY_OPT_ARCH%" == ".x86" goto skip_amd64_files
315	echo %_MY_OPT_GADIR%\VBoxDX-x86.dll>> "%_MY_OPT_DDF_FILE%"
316	echo %_MY_OPT_GADIR%\VBoxDispD3D-x86.dll>> "%_MY_OPT_DDF_FILE%"
317	echo %_MY_OPT_GADIR%\VBoxNine-x86.dll>> "%_MY_OPT_DDF_FILE%"
318	echo %_MY_OPT_GADIR%\VBoxSVGA-x86.dll>> "%_MY_OPT_DDF_FILE%"
319	echo %_MY_OPT_GADIR%\VBoxGL-x86.dll>> "%_MY_OPT_DDF_FILE%"
320	:skip_amd64_files
321
322	:no_additions_ddf
323
324	rem
325	rem Create the cabient file.
326	rem Note! MakeCab is shipped on W10, so we ASSUME it's in the PATH.
327	rem
328	MakeCab.exe /v2 /F "%_MY_OPT_DDF_FILE%" \|\| goto end_failed
329
330	rem
331	rem EV sign the cabient file.
332	rem
333	if not exist "sign-ev.cmd" goto end
334	echo info: Now signing the created CAB file. Can take a few minutes...
335	call sign-ev.cmd "%_MY_OPT_OUTPUT%" \|\| goto end_failed
336
337	goto end
338
339	:end_failed
340	@endlocal
341	@endlocal
342	@exit /b 1
343
344	:end
345	@endlocal
346	@endlocal

Note: See TracBrowser for help on using the repository browser.

source: vbox/trunk/src/VBox/Installer/win/Scripts/PackDriversForSubmission.cmd@ 106031

Download in other formats: