VirtualBox

source: vbox/trunk/src/VBox/Main/idl/midl.xsl@ 53390

Last change on this file since 53390 was 50855, checked in by vboxsync, 11 years ago

midl.xsl: IVirtualBoxErrorInfo causes midl warning because of choice of $errorinfo interface.
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 29.5 KB
Line 
1<?xml version="1.0"?>
2<!-- $Id: midl.xsl 50855 2014-03-24 13:30:46Z vboxsync $ -->
3
4<!--
5 * A template to generate a MS IDL compatible interface definition file
6 * from the generic interface definition expressed in XML.
7
8 Copyright (C) 2006-2014 Oracle Corporation
9
10 This file is part of VirtualBox Open Source Edition (OSE), as
11 available from http://www.virtualbox.org. This file is free software;
12 you can redistribute it and/or modify it under the terms of the GNU
13 General Public License (GPL) as published by the Free Software
14 Foundation, in version 2 as it comes in the "COPYING" file of the
15 VirtualBox OSE distribution. VirtualBox OSE is distributed in the
16 hope that it will be useful, but WITHOUT ANY WARRANTY of any kind.
17-->
18
19<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
20<xsl:output method="text"/>
21
22<xsl:strip-space elements="*"/>
23
24<!-- Whether to generate proxy code and type library ('yes'), or just the type-library. -->
25<xsl:param name="g_fGenProxy" select="'no'"/>
26
27
28<!--
29// helper definitions
30/////////////////////////////////////////////////////////////////////////////
31-->
32
33<!--
34 * capitalizes the first letter
35-->
36<xsl:template name="capitalize">
37 <xsl:param name="str" select="."/>
38 <xsl:value-of select="
39 concat(
40 translate(substring($str,1,1),'abcdefghijklmnopqrstuvwxyz','ABCDEFGHIJKLMNOPQRSTUVWXYZ'),
41 substring($str,2)
42 )
43 "/>
44</xsl:template>
45
46<!--
47 * uncapitalizes the first letter only if the second one is not capital
48 * otherwise leaves the string unchanged
49-->
50<xsl:template name="uncapitalize">
51 <xsl:param name="str" select="."/>
52 <xsl:choose>
53 <xsl:when test="not(contains('ABCDEFGHIJKLMNOPQRSTUVWXYZ', substring($str,2,1)))">
54 <xsl:value-of select="
55 concat(
56 translate(substring($str,1,1),'ABCDEFGHIJKLMNOPQRSTUVWXYZ','abcdefghijklmnopqrstuvwxyz'),
57 substring($str,2)
58 )
59 "/>
60 </xsl:when>
61 <xsl:otherwise>
62 <xsl:value-of select="string($str)"/>
63 </xsl:otherwise>
64 </xsl:choose>
65</xsl:template>
66
67
68<!--
69// templates
70/////////////////////////////////////////////////////////////////////////////
71-->
72
73<!--
74 * not explicitly matched elements and attributes
75-->
76<xsl:template match="*"/>
77
78
79<!--
80 * header
81-->
82<xsl:template match="/idl">
83 <xsl:text>
84/*
85 * DO NOT EDIT! This is a generated file.
86 *
87 * MS IDL (MIDL) definition for VirtualBox Main API (COM interfaces)
88 * generated from XIDL (XML interface definition).
89 *
90 * Source : src/VBox/Main/idl/VirtualBox.xidl
91 * Generator : src/VBox/Main/idl/midl.xsl
92 */
93 </xsl:text>
94 <xsl:text>&#x0A;</xsl:text>
95 <xsl:text>import "unknwn.idl";&#x0A;&#x0A;</xsl:text>
96 <xsl:apply-templates/>
97</xsl:template>
98
99
100<!--
101 * ignore all |if|s except those for MIDL target
102-->
103<xsl:template match="if">
104 <xsl:if test="@target='midl'">
105 <xsl:apply-templates/>
106 </xsl:if>
107</xsl:template>
108<xsl:template match="if" mode="forward">
109 <xsl:if test="@target='midl'">
110 <xsl:apply-templates mode="forward"/>
111 </xsl:if>
112</xsl:template>
113<xsl:template match="if" mode="forwarder">
114 <xsl:param name="nameOnly"/>
115 <xsl:if test="@target='midl'">
116 <xsl:apply-templates mode="forwarder">
117 <xsl:with-param name="nameOnly" select="$nameOnly"/>
118 </xsl:apply-templates>
119 </xsl:if>
120</xsl:template>
121
122
123<!--
124 * cpp_quote
125-->
126<xsl:template match="cpp">
127 <xsl:text>cpp_quote("</xsl:text>
128 <xsl:value-of select="@line"/>
129 <xsl:text>")&#x0A;&#x0A;</xsl:text>
130</xsl:template>
131
132
133<!--
134 * #if statement (@if attribute)
135-->
136<xsl:template match="@if" mode="begin">
137 <xsl:text>#if </xsl:text>
138 <xsl:value-of select="."/>
139 <xsl:text>&#x0A;</xsl:text>
140</xsl:template>
141<xsl:template match="@if" mode="end">
142 <xsl:text>#endif&#x0A;</xsl:text>
143</xsl:template>
144
145
146<!--
147 * libraries
148-->
149<xsl:template match="library">
150 <xsl:if test="$g_fGenProxy = 'yes'">
151 <!-- Declare everything outside the library and then reference these
152 from inside the library statement. See:
153 http://msdn.microsoft.com/en-us/library/windows/desktop/aa366841(v=vs.85).aspx -->
154 <xsl:text>&#x0A;</xsl:text>
155 <!-- forward declarations -->
156 <xsl:apply-templates select="if | interface" mode="forward"/>
157 <xsl:text>&#x0A;</xsl:text>
158 <!-- all enums go first -->
159 <xsl:apply-templates select="enum | if/enum"/>
160 <!-- declare the interfaces -->
161 <xsl:apply-templates select="if | interface"/>
162 </xsl:if>
163
164[
165 uuid(<xsl:value-of select="@uuid"/>),
166 version(<xsl:value-of select="@version"/>),
167 helpstring("<xsl:value-of select="@desc"/>")
168]
169<xsl:text>library </xsl:text>
170 <xsl:value-of select="@name"/>
171 <xsl:text>&#x0A;{&#x0A;</xsl:text>
172 <xsl:text>&#x0A;importlib("stdole2.tlb");&#x0A;&#x0A;</xsl:text>
173 <!-- result codes -->
174 <xsl:for-each select="result">
175 <xsl:apply-templates select="."/>
176 </xsl:for-each>
177 <xsl:text>&#x0A;</xsl:text>
178 <xsl:text>&#x0A;</xsl:text>
179 <xsl:choose>
180 <xsl:when test="$g_fGenProxy = 'yes'">
181 <!-- reference enums and interfaces -->
182 <xsl:apply-templates select="if | interface" mode="forward"/>
183 <xsl:apply-templates select="enum | if/enum" mode="forward"/>
184 <!-- the modules (i.e. everything else) -->
185 <xsl:apply-templates select="module | if/module"/>
186 </xsl:when>
187 <xsl:otherwise>
188 <!-- forward declarations -->
189 <xsl:apply-templates select="if | interface" mode="forward"/>
190 <!-- all enums go first -->
191 <xsl:apply-templates select="enum | if/enum"/>
192 <!-- everything else but result codes and enums -->
193 <xsl:apply-templates select="*[not(self::result or self::enum) and
194 not(self::if[result] or self::if[enum])]"/>
195 </xsl:otherwise>
196 </xsl:choose>
197 <!-- -->
198 <xsl:text>}; /* library </xsl:text>
199 <xsl:value-of select="@name"/>
200 <xsl:text> */&#x0A;&#x0A;</xsl:text>
201</xsl:template>
202
203
204<!--
205 * result codes
206-->
207<xsl:template match="result">
208 <xsl:text>cpp_quote("</xsl:text>
209 <xsl:value-of select="concat('#define ',@name,' ',@value)"/>
210 <xsl:text>")&#x0A;</xsl:text>
211</xsl:template>
212
213
214<!--
215 * forward declarations
216-->
217<xsl:template match="interface" mode="forward">
218 <xsl:text>interface </xsl:text>
219 <xsl:value-of select="@name"/>
220 <xsl:text>;&#x0A;</xsl:text>
221</xsl:template>
222
223
224<xsl:template match="enum" mode="forward">
225 <xsl:text>enum </xsl:text>
226 <xsl:value-of select="@name"/>
227 <xsl:text>;&#x0A;&#x0A;</xsl:text>
228</xsl:template>
229
230
231<!--
232 * interfaces
233-->
234<xsl:template match="interface">[
235 uuid(<xsl:value-of select="@uuid"/>),
236 object,
237 dual,
238 oleautomation
239]
240<xsl:text>interface </xsl:text>
241 <xsl:value-of select="@name"/>
242 <xsl:text> : </xsl:text>
243 <xsl:choose>
244 <xsl:when test="@extends='$unknown'">IDispatch</xsl:when>
245 <xsl:when test="@extends='$errorinfo'">IErrorInfo</xsl:when>
246 <!-- TODO/FIXME/BUGBUG: The above $errorinfo value causes the following warning (/W4):
247warning MIDL2460 : dual interface should be derived from IDispatch : IVirtualBoxErrorInfo [ Interface 'IVirtualBoxErrorInfo' ]
248 -->
249 <xsl:otherwise><xsl:value-of select="@extends"/></xsl:otherwise>
250 </xsl:choose>
251 <xsl:text>&#x0A;{&#x0A;</xsl:text>
252 <!-- attributes (properties) -->
253 <xsl:apply-templates select="attribute"/>
254 <!-- methods -->
255 <xsl:apply-templates select="method"/>
256 <!-- 'if' enclosed elements, unsorted -->
257 <xsl:apply-templates select="if"/>
258 <!-- -->
259 <xsl:text>}; /* interface </xsl:text>
260 <xsl:value-of select="@name"/>
261 <xsl:text> */&#x0A;&#x0A;</xsl:text>
262 <!-- Interface implementation forwarder macro -->
263 <xsl:text>/* Interface implementation forwarder macro */&#x0A;</xsl:text>
264 <!-- 1) individual methods -->
265 <xsl:apply-templates select="attribute" mode="forwarder"/>
266 <xsl:apply-templates select="method" mode="forwarder"/>
267 <xsl:apply-templates select="if" mode="forwarder"/>
268 <!-- 2) COM_FORWARD_Interface_TO(smth) -->
269 <xsl:text>cpp_quote("#define COM_FORWARD_</xsl:text>
270 <xsl:value-of select="@name"/>
271 <xsl:text>_TO(smth) </xsl:text>
272 <xsl:apply-templates select="attribute" mode="forwarder">
273 <xsl:with-param name="nameOnly" select="'yes'"/>
274 </xsl:apply-templates>
275 <xsl:apply-templates select="method" mode="forwarder">
276 <xsl:with-param name="nameOnly" select="'yes'"/>
277 </xsl:apply-templates>
278 <xsl:apply-templates select="if" mode="forwarder">
279 <xsl:with-param name="nameOnly" select="'yes'"/>
280 </xsl:apply-templates>
281 <xsl:text>")&#x0A;</xsl:text>
282 <!-- 3) COM_FORWARD_Interface_TO_OBJ(obj) -->
283 <xsl:text>cpp_quote("#define COM_FORWARD_</xsl:text>
284 <xsl:value-of select="@name"/>
285 <xsl:text>_TO_OBJ(obj) COM_FORWARD_</xsl:text>
286 <xsl:value-of select="@name"/>
287 <xsl:text>_TO ((obj)->)")&#x0A;</xsl:text>
288 <!-- 4) COM_FORWARD_Interface_TO_BASE(base) -->
289 <xsl:text>cpp_quote("#define COM_FORWARD_</xsl:text>
290 <xsl:value-of select="@name"/>
291 <xsl:text>_TO_BASE(base) COM_FORWARD_</xsl:text>
292 <xsl:value-of select="@name"/>
293 <xsl:text>_TO (base::)")&#x0A;</xsl:text>
294 <!-- end -->
295 <xsl:text>&#x0A;</xsl:text>
296</xsl:template>
297
298
299<!--
300 * attributes
301-->
302<xsl:template match="interface//attribute">
303 <xsl:apply-templates select="@if" mode="begin"/>
304 <!-- getter -->
305 <xsl:text> [propget] HRESULT </xsl:text>
306 <xsl:call-template name="capitalize">
307 <xsl:with-param name="str" select="@name"/>
308 </xsl:call-template>
309 <xsl:text> ([out, retval] </xsl:text>
310 <xsl:if test="@safearray='yes'">
311 <xsl:text>SAFEARRAY(</xsl:text>
312 </xsl:if>
313 <xsl:apply-templates select="@type"/>
314 <xsl:if test="@safearray='yes'">
315 <xsl:text>)</xsl:text>
316 </xsl:if>
317 <xsl:text> * a</xsl:text>
318 <xsl:call-template name="capitalize">
319 <xsl:with-param name="str" select="@name"/>
320 </xsl:call-template>
321 <xsl:text>);&#x0A;</xsl:text>
322 <!-- setter -->
323 <xsl:if test="not(@readonly='yes')">
324 <xsl:text> [propput] HRESULT </xsl:text>
325 <xsl:call-template name="capitalize">
326 <xsl:with-param name="str" select="@name"/>
327 </xsl:call-template>
328 <xsl:text> ([in] </xsl:text>
329 <xsl:if test="@safearray='yes'">
330 <xsl:text>SAFEARRAY(</xsl:text>
331 </xsl:if>
332 <xsl:apply-templates select="@type"/>
333 <xsl:if test="@safearray='yes'">
334 <xsl:text>)</xsl:text>
335 </xsl:if>
336 <xsl:text> a</xsl:text>
337 <xsl:call-template name="capitalize">
338 <xsl:with-param name="str" select="@name"/>
339 </xsl:call-template>
340 <xsl:text>);&#x0A;</xsl:text>
341 </xsl:if>
342 <xsl:apply-templates select="@if" mode="end"/>
343 <xsl:text>&#x0A;</xsl:text>
344</xsl:template>
345
346<xsl:template match="interface//attribute" mode="forwarder">
347
348 <!-- if nameOnly='yes' then only the macro name is composed
349 followed by a space -->
350 <xsl:param name="nameOnly"/>
351
352 <xsl:variable name="parent" select="ancestor::interface"/>
353
354 <xsl:apply-templates select="@if" mode="begin"/>
355
356 <xsl:choose>
357 <xsl:when test="$nameOnly='yes'">
358 <!-- getter: COM_FORWARD_Interface_GETTER_Name_TO(smth) -->
359 <xsl:text>COM_FORWARD_</xsl:text>
360 <xsl:value-of select="$parent/@name"/>
361 <xsl:text>_GETTER_</xsl:text>
362 <xsl:call-template name="capitalize">
363 <xsl:with-param name="str" select="@name"/>
364 </xsl:call-template>
365 <xsl:text>_TO (smth) </xsl:text>
366 <!-- setter: COM_FORWARD_Interface_SETTER_Name_TO(smth) -->
367 <xsl:if test="not(@readonly='yes')">
368 <xsl:text>COM_FORWARD_</xsl:text>
369 <xsl:value-of select="$parent/@name"/>
370 <xsl:text>_SETTER_</xsl:text>
371 <xsl:call-template name="capitalize">
372 <xsl:with-param name="str" select="@name"/>
373 </xsl:call-template>
374 <xsl:text>_TO (smth) </xsl:text>
375 </xsl:if>
376 </xsl:when>
377 <xsl:otherwise>
378 <!-- getter: COM_FORWARD_Interface_GETTER_Name_TO(smth) -->
379 <xsl:text>cpp_quote("#define COM_FORWARD_</xsl:text>
380 <xsl:value-of select="$parent/@name"/>
381 <xsl:text>_GETTER_</xsl:text>
382 <xsl:call-template name="capitalize">
383 <xsl:with-param name="str" select="@name"/>
384 </xsl:call-template>
385 <xsl:text>_TO(smth) HRESULT STDMETHODCALLTYPE get_</xsl:text>
386 <xsl:call-template name="capitalize">
387 <xsl:with-param name="str" select="@name"/>
388 </xsl:call-template>
389 <xsl:text> (</xsl:text>
390 <xsl:choose>
391 <xsl:when test="@safearray='yes'">
392 <xsl:text>SAFEARRAY *</xsl:text>
393 </xsl:when>
394 <xsl:otherwise>
395 <xsl:apply-templates select="@type"/>
396 </xsl:otherwise>
397 </xsl:choose>
398 <xsl:text> * a</xsl:text>
399 <xsl:call-template name="capitalize">
400 <xsl:with-param name="str" select="@name"/>
401 </xsl:call-template>
402 <xsl:text>) { return smth get_</xsl:text>
403 <xsl:call-template name="capitalize">
404 <xsl:with-param name="str" select="@name"/>
405 </xsl:call-template>
406 <xsl:text> (a</xsl:text>
407 <xsl:call-template name="capitalize">
408 <xsl:with-param name="str" select="@name"/>
409 </xsl:call-template>
410 <xsl:text>); }")&#x0A;</xsl:text>
411 <!-- getter: COM_FORWARD_Interface_GETTER_Name_TO_OBJ(obj) -->
412 <xsl:text>cpp_quote("#define COM_FORWARD_</xsl:text>
413 <xsl:value-of select="$parent/@name"/>
414 <xsl:text>_GETTER_</xsl:text>
415 <xsl:call-template name="capitalize">
416 <xsl:with-param name="str" select="@name"/>
417 </xsl:call-template>
418 <xsl:text>_TO_OBJ(obj) COM_FORWARD_</xsl:text>
419 <xsl:value-of select="$parent/@name"/>
420 <xsl:text>_GETTER_</xsl:text>
421 <xsl:call-template name="capitalize">
422 <xsl:with-param name="str" select="@name"/>
423 </xsl:call-template>
424 <xsl:text>_TO ((obj)->)")&#x0A;</xsl:text>
425 <!-- getter: COM_FORWARD_Interface_GETTER_Name_TO_BASE(base) -->
426 <xsl:text>cpp_quote("#define COM_FORWARD_</xsl:text>
427 <xsl:value-of select="$parent/@name"/>
428 <xsl:text>_GETTER_</xsl:text>
429 <xsl:call-template name="capitalize">
430 <xsl:with-param name="str" select="@name"/>
431 </xsl:call-template>
432 <xsl:text>_TO_BASE(base) COM_FORWARD_</xsl:text>
433 <xsl:value-of select="$parent/@name"/>
434 <xsl:text>_GETTER_</xsl:text>
435 <xsl:call-template name="capitalize">
436 <xsl:with-param name="str" select="@name"/>
437 </xsl:call-template>
438 <xsl:text>_TO (base::)")&#x0A;</xsl:text>
439 <!-- -->
440 <xsl:if test="not(@readonly='yes')">
441 <!-- setter: COM_FORWARD_Interface_SETTER_Name_TO(smth) -->
442 <xsl:text>cpp_quote("#define COM_FORWARD_</xsl:text>
443 <xsl:value-of select="$parent/@name"/>
444 <xsl:text>_SETTER_</xsl:text>
445 <xsl:call-template name="capitalize">
446 <xsl:with-param name="str" select="@name"/>
447 </xsl:call-template>
448 <xsl:text>_TO(smth) HRESULT STDMETHODCALLTYPE put_</xsl:text>
449 <xsl:call-template name="capitalize">
450 <xsl:with-param name="str" select="@name"/>
451 </xsl:call-template>
452 <xsl:text> (</xsl:text>
453 <xsl:choose>
454 <xsl:when test="@safearray='yes'">
455 <xsl:text>SAFEARRAY *</xsl:text>
456 </xsl:when>
457 <xsl:otherwise>
458 <xsl:apply-templates select="@type"/>
459 </xsl:otherwise>
460 </xsl:choose>
461 <xsl:text> a</xsl:text>
462 <xsl:call-template name="capitalize">
463 <xsl:with-param name="str" select="@name"/>
464 </xsl:call-template>
465 <xsl:text>) { return smth put_</xsl:text>
466 <xsl:call-template name="capitalize">
467 <xsl:with-param name="str" select="@name"/>
468 </xsl:call-template>
469 <xsl:text> (a</xsl:text>
470 <xsl:call-template name="capitalize">
471 <xsl:with-param name="str" select="@name"/>
472 </xsl:call-template>
473 <xsl:text>); }")&#x0A;</xsl:text>
474 <!-- setter: COM_FORWARD_Interface_SETTER_Name_TO_OBJ(obj) -->
475 <xsl:text>cpp_quote("#define COM_FORWARD_</xsl:text>
476 <xsl:value-of select="$parent/@name"/>
477 <xsl:text>_SETTER_</xsl:text>
478 <xsl:call-template name="capitalize">
479 <xsl:with-param name="str" select="@name"/>
480 </xsl:call-template>
481 <xsl:text>_TO_OBJ(obj) COM_FORWARD_</xsl:text>
482 <xsl:value-of select="$parent/@name"/>
483 <xsl:text>_SETTER_</xsl:text>
484 <xsl:call-template name="capitalize">
485 <xsl:with-param name="str" select="@name"/>
486 </xsl:call-template>
487 <xsl:text>_TO ((obj)->)")&#x0A;</xsl:text>
488 <!-- setter: COM_FORWARD_Interface_SETTER_Name_TO_BASE(base) -->
489 <xsl:text>cpp_quote("#define COM_FORWARD_</xsl:text>
490 <xsl:value-of select="$parent/@name"/>
491 <xsl:text>_SETTER_</xsl:text>
492 <xsl:call-template name="capitalize">
493 <xsl:with-param name="str" select="@name"/>
494 </xsl:call-template>
495 <xsl:text>_TO_BASE(base) COM_FORWARD_</xsl:text>
496 <xsl:value-of select="$parent/@name"/>
497 <xsl:text>_SETTER_</xsl:text>
498 <xsl:call-template name="capitalize">
499 <xsl:with-param name="str" select="@name"/>
500 </xsl:call-template>
501 <xsl:text>_TO (base::)")&#x0A;</xsl:text>
502 </xsl:if>
503 </xsl:otherwise>
504 </xsl:choose>
505
506 <xsl:apply-templates select="@if" mode="end"/>
507
508</xsl:template>
509
510
511<!--
512 * methods
513-->
514<xsl:template match="interface//method">
515 <xsl:apply-templates select="@if" mode="begin"/>
516 <xsl:text> HRESULT </xsl:text>
517 <xsl:call-template name="capitalize">
518 <xsl:with-param name="str" select="@name"/>
519 </xsl:call-template>
520 <xsl:choose>
521 <xsl:when test="param">
522 <xsl:text> (&#x0A;</xsl:text>
523 <xsl:for-each select="param [position() != last()]">
524 <xsl:text> </xsl:text>
525 <xsl:apply-templates select="."/>
526 <xsl:text>,&#x0A;</xsl:text>
527 </xsl:for-each>
528 <xsl:text> </xsl:text>
529 <xsl:apply-templates select="param [last()]"/>
530 <xsl:text>&#x0A; );&#x0A;</xsl:text>
531 </xsl:when>
532 <xsl:otherwise test="not(param)">
533 <xsl:text>();&#x0A;</xsl:text>
534 </xsl:otherwise>
535 </xsl:choose>
536 <xsl:apply-templates select="@if" mode="end"/>
537 <xsl:text>&#x0A;</xsl:text>
538</xsl:template>
539
540<xsl:template match="interface//method" mode="forwarder">
541
542 <!-- if nameOnly='yes' then only the macro name is composed followed by \ -->
543 <xsl:param name="nameOnly"/>
544
545 <xsl:variable name="parent" select="ancestor::interface"/>
546
547 <xsl:apply-templates select="@if" mode="begin"/>
548
549 <xsl:choose>
550 <xsl:when test="$nameOnly='yes'">
551 <!-- COM_FORWARD_Interface_Method_TO(smth) -->
552 <xsl:text>COM_FORWARD_</xsl:text>
553 <xsl:value-of select="$parent/@name"/>
554 <xsl:text>_</xsl:text>
555 <xsl:call-template name="capitalize">
556 <xsl:with-param name="str" select="@name"/>
557 </xsl:call-template>
558 <xsl:text>_TO (smth) </xsl:text>
559 </xsl:when>
560 <xsl:otherwise>
561 <xsl:text>cpp_quote("#define COM_FORWARD_</xsl:text>
562 <xsl:value-of select="$parent/@name"/>
563 <xsl:text>_</xsl:text>
564 <xsl:call-template name="capitalize">
565 <xsl:with-param name="str" select="@name"/>
566 </xsl:call-template>
567 <xsl:text>_TO(smth) HRESULT STDMETHODCALLTYPE </xsl:text>
568 <xsl:call-template name="capitalize">
569 <xsl:with-param name="str" select="@name"/>
570 </xsl:call-template>
571 <xsl:choose>
572 <xsl:when test="param">
573 <xsl:text> (</xsl:text>
574 <xsl:for-each select="param [position() != last()]">
575 <xsl:apply-templates select="." mode="forwarder"/>
576 <xsl:text>, </xsl:text>
577 </xsl:for-each>
578 <xsl:apply-templates select="param [last()]" mode="forwarder"/>
579 <xsl:text>) { return smth </xsl:text>
580 <xsl:call-template name="capitalize">
581 <xsl:with-param name="str" select="@name"/>
582 </xsl:call-template>
583 <xsl:text> (</xsl:text>
584 <xsl:for-each select="param [position() != last()]">
585 <xsl:text>a</xsl:text>
586 <xsl:call-template name="capitalize">
587 <xsl:with-param name="str" select="@name"/>
588 </xsl:call-template>
589 <xsl:text>, </xsl:text>
590 </xsl:for-each>
591 <xsl:text>a</xsl:text>
592 <xsl:call-template name="capitalize">
593 <xsl:with-param name="str" select="param [last()]/@name"/>
594 </xsl:call-template>
595 <xsl:text>); }</xsl:text>
596 </xsl:when>
597 <xsl:otherwise test="not(param)">
598 <xsl:text>() { return smth </xsl:text>
599 <xsl:call-template name="capitalize">
600 <xsl:with-param name="str" select="@name"/>
601 </xsl:call-template>
602 <xsl:text>(); }</xsl:text>
603 </xsl:otherwise>
604 </xsl:choose>
605 <xsl:text>")&#x0A;</xsl:text>
606 <!-- COM_FORWARD_Interface_Method_TO_OBJ(obj) -->
607 <xsl:text>cpp_quote("#define COM_FORWARD_</xsl:text>
608 <xsl:value-of select="$parent/@name"/>
609 <xsl:text>_</xsl:text>
610 <xsl:call-template name="capitalize">
611 <xsl:with-param name="str" select="@name"/>
612 </xsl:call-template>
613 <xsl:text>_TO_OBJ(obj) COM_FORWARD_</xsl:text>
614 <xsl:value-of select="$parent/@name"/>
615 <xsl:text>_</xsl:text>
616 <xsl:call-template name="capitalize">
617 <xsl:with-param name="str" select="@name"/>
618 </xsl:call-template>
619 <xsl:text>_TO ((obj)->)")&#x0A;</xsl:text>
620 <!-- COM_FORWARD_Interface_Method_TO_BASE(base) -->
621 <xsl:text>cpp_quote("#define COM_FORWARD_</xsl:text>
622 <xsl:value-of select="$parent/@name"/>
623 <xsl:text>_</xsl:text>
624 <xsl:call-template name="capitalize">
625 <xsl:with-param name="str" select="@name"/>
626 </xsl:call-template>
627 <xsl:text>_TO_BASE(base) COM_FORWARD_</xsl:text>
628 <xsl:value-of select="$parent/@name"/>
629 <xsl:text>_</xsl:text>
630 <xsl:call-template name="capitalize">
631 <xsl:with-param name="str" select="@name"/>
632 </xsl:call-template>
633 <xsl:text>_TO (base::)")&#x0A;</xsl:text>
634 </xsl:otherwise>
635 </xsl:choose>
636
637 <xsl:apply-templates select="@if" mode="end"/>
638
639</xsl:template>
640
641
642<!--
643 * modules
644-->
645<xsl:template match="module">
646 <xsl:apply-templates select="class"/>
647</xsl:template>
648
649
650<!--
651 * co-classes
652-->
653<xsl:template match="module/class">[
654 uuid(<xsl:value-of select="@uuid"/>)
655]
656<xsl:text>coclass </xsl:text>
657 <xsl:value-of select="@name"/>
658 <xsl:text>&#x0A;{&#x0A;</xsl:text>
659 <xsl:for-each select="interface">
660 <xsl:text> </xsl:text>
661 <xsl:if test="@default='yes'">
662 <xsl:text>[default] </xsl:text>
663 </xsl:if>
664 <xsl:text>interface </xsl:text>
665 <xsl:value-of select="@name"/>
666 <xsl:text>;&#x0A;</xsl:text>
667 </xsl:for-each>
668 <xsl:for-each select="eventsink">
669 <xsl:text> </xsl:text>
670 <xsl:choose>
671 <xsl:when test="@default='yes'"><xsl:text>[default,source]</xsl:text></xsl:when>
672 <xsl:otherwise><xsl:text>[source]</xsl:text></xsl:otherwise>
673 </xsl:choose>
674 <xsl:text> interface </xsl:text>
675 <xsl:value-of select="@name"/>
676 <xsl:text>;&#x0A;</xsl:text>
677 </xsl:for-each>
678 <xsl:text>&#x0A;}; /* coclass </xsl:text>
679 <xsl:value-of select="@name"/>
680 <xsl:text> */&#x0A;&#x0A;</xsl:text>
681</xsl:template>
682
683
684<!--
685 * enums
686-->
687<xsl:template match="enum">[
688 uuid(<xsl:value-of select="@uuid"/>),
689 v1_enum
690]
691<xsl:text>typedef enum &#x0A;{&#x0A;</xsl:text>
692 <xsl:for-each select="const">
693 <xsl:text> </xsl:text>
694 <xsl:value-of select="concat(../@name,'_',@name)"/> = <xsl:value-of select="@value"/>
695 <xsl:choose>
696 <xsl:when test="position()!=last()"><xsl:text>,&#x0A;</xsl:text></xsl:when>
697 <xsl:otherwise><xsl:text>&#x0A;</xsl:text></xsl:otherwise>
698 </xsl:choose>
699 </xsl:for-each>
700 <xsl:text>} </xsl:text>
701 <xsl:value-of select="@name"/>
702 <xsl:text>;&#x0A;&#x0A;</xsl:text>
703 <!-- -->
704 <xsl:value-of select="concat('/* cross-platform type name for ', @name, ' */&#x0A;')"/>
705 <xsl:value-of select="concat('cpp_quote(&quot;#define ', @name, '_T', ' ',
706 @name, '&quot;)&#x0A;&#x0A;')"/>
707 <xsl:text>&#x0A;&#x0A;</xsl:text>
708</xsl:template>
709
710
711<!--
712 * method parameters
713-->
714<xsl:template match="method/param">
715 <xsl:text>[</xsl:text>
716 <xsl:choose>
717 <xsl:when test="@dir='in'">in</xsl:when>
718 <xsl:when test="@dir='out'">out</xsl:when>
719 <xsl:when test="@dir='return'">out, retval</xsl:when>
720 <xsl:otherwise>in</xsl:otherwise>
721 </xsl:choose>
722 <xsl:text>] </xsl:text>
723 <xsl:if test="@safearray='yes'">
724 <xsl:text>SAFEARRAY(</xsl:text>
725 </xsl:if>
726 <xsl:apply-templates select="@type"/>
727 <xsl:if test="@safearray='yes'">
728 <xsl:text>)</xsl:text>
729 </xsl:if>
730 <xsl:if test="@dir='out' or @dir='return'">
731 <xsl:text> *</xsl:text>
732 </xsl:if>
733 <xsl:text> a</xsl:text>
734 <xsl:call-template name="capitalize">
735 <xsl:with-param name="str" select="@name"/>
736 </xsl:call-template>
737</xsl:template>
738
739<xsl:template match="method/param" mode="forwarder">
740 <xsl:choose>
741 <xsl:when test="@safearray='yes'">
742 <xsl:text>SAFEARRAY *</xsl:text>
743 </xsl:when>
744 <xsl:otherwise>
745 <xsl:apply-templates select="@type"/>
746 </xsl:otherwise>
747 </xsl:choose>
748 <xsl:if test="@dir='out' or @dir='return' or @safearray='yes'">
749 <xsl:text> *</xsl:text>
750 </xsl:if>
751 <xsl:text> a</xsl:text>
752 <xsl:call-template name="capitalize">
753 <xsl:with-param name="str" select="@name"/>
754 </xsl:call-template>
755</xsl:template>
756
757
758<!--
759 * attribute/parameter type conversion
760-->
761<xsl:template match="attribute/@type | param/@type">
762 <xsl:variable name="self_target" select="current()/ancestor::if/@target"/>
763
764 <xsl:choose>
765 <!-- modifiers -->
766 <xsl:when test="name(current())='type' and ../@mod">
767 <xsl:choose>
768 <xsl:when test="../@mod='ptr'">
769 <xsl:choose>
770 <!-- standard types -->
771 <!--xsl:when test=".='result'">??</xsl:when-->
772 <xsl:when test=".='boolean'">BOOL *</xsl:when>
773 <xsl:when test=".='octet'">BYTE *</xsl:when>
774 <xsl:when test=".='short'">SHORT *</xsl:when>
775 <xsl:when test=".='unsigned short'">USHORT *</xsl:when>
776 <xsl:when test=".='long'">LONG *</xsl:when>
777 <xsl:when test=".='long long'">LONG64 *</xsl:when>
778 <xsl:when test=".='unsigned long'">ULONG *</xsl:when>
779 <xsl:when test=".='unsigned long long'">
780 <xsl:message terminate="yes">
781 <xsl:value-of select="'&quot;unsigned long long&quot; no longer supported'" />
782 </xsl:message>
783 </xsl:when>
784 <xsl:otherwise>
785 <xsl:message terminate="yes">
786 <xsl:value-of select="concat(../../../@name,'::',../../@name,'::',../@name,': ')"/>
787 <xsl:text>attribute 'mod=</xsl:text>
788 <xsl:value-of select="concat('&quot;',../@mod,'&quot;')"/>
789 <xsl:text>' cannot be used with type </xsl:text>
790 <xsl:value-of select="concat('&quot;',current(),'&quot;!')"/>
791 </xsl:message>
792 </xsl:otherwise>
793 </xsl:choose>
794 </xsl:when>
795 <xsl:when test="../@mod='string'">
796 <xsl:choose>
797 <!-- standard types -->
798 <!--xsl:when test=".='result'">??</xsl:when-->
799 <xsl:when test=".='uuid'">BSTR</xsl:when>
800 <xsl:otherwise>
801 <xsl:message terminate="yes">
802 <xsl:value-of select="concat(../../../@name,'::',../../@name,'::',../@name,': ')"/>
803 <xsl:text>attribute 'mod=</xsl:text>
804 <xsl:value-of select="concat('&quot;',../@mod,'&quot;')"/>
805 <xsl:text>' cannot be used with type </xsl:text>
806 <xsl:value-of select="concat('&quot;',current(),'&quot;!')"/>
807 </xsl:message>
808 </xsl:otherwise>
809 </xsl:choose>
810 </xsl:when>
811 <xsl:otherwise>
812 <xsl:message terminate="yes">
813 <xsl:value-of select="concat(../../../@name,'::',../../@name,'::',../@name,': ')"/>
814 <xsl:value-of select="concat('value &quot;',../@mod,'&quot; ')"/>
815 <xsl:text>of attribute 'mod' is invalid!</xsl:text>
816 </xsl:message>
817 </xsl:otherwise>
818 </xsl:choose>
819 </xsl:when>
820 <!-- no modifiers -->
821 <xsl:otherwise>
822 <xsl:choose>
823 <!-- standard types -->
824 <xsl:when test=".='result'">HRESULT</xsl:when>
825 <xsl:when test=".='boolean'">BOOL</xsl:when>
826 <xsl:when test=".='octet'">BYTE</xsl:when>
827 <xsl:when test=".='short'">SHORT</xsl:when>
828 <xsl:when test=".='unsigned short'">USHORT</xsl:when>
829 <xsl:when test=".='long'">LONG</xsl:when>
830 <xsl:when test=".='long long'">LONG64</xsl:when>
831 <xsl:when test=".='unsigned long'">ULONG</xsl:when>
832 <xsl:when test=".='char'">CHAR</xsl:when>
833 <xsl:when test=".='string'">CHAR *</xsl:when>
834 <xsl:when test=".='wchar'">OLECHAR</xsl:when>
835 <xsl:when test=".='wstring'">BSTR</xsl:when>
836 <!-- UUID type -->
837 <xsl:when test=".='uuid'">GUID</xsl:when>
838 <!-- system interface types -->
839 <xsl:when test=".='$unknown'">IUnknown *</xsl:when>
840 <xsl:when test=".='unsigned long long'">
841 <xsl:message terminate="yes">
842 <xsl:value-of select="'&quot;unsigned long long&quot; no longer supported'" />
843 </xsl:message>
844 </xsl:when>
845 <xsl:otherwise>
846 <xsl:choose>
847 <!-- enum types -->
848 <xsl:when test="
849 (ancestor::library/enum[@name=current()]) or
850 (ancestor::library/if[@target=$self_target]/enum[@name=current()])
851 ">
852 <xsl:value-of select="."/>
853 </xsl:when>
854 <!-- custom interface types -->
855 <xsl:when test="
856 ((ancestor::library/interface[@name=current()]) or
857 (ancestor::library/if[@target=$self_target]/interface[@name=current()])
858 )
859 ">
860 <xsl:value-of select="."/><xsl:text> *</xsl:text>
861 </xsl:when>
862 <!-- other types -->
863 <xsl:otherwise>
864 <xsl:message terminate="yes">
865 <xsl:text>Unknown parameter type: </xsl:text>
866 <xsl:value-of select="."/>
867 </xsl:message>
868 </xsl:otherwise>
869 </xsl:choose>
870 </xsl:otherwise>
871 </xsl:choose>
872 </xsl:otherwise>
873 </xsl:choose>
874</xsl:template>
875
876</xsl:stylesheet>
Note: See TracBrowser for help on using the repository browser.

© 2024 Oracle Support Privacy / Do Not Sell My Info Terms of Use Trademark Policy Automated Access Etiquette