CPUMAllA.asm@ 14869

Last change on this file since 14869 was 14859, checked in by vboxsync, 16 years ago
More updates for 32/64.
Property svn:eol-style set to `native` Property svn:keywords set to `Id`
File size: 13.0 KB

Line
1	; $Id: CPUMAllA.asm 14859 2008-12-01 14:01:55Z vboxsync $
2	;; @file
3	; CPUM - Guest Context Assembly Routines.
4	;
5
6	;
7	; Copyright (C) 2006-2007 Sun Microsystems, Inc.
8	;
9	; This file is part of VirtualBox Open Source Edition (OSE), as
10	; available from http://www.virtualbox.org. This file is free software;
11	; you can redistribute it and/or modify it under the terms of the GNU
12	; General Public License (GPL) as published by the Free Software
13	; Foundation, in version 2 as it comes in the "COPYING" file of the
14	; VirtualBox OSE distribution. VirtualBox OSE is distributed in the
15	; hope that it will be useful, but WITHOUT ANY WARRANTY of any kind.
16	;
17	; Please contact Sun Microsystems, Inc., 4150 Network Circle, Santa
18	; Clara, CA 95054 USA or visit http://www.sun.com if you need
19	; additional information or have any questions.
20	;
21
22	;*******************************************************************************
23	;* Header Files *
24	;*******************************************************************************
25	%include "VBox/asmdefs.mac"
26	%include "VBox/vm.mac"
27	%include "VBox/err.mac"
28	%include "VBox/stam.mac"
29	%include "CPUMInternal.mac"
30	%include "VBox/x86.mac"
31	%include "VBox/cpum.mac"
32
33	%ifdef IN_RING3
34	%error "The jump table doesn't link on leopard."
35	%endif
36
37	;
38	; Enables write protection of Hypervisor memory pages.
39	; !note! Must be commented out for Trap8 debug handler.
40	;
41	%define ENABLE_WRITE_PROTECTION 1
42
43	BEGINCODE
44
45
46	;;
47	; Handles lazy FPU saving and restoring.
48	;
49	; This handler will implement lazy fpu (sse/mmx/stuff) saving.
50	; Two actions may be taken in this handler since the Guest OS may
51	; be doing lazy fpu switching. So, we'll have to generate those
52	; traps which the Guest CPU CTX shall have according to the
53	; its CR0 flags. If no traps for the Guest OS, we'll save the host
54	; context and restore the guest context.
55	;
56	; @returns 0 if caller should continue execution.
57	; @returns VINF_EM_RAW_GUEST_TRAP if a guest trap should be generated.
58	; @param pCPUMCPU x86:[esp+4] GCC:rdi MSC:rcx CPUMCPU pointer
59	;
60	align 16
61	BEGINPROC CPUMHandleLazyFPUAsm
62	;
63	; Figure out what to do.
64	;
65	; There are two basic actions:
66	; 1. Save host fpu and restore guest fpu.
67	; 2. Generate guest trap.
68	;
69	; When entering the hypervisor we'll always enable MP (for proper wait
70	; trapping) and TS (for intercepting all fpu/mmx/sse stuff). The EM flag
71	; is taken from the guest OS in order to get proper SSE handling.
72	;
73	;
74	; Actions taken depending on the guest CR0 flags:
75	;
76	; 3 2 1
77	; TS \| EM \| MP \| FPUInstr \| WAIT :: VMM Action
78	; ------------------------------------------------------------------------
79	; 0 \| 0 \| 0 \| Exec \| Exec :: Clear TS & MP, Save HC, Load GC.
80	; 0 \| 0 \| 1 \| Exec \| Exec :: Clear TS, Save HC, Load GC.
81	; 0 \| 1 \| 0 \| #NM \| Exec :: Clear TS & MP, Save HC, Load GC;
82	; 0 \| 1 \| 1 \| #NM \| Exec :: Clear TS, Save HC, Load GC.
83	; 1 \| 0 \| 0 \| #NM \| Exec :: Clear MP, Save HC, Load GC. (EM is already cleared.)
84	; 1 \| 0 \| 1 \| #NM \| #NM :: Go to host taking trap there.
85	; 1 \| 1 \| 0 \| #NM \| Exec :: Clear MP, Save HC, Load GC. (EM is already set.)
86	; 1 \| 1 \| 1 \| #NM \| #NM :: Go to host taking trap there.
87
88	;
89	; Before taking any of these actions we're checking if we have already
90	; loaded the GC FPU. Because if we have, this is an trap for the guest - raw ring-3.
91	;
92	%ifdef RT_ARCH_AMD64
93	%ifdef RT_OS_WINDOWS
94	mov xDX, rcx
95	%else
96	mov xDX, rdi
97	%endif
98	%else
99	mov xDX, dword [esp + 4]
100	%endif
101	test dword [xDX + CPUMCPU.fUseFlags], CPUM_USED_FPU
102	jz hlfpua_not_loaded
103	jmp hlfpua_to_host
104
105	;
106	; Take action.
107	;
108	align 16
109	hlfpua_not_loaded:
110	mov eax, [xDX + CPUMCPU.Guest.cr0]
111	and eax, X86_CR0_MP \| X86_CR0_EM \| X86_CR0_TS
112	%ifdef RT_ARCH_AMD64
113	lea r8, [hlfpuajmp1 wrt rip]
114	jmp qword [rax*4 + r8]
115	%else
116	jmp dword [eax*2 + hlfpuajmp1]
117	%endif
118	align 16
119	;; jump table using fpu related cr0 flags as index.
120	hlfpuajmp1:
121	RTCCPTR_DEF hlfpua_switch_fpu_ctx
122	RTCCPTR_DEF hlfpua_switch_fpu_ctx
123	RTCCPTR_DEF hlfpua_switch_fpu_ctx
124	RTCCPTR_DEF hlfpua_switch_fpu_ctx
125	RTCCPTR_DEF hlfpua_switch_fpu_ctx
126	RTCCPTR_DEF hlfpua_to_host
127	RTCCPTR_DEF hlfpua_switch_fpu_ctx
128	RTCCPTR_DEF hlfpua_to_host
129	;; and mask for cr0.
130	hlfpu_afFlags:
131	RTCCPTR_DEF ~(X86_CR0_TS \| X86_CR0_MP)
132	RTCCPTR_DEF ~(X86_CR0_TS)
133	RTCCPTR_DEF ~(X86_CR0_TS \| X86_CR0_MP)
134	RTCCPTR_DEF ~(X86_CR0_TS)
135	RTCCPTR_DEF ~(X86_CR0_MP)
136	RTCCPTR_DEF 0
137	RTCCPTR_DEF ~(X86_CR0_MP)
138	RTCCPTR_DEF 0
139
140	;
141	; Action - switch FPU context and change cr0 flags.
142	;
143	align 16
144	hlfpua_switch_fpu_ctx:
145	%ifndef IN_RING3 ; IN_RC or IN_RING0
146	mov xCX, cr0
147	%ifdef RT_ARCH_AMD64
148	lea r8, [hlfpu_afFlags wrt rip]
149	and rcx, [rax*4 + r8] ; calc the new cr0 flags.
150	%else
151	and ecx, [eax*2 + hlfpu_afFlags] ; calc the new cr0 flags.
152	%endif
153	mov xAX, cr0
154	and xAX, ~(X86_CR0_TS \| X86_CR0_EM)
155	mov cr0, xAX ; clear flags so we don't trap here.
156	%endif
157	%ifndef RT_ARCH_AMD64
158	mov eax, edx
159	; Calculate the PCPUM pointer
160	sub eax, [edx + CPUMCPU.ulOffCPUM]
161	test dword [eax + CPUM.CPUFeatures.edx], X86_CPUID_FEATURE_EDX_FXSR
162	jz short hlfpua_no_fxsave
163	%endif
164
165	fxsave [xDX + CPUMCPU.Host.fpu]
166	or dword [xDX + CPUMCPU.fUseFlags], (CPUM_USED_FPU \| CPUM_USED_FPU_SINCE_REM)
167	fxrstor [xDX + CPUMCPU.Guest.fpu]
168	hlfpua_finished_switch:
169	%ifdef IN_RC
170	mov cr0, xCX ; load the new cr0 flags.
171	%endif
172	; return continue execution.
173	xor eax, eax
174	ret
175
176	%ifndef RT_ARCH_AMD64
177	; legacy support.
178	hlfpua_no_fxsave:
179	fnsave [xDX + CPUMCPU.Host.fpu]
180	or dword [xDX + CPUMCPU.fUseFlags], dword (CPUM_USED_FPU \| CPUM_USED_FPU_SINCE_REM) ; yasm / nasm
181	mov eax, [xDX + CPUMCPU.Guest.fpu] ; control word
182	not eax ; 1 means exception ignored (6 LS bits)
183	and eax, byte 03Fh ; 6 LS bits only
184	test eax, [xDX + CPUMCPU.Guest.fpu + 4]; status word
185	jz short hlfpua_no_exceptions_pending
186	; technically incorrect, but we certainly don't want any exceptions now!!
187	and dword [xDX + CPUMCPU.Guest.fpu + 4], ~03Fh
188	hlfpua_no_exceptions_pending:
189	frstor [xDX + CPUMCPU.Guest.fpu]
190	jmp near hlfpua_finished_switch
191	%endif ; !RT_ARCH_AMD64
192
193
194	;
195	; Action - Generate Guest trap.
196	;
197	hlfpua_action_4:
198	hlfpua_to_host:
199	mov eax, VINF_EM_RAW_GUEST_TRAP
200	ret
201	ENDPROC CPUMHandleLazyFPUAsm
202
203
204	;;
205	; Restores the host's FPU/XMM state
206	;
207	; @returns 0
208	; @param pCPUMCPU x86:[esp+4] GCC:rdi MSC:rcx CPUMCPU pointer
209	;
210	align 16
211	BEGINPROC CPUMSaveGuestRestoreHostFPUStateAsm
212	%ifdef RT_ARCH_AMD64
213	%ifdef RT_OS_WINDOWS
214	mov xDX, rcx
215	%else
216	mov xDX, rdi
217	%endif
218	%else
219	mov xDX, dword [esp + 4]
220	%endif
221
222	; Restore FPU if guest has used it.
223	; Using fxrstor should ensure that we're not causing unwanted exception on the host.
224	test dword [xDX + CPUMCPU.fUseFlags], CPUM_USED_FPU
225	jz short gth_fpu_no
226
227	mov xAX, cr0
228	mov xCX, xAX ; save old CR0
229	and xAX, ~(X86_CR0_TS \| X86_CR0_EM)
230	mov cr0, xAX
231
232	fxsave [xDX + CPUMCPU.Guest.fpu]
233	fxrstor [xDX + CPUMCPU.Host.fpu]
234
235	mov cr0, xCX ; and restore old CR0 again
236	and dword [xDX + CPUMCPU.fUseFlags], ~CPUM_USED_FPU
237	gth_fpu_no:
238	xor eax, eax
239	ret
240	ENDPROC CPUMSaveGuestRestoreHostFPUStateAsm
241
242	;;
243	; Sets the host's FPU/XMM state
244	;
245	; @returns 0
246	; @param pCPUMCPU x86:[esp+4] GCC:rdi MSC:rcx CPUMCPU pointer
247	;
248	align 16
249	BEGINPROC CPUMRestoreHostFPUStateAsm
250	%ifdef RT_ARCH_AMD64
251	%ifdef RT_OS_WINDOWS
252	mov xDX, rcx
253	%else
254	mov xDX, rdi
255	%endif
256	%else
257	mov xDX, dword [esp + 4]
258	%endif
259
260	; Restore FPU if guest has used it.
261	; Using fxrstor should ensure that we're not causing unwanted exception on the host.
262	test dword [xDX + CPUMCPU.fUseFlags], CPUM_USED_FPU
263	jz short gth_fpu_no_2
264
265	mov xAX, cr0
266	mov xCX, xAX ; save old CR0
267	and xAX, ~(X86_CR0_TS \| X86_CR0_EM)
268	mov cr0, xAX
269
270	fxrstor [xDX + CPUMCPU.Host.fpu]
271
272	mov cr0, xCX ; and restore old CR0 again
273	and dword [xDX + CPUMCPU.fUseFlags], ~CPUM_USED_FPU
274	gth_fpu_no_2:
275	xor eax, eax
276	ret
277	ENDPROC CPUMRestoreHostFPUStateAsm
278
279	;;
280	; Restores the guest's FPU/XMM state
281	;
282	; @param pCtx x86:[esp+4] GCC:rdi MSC:rcx CPUMCTX pointer
283	;
284	align 16
285	BEGINPROC CPUMLoadFPUAsm
286	%ifdef RT_ARCH_AMD64
287	%ifdef RT_OS_WINDOWS
288	mov xDX, rcx
289	%else
290	mov xDX, rdi
291	%endif
292	%else
293	mov xDX, dword [esp + 4]
294	%endif
295	fxrstor [xDX + CPUMCTX.fpu]
296	ret
297	ENDPROC CPUMLoadFPUAsm
298
299
300	;;
301	; Restores the guest's FPU/XMM state
302	;
303	; @param pCtx x86:[esp+4] GCC:rdi MSC:rcx CPUMCTX pointer
304	;
305	align 16
306	BEGINPROC CPUMSaveFPUAsm
307	%ifdef RT_ARCH_AMD64
308	%ifdef RT_OS_WINDOWS
309	mov xDX, rcx
310	%else
311	mov xDX, rdi
312	%endif
313	%else
314	mov xDX, dword [esp + 4]
315	%endif
316	fxsave [xDX + CPUMCTX.fpu]
317	ret
318	ENDPROC CPUMSaveFPUAsm
319
320
321	;;
322	; Restores the guest's XMM state
323	;
324	; @param pCtx x86:[esp+4] GCC:rdi MSC:rcx CPUMCTX pointer
325	;
326	align 16
327	BEGINPROC CPUMLoadXMMAsm
328	%ifdef RT_ARCH_AMD64
329	%ifdef RT_OS_WINDOWS
330	mov xDX, rcx
331	%else
332	mov xDX, rdi
333	%endif
334	%else
335	mov xDX, dword [esp + 4]
336	%endif
337	movdqa xmm0, [xDX + CPUMCTX.fpu + X86FXSTATE.aXMM + 16*0]
338	movdqa xmm1, [xDX + CPUMCTX.fpu + X86FXSTATE.aXMM + 16*1]
339	movdqa xmm2, [xDX + CPUMCTX.fpu + X86FXSTATE.aXMM + 16*2]
340	movdqa xmm3, [xDX + CPUMCTX.fpu + X86FXSTATE.aXMM + 16*3]
341	movdqa xmm4, [xDX + CPUMCTX.fpu + X86FXSTATE.aXMM + 16*4]
342	movdqa xmm5, [xDX + CPUMCTX.fpu + X86FXSTATE.aXMM + 16*5]
343	movdqa xmm6, [xDX + CPUMCTX.fpu + X86FXSTATE.aXMM + 16*6]
344	movdqa xmm7, [xDX + CPUMCTX.fpu + X86FXSTATE.aXMM + 16*7]
345
346	%ifdef RT_ARCH_AMD64
347	test qword [xDX + CPUMCTX.msrEFER], MSR_K6_EFER_LMA
348	jz CPUMLoadXMMAsm_done
349
350	movdqa xmm8, [xDX + CPUMCTX.fpu + X86FXSTATE.aXMM + 16*8]
351	movdqa xmm9, [xDX + CPUMCTX.fpu + X86FXSTATE.aXMM + 16*9]
352	movdqa xmm10, [xDX + CPUMCTX.fpu + X86FXSTATE.aXMM + 16*10]
353	movdqa xmm11, [xDX + CPUMCTX.fpu + X86FXSTATE.aXMM + 16*11]
354	movdqa xmm12, [xDX + CPUMCTX.fpu + X86FXSTATE.aXMM + 16*12]
355	movdqa xmm13, [xDX + CPUMCTX.fpu + X86FXSTATE.aXMM + 16*13]
356	movdqa xmm14, [xDX + CPUMCTX.fpu + X86FXSTATE.aXMM + 16*14]
357	movdqa xmm15, [xDX + CPUMCTX.fpu + X86FXSTATE.aXMM + 16*15]
358	CPUMLoadXMMAsm_done:
359	%endif
360
361	ret
362	ENDPROC CPUMLoadXMMAsm
363
364
365	;;
366	; Restores the guest's XMM state
367	;
368	; @param pCtx x86:[esp+4] GCC:rdi MSC:rcx CPUMCTX pointer
369	;
370	align 16
371	BEGINPROC CPUMSaveXMMAsm
372	%ifdef RT_ARCH_AMD64
373	%ifdef RT_OS_WINDOWS
374	mov xDX, rcx
375	%else
376	mov xDX, rdi
377	%endif
378	%else
379	mov xDX, dword [esp + 4]
380	%endif
381	movdqa [xDX + CPUMCTX.fpu + X86FXSTATE.aXMM + 16*0], xmm0
382	movdqa [xDX + CPUMCTX.fpu + X86FXSTATE.aXMM + 16*1], xmm1
383	movdqa [xDX + CPUMCTX.fpu + X86FXSTATE.aXMM + 16*2], xmm2
384	movdqa [xDX + CPUMCTX.fpu + X86FXSTATE.aXMM + 16*3], xmm3
385	movdqa [xDX + CPUMCTX.fpu + X86FXSTATE.aXMM + 16*4], xmm4
386	movdqa [xDX + CPUMCTX.fpu + X86FXSTATE.aXMM + 16*5], xmm5
387	movdqa [xDX + CPUMCTX.fpu + X86FXSTATE.aXMM + 16*6], xmm6
388	movdqa [xDX + CPUMCTX.fpu + X86FXSTATE.aXMM + 16*7], xmm7
389
390	%ifdef RT_ARCH_AMD64
391	test qword [xDX + CPUMCTX.msrEFER], MSR_K6_EFER_LMA
392	jz CPUMSaveXMMAsm_done
393
394	movdqa [xDX + CPUMCTX.fpu + X86FXSTATE.aXMM + 16*8], xmm8
395	movdqa [xDX + CPUMCTX.fpu + X86FXSTATE.aXMM + 16*9], xmm9
396	movdqa [xDX + CPUMCTX.fpu + X86FXSTATE.aXMM + 16*10], xmm10
397	movdqa [xDX + CPUMCTX.fpu + X86FXSTATE.aXMM + 16*11], xmm11
398	movdqa [xDX + CPUMCTX.fpu + X86FXSTATE.aXMM + 16*12], xmm12
399	movdqa [xDX + CPUMCTX.fpu + X86FXSTATE.aXMM + 16*13], xmm13
400	movdqa [xDX + CPUMCTX.fpu + X86FXSTATE.aXMM + 16*14], xmm14
401	movdqa [xDX + CPUMCTX.fpu + X86FXSTATE.aXMM + 16*15], xmm15
402
403	CPUMSaveXMMAsm_done:
404	%endif
405	ret
406	ENDPROC CPUMSaveXMMAsm
407
408
409	;;
410	; Set the FPU control word; clearing exceptions first
411	;
412	; @param u16FCW x86:[esp+4] GCC:rdi MSC:rcx New FPU control word
413	align 16
414	BEGINPROC CPUMSetFCW
415	%ifdef RT_ARCH_AMD64
416	%ifdef RT_OS_WINDOWS
417	mov xAX, rcx
418	%else
419	mov xAX, rdi
420	%endif
421	%else
422	mov xAX, dword [esp + 4]
423	%endif
424	fnclex
425	push xAX
426	fldcw [xSP]
427	pop xAX
428	ret
429	ENDPROC CPUMSetFCW
430
431
432	;;
433	; Get the FPU control word
434	;
435	align 16
436	BEGINPROC CPUMGetFCW
437	fnstcw [xSP - 8]
438	mov ax, word [xSP - 8]
439	ret
440	ENDPROC CPUMGetFCW
441
442
443	;;
444	; Set the MXCSR;
445	;
446	; @param u32MXCSR x86:[esp+4] GCC:rdi MSC:rcx New MXCSR
447	align 16
448	BEGINPROC CPUMSetMXCSR
449	%ifdef RT_ARCH_AMD64
450	%ifdef RT_OS_WINDOWS
451	mov xAX, rcx
452	%else
453	mov xAX, rdi
454	%endif
455	%else
456	mov xAX, dword [esp + 4]
457	%endif
458	push xAX
459	ldmxcsr [xSP]
460	pop xAX
461	ret
462	ENDPROC CPUMSetMXCSR
463
464
465	;;
466	; Get the MXCSR
467	;
468	align 16
469	BEGINPROC CPUMGetMXCSR
470	stmxcsr [xSP - 8]
471	mov eax, dword [xSP - 8]
472	ret
473	ENDPROC CPUMGetMXCSR

Note: See TracBrowser for help on using the repository browser.

source: vbox/trunk/src/VBox/VMM/VMMAll/CPUMAllA.asm@ 14869

Download in other formats: