bootsector2-common-init-traps.mac@ 53346

Last change on this file since 53346 was 52776, checked in by vboxsync, 10 years ago
fix OSE
Property svn:eol-style set to `native` Property svn:keywords set to `Author Date Id Revision`
File size: 54.7 KB

Line
1	; $Id: bootsector2-common-init-traps.mac 52776 2014-09-17 14:51:43Z vboxsync $
2	;; @file
3	; Common bootsector code init, traps.
4	;
5	; This is included from bootsector2-common-init-code.mac and was split out of
6	; that file to keep the size manageable.
7	;
8
9	;
10	; Copyright (C) 2007-2014 Oracle Corporation
11	;
12	; This file is part of VirtualBox Open Source Edition (OSE), as
13	; available from http://www.virtualbox.org. This file is free software;
14	; you can redistribute it and/or modify it under the terms of the GNU
15	; General Public License (GPL) as published by the Free Software
16	; Foundation, in version 2 as it comes in the "COPYING" file of the
17	; VirtualBox OSE distribution. VirtualBox OSE is distributed in the
18	; hope that it will be useful, but WITHOUT ANY WARRANTY of any kind.
19	;
20	; The contents of this file may alternatively be used under the terms
21	; of the Common Development and Distribution License Version 1.0
22	; (CDDL) only, as it comes in the "COPYING.CDDL" file of the
23	; VirtualBox OSE distribution, in which case the provisions of the
24	; CDDL are applicable instead of those of the GPL.
25	;
26	; You may elect to license modified versions of this file under the
27	; terms and conditions of either the GPL or the CDDL or both.
28	;
29
30	%ifndef BS2_WITH_TRAPS
31	%error "huh? BS2_WITH_TRAPS is not defined!"
32	%endif
33
34
35	;*******************************************************************************
36	;* Header Files *
37	;*******************************************************************************
38	%include "bootsector2-structures.mac"
39	%include "bootsector2-api.mac"
40
41
42	;*******************************************************************************
43	;* Global Variables *
44	;*******************************************************************************
45	BEGINCODELOW
46	ALIGNDATA(8)
47	;; Where to resume execution after a trap (if g_fTrapPrepared is set).
48	; @internal
49	g_TrapResumeRIP:
50	dq 0
51	;; Set if we've prepared for a trap.
52	; @internal
53	g_fTrapPrepared:
54	db 0
55	;; Benchmark indicator.
56	; This is set to the expected trap number when we're benchmarking and 0ffh when
57	; we aren't benchmarking.
58	; @internal
59	g_u8TrapBenchmarkNo:
60	db 0ffh
61	db 0 ; alignment padding.
62	;; The last trap number.
63	GLOBALNAME g_u8LastTrapNo
64	db 0
65	;; The number of traps since last call to Bs2TrapReset.
66	GLOBALNAME g_u32cTraps
67	dd 0
68	;; The last trap error code.
69	GLOBALNAME g_u64LastTrapErr
70	dq 0
71	;; The register frame of the last trap (BS2REGS).
72	GLOBALNAME g_LastTrapRegs
73	times (BS2REGS_size) db 0
74
75	;; The RFLAGS/EFLAGS inside last invoked trap handler.
76	GLOBALNAME g_u64LastTrapHandlerRFlags
77	dq 0
78	;; The CS inside last invoked trap handler.
79	GLOBALNAME g_u16LastTrapHandlerCS
80	dw 0
81	;; The SS inside last invoked trap handler.
82	GLOBALNAME g_u16LastTrapHandlerSS
83	dw 0
84	dw 0,0 ; alignment
85	;; The RSP inside the last invoked trap handler, i.e. when bs2Trap_XX_32bit is
86	; entered, so including fake error code and vector number.
87	GLOBALNAME g_u64LastTrapHandlerRSP
88	dq 0
89
90	;;
91	; Pointer to an array of BS2TRAPREC1 records.
92	GLOBALNAME g_paTrapRecs
93	dq 0
94	;; Number of entries in the array g_paTrapRecs points to.
95	GLOBALNAME g_cTrapRecs
96	dd 0
97	;; The index of the last BS2TRAPREC1 we hit.
98	GLOBALNAME g_iTrapRecLast
99	dd 0
100	;; The base address the BS2TRAPREC.offWhere values are relative to.
101	GLOBALNAME g_pTrapRecBase
102	dq 0
103
104
105	;;
106	; Reset all the trap globals to default.
107	;
108	; This undos the effect of any previous Bs2TrapPrepare call.
109	;
110	; @uses nothing.
111	;
112	BEGINCODELOW
113	BITS 16
114	BEGINPROC Bs2TrapReset_rm16
115	push xBP
116	mov xBP, xSP
117	push ds
118	push word 0
119	pop ds
120
121	mov dword [g_u32cTraps], 0
122	mov byte [g_u8LastTrapNo], 0ffh
123	mov dword [g_u64LastTrapErr], 0
124	mov dword [g_u64LastTrapErr + 4], 0
125	mov dword [g_TrapResumeRIP], 0
126	mov dword [g_TrapResumeRIP + 4], 0
127	mov byte [g_u8TrapBenchmarkNo], 0ffh
128	mov byte [g_fTrapPrepared], 0
129
130	pop ds
131	leave
132	ret
133	ENDPROC Bs2TrapReset_rm16
134
135
136	;;
137	; Reset all the trap globals to default.
138	;
139	; This undos the effect of any previous Bs2TrapPrepare call.
140	;
141	; @uses nothing.
142	;
143	BEGINCODELOW
144	BITS 16
145	BEGINPROC Bs2TrapReset_p16
146	push ds
147	push BS2_SEL_DS16
148	pop ds
149
150	mov dword [g_u32cTraps], 0
151	mov byte [g_u8LastTrapNo], 0ffh
152	mov dword [g_u64LastTrapErr], 0
153	mov dword [g_u64LastTrapErr + 4], 0
154	mov dword [g_TrapResumeRIP], 0
155	mov dword [g_TrapResumeRIP + 4], 0
156	mov byte [g_u8TrapBenchmarkNo], 0ffh
157	mov byte [g_fTrapPrepared], 0
158
159	pop ds
160	ret
161	ENDPROC Bs2TrapReset_p16
162
163
164
165	;;
166	; Reset all the trap globals to default.
167	;
168	; This undos the effect of any previous Bs2TrapPrepare call.
169	;
170	; @uses nothing.
171	;
172	BEGINCODEHIGH
173	BITS 32
174	BEGINPROC Bs2TrapReset_p32
175	push ds
176	push BS2_SEL_DS32
177	pop ds
178
179	mov dword [g_u32cTraps], 0
180	mov byte [g_u8LastTrapNo], 0ffh
181	mov dword [g_u64LastTrapErr], 0
182	mov dword [g_u64LastTrapErr + 4], 0
183	mov dword [g_TrapResumeRIP], 0
184	mov dword [g_TrapResumeRIP + 4], 0
185	mov byte [g_u8TrapBenchmarkNo], 0ffh
186	mov byte [g_fTrapPrepared], 0
187
188	pop ds
189	ret
190	ENDPROC Bs2TrapReset_p32
191
192
193	;;
194	; Reset all the trap globals to default.
195	;
196	; This undos the effect of any previous Bs2TrapPrepare call.
197	;
198	; @uses nothing.
199	;
200	BEGINCODEHIGH
201	BITS 64
202	BEGINPROC Bs2TrapReset_p64
203	mov dword [g_u32cTraps], 0
204	mov byte [g_u8LastTrapNo], 0ffh
205	mov qword [g_u64LastTrapErr], 0
206	mov qword [g_TrapResumeRIP], 0
207	mov byte [g_u8TrapBenchmarkNo], 0ffh
208	mov byte [g_fTrapPrepared], 0
209	ret
210	ENDPROC Bs2TrapReset_p64
211
212
213
214	;;
215	; Prepare for a test that will trap.
216	;
217	; @param xAX Where to resume after the trap.
218	; @param dl Set to 0ffh for tests and the expected trap number when
219	; preparing a benchmark.
220	; @uses nothing.
221	;
222	BEGINCODELOW
223	BITS 16
224	BEGINPROC Bs2TrapPrepare_rm16
225	push xBP
226	mov xBP, xSP
227	push ds
228	push word 0
229	pop ds
230
231	mov dword [g_u32cTraps], 0
232	mov byte [g_u8LastTrapNo], 0ffh
233	mov dword [g_u64LastTrapErr], 0
234	mov dword [g_u64LastTrapErr + 4], 0
235	mov word [g_TrapResumeRIP], ax
236	mov word [g_TrapResumeRIP + 2], 0
237	mov dword [g_TrapResumeRIP + 4], 0
238	mov byte [g_u8TrapBenchmarkNo], dl
239	mov byte [g_fTrapPrepared], 1
240
241	pop ds
242	leave
243	ret
244	ENDPROC Bs2TrapPrepare_rm16
245
246
247	;;
248	; Prepare for a test that will trap.
249	;
250	; @param ax Where to resume after the trap.
251	; @param dl Set to 0ffh for tests and the expected trap number when
252	; preparing a benchmark.
253	; @uses nothing.
254	;
255	BEGINCODELOW
256	BITS 16
257	BEGINPROC Bs2TrapPrepare_p16
258	push ds
259	push BS2_SEL_DS16
260	pop ds
261
262	mov dword [g_u32cTraps], 0
263	mov byte [g_u8LastTrapNo], 0ffh
264	mov dword [g_u64LastTrapErr], 0
265	mov dword [g_u64LastTrapErr + 4], 0
266	mov word [g_TrapResumeRIP], ax
267	mov word [g_TrapResumeRIP + 2], 0
268	mov dword [g_TrapResumeRIP + 4], 0
269	mov byte [g_u8TrapBenchmarkNo], dl
270	mov byte [g_fTrapPrepared], 1
271
272	pop ds
273	ret
274	ENDPROC Bs2TrapPrepare_p16
275
276
277	;;
278	; Prepare for a test that will trap.
279	;
280	; @param eax Where to resume after the trap.
281	; @param dl Set to 0ffh for tests and the expected trap number when
282	; preparing a benchmark.
283	; @uses nothing.
284	;
285	BEGINCODEHIGH
286	BITS 32
287	BEGINPROC Bs2TrapPrepare_p32
288	push ds
289	push BS2_SEL_DS32
290	pop ds
291
292	mov dword [g_u32cTraps], 0
293	mov byte [g_u8LastTrapNo], 0ffh
294	mov dword [g_u64LastTrapErr], 0
295	mov dword [g_u64LastTrapErr + 4], 0
296	mov dword [g_TrapResumeRIP], eax
297	mov dword [g_TrapResumeRIP + 4], 0
298	mov byte [g_u8TrapBenchmarkNo], dl
299	mov byte [g_fTrapPrepared], 1
300
301	pop ds
302	ret
303	ENDPROC Bs2TrapPrepare_p32
304
305
306	;;
307	; Prepare for a test that will trap.
308	;
309	; @param rax Where to resume after the trap.
310	; @param dl Set to 0ffh for tests and the expected trap number when
311	; preparing a benchmark.
312	; @uses nothing.
313	;
314	BEGINCODEHIGH
315	BITS 64
316	BEGINPROC Bs2TrapPrepare_p64
317	mov dword [g_u32cTraps], 0
318	mov byte [g_u8LastTrapNo], 0ffh
319	mov qword [g_u64LastTrapErr], 0
320	mov qword [g_TrapResumeRIP], rax
321	mov byte [g_u8TrapBenchmarkNo], dl
322	mov byte [g_fTrapPrepared], 1
323	ret
324	ENDPROC Bs2TrapPrepare_p64
325
326
327	BEGINCODELOW ; The TSSes, IDTs and handlers must be 16-bit addressable.
328
329	%ifdef BS2_INC_CMN_PM
330	;
331	; 32-bit TSS (X86TSS32).
332	;
333	ALIGNDATA(16)
334	bs2Tss32Bit:
335	dw 07fffh ; selPrev - Back link to previous task. (static)
336	dw 0h ; padding1;
337	dd BS2_R0_STACK_ADDR ; esp0 - Ring-0 stack pointer. (static)
338	dw BS2_SEL_SS32 ; ss0
339	dw 0 ; padding
340	dd BS2_R1_STACK_ADDR ; esp1 - Ring-1 stack pointer. (static)
341	dw 0 ; ss1
342	dw 0 ; padding
343	dd BS2_R2_STACK_ADDR ; esp2 - Ring-1 stack pointer. (static)
344	dw 0 ; ss2
345	dw 0 ; padding
346	dd 0ffffffffh ; cr3 - Page directory for the task. (static)
347	dd 0 ; eip - EIP before task switch.
348	dd 0 ; eflags - EFLAGS before task switch.
349	dd 0 ; eax - EAX before task switch.
350	dd 0 ; ecx - ECX before task switch.
351	dd 0 ; edx - EDX before task switch.
352	dd 0 ; ebx - EBX before task switch.
353	dd 0 ; esp - ESP before task switch.
354	dd 0 ; ebp - EBP before task switch.
355	dd 0 ; esi - ESI before task switch.
356	dd 0 ; edi - EDI before task switch.
357	dw 0, 0 ; es,pad - ES before task switch.
358	dw 0, 0 ; cs,pad - CS before task switch.
359	dw 0, 0 ; ss,pad - SS before task switch.
360	dw 0, 0 ; ds,pad - DS before task switch.
361	dw 0, 0 ; fs,pad - FS before task switch.
362	dw 0, 0 ; gs,pad - GS before task switch.
363	dw 0, 0 ; ldt,pad - LDTR before task switch.
364	dw 0 ; fDebugTrap - Debug trap flag.
365	dw 7fffh ; offIoBitmap - Offset relative to the TSS of the
366	; start of the I/O Bitmap and the end of the
367	; interrupt redirection bitmap.
368	; IntRedirBitmap - 32 bytes for the virtual interrupt redirection bitmap. (VME)
369	bs2Tss32BitEnd:
370	times (68h - (bs2Tss32BitEnd - bs2Tss32Bit)) db 0
371	times ((bs2Tss32BitEnd - bs2Tss32Bit) - 68h) db 0
372
373
374	;
375	; 32-bit TSS for #DF (X86TSS32).
376	;
377	ALIGNDATA(16)
378	bs2Tss32BitDf:
379	dw 07fffh ; selPrev - Back link to previous task. (static)
380	dw 0h ; padding1;
381	dd BS2_DF_R0_STACK_ADDR ; esp0 - Ring-0 stack pointer. (static)
382	dw BS2_SEL_SS32 ; ss0
383	dw 0 ; padding
384	dd 0 ; esp1 - Ring-1 stack pointer. (static)
385	dw 0 ; ss1
386	dw 0 ; padding
387	dd 0 ; esp2 - Ring-1 stack pointer. (static)
388	dw 0 ; ss2
389	dw 0 ; padding
390	dd 0ffffffffh ; cr3 - Page directory for the task. (static)
391	dd bs2Trap_08h_32bit ; eip - EIP before task switch. */
392	dd 0 ; eflags - EFLAGS before task switch. */
393	dd 0 ; eax - EAX before task switch. */
394	dd 0 ; ecx - ECX before task switch. */
395	dd 0 ; edx - EDX before task switch. */
396	dd 0 ; ebx - EBX before task switch. */
397	dd BS2_DF_R0_STACK_ADDR ; esp - ESP before task switch. */
398	dd 0 ; ebp - EBP before task switch. */
399	dd 0 ; esi - ESI before task switch. */
400	dd 0 ; edi - EDI before task switch. */
401	dw BS2_SEL_DS32, 0 ; es,pad - ES before task switch. */
402	dw BS2_SEL_CS32, 0 ; cs,pad - CS before task switch. */
403	dw BS2_SEL_SS32, 0 ; ss,pad - SS before task switch. */
404	dw BS2_SEL_DS32, 0 ; ds,pad - DS before task switch. */
405	dw BS2_SEL_DS32, 0 ; fs,pad - FS before task switch. */
406	dw BS2_SEL_DS32, 0 ; gs,pad - GS before task switch. */
407	dw 0, 0 ; ldt,pad- LDTR before task switch. */
408	dw 0 ; fDebugTrap - Debug trap flag.
409	dw 7fffh ; offIoBitmap - Offset relative to the TSS of the
410	; start of the I/O Bitmap and the end of the
411	; interrupt redirection bitmap.
412	; IntRedirBitmap - 32 bytes for the virtual interrupt redirection bitmap. (VME)
413	bs2Tss32BitDfEnd:
414	times (68h - (bs2Tss32BitDfEnd - bs2Tss32BitDf)) db 0
415	times ((bs2Tss32BitDfEnd - bs2Tss32BitDf) - 68h) db 0
416
417
418	;
419	; 32-bit IDT (X86DESCGATE).
420	;
421	ALIGNDATA(16)
422	bs2Idt32bit:
423	dw bs2Trap_00h_32bit, BS2_SEL_CS32, 08e00h, 00000h ; p=1 dpl=0 type=int32gate
424	dw bs2Trap_01h_32bit, BS2_SEL_CS32, 08e00h, 00000h ; p=1 dpl=0 type=int32gate
425	dw bs2Trap_02h_32bit, BS2_SEL_CS32, 08e00h, 00000h ; p=1 dpl=0 type=int32gate
426	bs2Idt32bit_BP:
427	dw bs2Trap_03h_32bit, BS2_SEL_CS32, 08e00h, 00000h ; p=1 dpl=0 type=int32gate
428	dw bs2Trap_04h_32bit, BS2_SEL_CS32, 08e00h, 00000h ; p=1 dpl=0 type=int32gate
429	dw bs2Trap_05h_32bit, BS2_SEL_CS32, 08e00h, 00000h ; p=1 dpl=0 type=int32gate
430	dw bs2Trap_06h_32bit, BS2_SEL_CS32, 08e00h, 00000h ; p=1 dpl=0 type=int32gate
431	dw bs2Trap_07h_32bit, BS2_SEL_CS32, 08e00h, 00000h ; p=1 dpl=0 type=int32gate
432	dw 0, BS2_SEL_TSS32_DF, 08500h, 00000h ; p=1 dpl=0 type=taskgate
433	dw bs2Trap_09h_32bit, BS2_SEL_CS32, 08e00h, 00000h ; p=1 dpl=0 type=int32gate
434	dw bs2Trap_0ah_32bit, BS2_SEL_CS32, 08e00h, 00000h ; p=1 dpl=0 type=int32gate
435	dw bs2Trap_0bh_32bit, BS2_SEL_CS32, 08e00h, 00000h ; p=1 dpl=0 type=int32gate
436	dw bs2Trap_0ch_32bit, BS2_SEL_CS32, 08e00h, 00000h ; p=1 dpl=0 type=int32gate
437	dw bs2Trap_0dh_32bit, BS2_SEL_CS32, 08e00h, 00000h ; p=1 dpl=0 type=int32gate
438	dw bs2Trap_0eh_32bit, BS2_SEL_CS32, 08e00h, 00000h ; p=1 dpl=0 type=int32gate
439	dw bs2Trap_0fh_32bit, BS2_SEL_CS32, 08e00h, 00000h ; p=1 dpl=0 type=int32gate
440	dw bs2Trap_10h_32bit, BS2_SEL_CS32, 08e00h, 00000h ; p=1 dpl=0 type=int32gate
441	dw bs2Trap_11h_32bit, BS2_SEL_CS32, 08e00h, 00000h ; p=1 dpl=0 type=int32gate
442	dw bs2Trap_12h_32bit, BS2_SEL_CS32, 08e00h, 00000h ; p=1 dpl=0 type=int32gate
443	dw bs2Trap_13h_32bit, BS2_SEL_CS32, 08e00h, 00000h ; p=1 dpl=0 type=int32gate
444	dw bs2Trap_14h_32bit, BS2_SEL_CS32, 08e00h, 00000h ; p=1 dpl=0 type=int32gate
445	dw bs2Trap_15h_32bit, BS2_SEL_CS32, 08e00h, 00000h ; p=1 dpl=0 type=int32gate
446	dw bs2Trap_16h_32bit, BS2_SEL_CS32, 08e00h, 00000h ; p=1 dpl=0 type=int32gate
447	dw bs2Trap_17h_32bit, BS2_SEL_CS32, 08e00h, 00000h ; p=1 dpl=0 type=int32gate
448	dw bs2Trap_18h_32bit, BS2_SEL_CS32, 08e00h, 00000h ; p=1 dpl=0 type=int32gate
449	dw bs2Trap_19h_32bit, BS2_SEL_CS32, 08e00h, 00000h ; p=1 dpl=0 type=int32gate
450	dw bs2Trap_1ah_32bit, BS2_SEL_CS32, 08e00h, 00000h ; p=1 dpl=0 type=int32gate
451	dw bs2Trap_1bh_32bit, BS2_SEL_CS32, 08e00h, 00000h ; p=1 dpl=0 type=int32gate
452	dw bs2Trap_1ch_32bit, BS2_SEL_CS32, 08e00h, 00000h ; p=1 dpl=0 type=int32gate
453	dw bs2Trap_1dh_32bit, BS2_SEL_CS32, 08e00h, 00000h ; p=1 dpl=0 type=int32gate
454	dw bs2Trap_1eh_32bit, BS2_SEL_CS32, 08e00h, 00000h ; p=1 dpl=0 type=int32gate
455	dw bs2Trap_1fh_32bit, BS2_SEL_CS32, 08e00h, 00000h ; p=1 dpl=0 type=int32gate
456	dw bs2TrapService32bit,BS2_SEL_CS32,0ee00h, 00000h, 0, 0, 0, 0 ; p=1 dpl=3 type=int32gate
457	%define BS2_TRAP_SERVICE_NO 30h
458	;; @todo
459	bs2Idt32bitEnd
460
461	;
462	; 32-bit trap handlers.
463	;
464	BITS 32
465	%macro bs2Trap_XX_32bit_macro 1
466	bs2Trap_ %+ %1 %+ _32bit:
467	push %1
468	jmp bs2Trap_XX_32bit
469	%endmacro
470	%macro bs2Trap_XX_32bit_macro_no_err 1
471	bs2Trap_ %+ %1 %+ _32bit:
472	push 0
473	push %1
474	jmp bs2Trap_XX_32bit
475	%endmacro
476	bs2Trap_XX_32bit_macro_no_err 00h
477	bs2Trap_XX_32bit_macro_no_err 01h
478	bs2Trap_XX_32bit_macro_no_err 02h
479	bs2Trap_XX_32bit_macro_no_err 03h
480	bs2Trap_XX_32bit_macro_no_err 04h
481	bs2Trap_XX_32bit_macro_no_err 05h
482	bs2Trap_XX_32bit_macro_no_err 06h
483	bs2Trap_XX_32bit_macro_no_err 07h
484	bs2Trap_XX_32bit_macro 08h
485	bs2Trap_XX_32bit_macro_no_err 09h
486	bs2Trap_XX_32bit_macro 0ah
487	bs2Trap_XX_32bit_macro 0bh
488	bs2Trap_XX_32bit_macro 0ch
489	bs2Trap_XX_32bit_macro 0dh
490	bs2Trap_XX_32bit_macro 0eh
491	bs2Trap_XX_32bit_macro_no_err 0fh
492	bs2Trap_XX_32bit_macro_no_err 10h
493	bs2Trap_XX_32bit_macro 11h
494	bs2Trap_XX_32bit_macro_no_err 12h
495	bs2Trap_XX_32bit_macro_no_err 13h
496	bs2Trap_XX_32bit_macro_no_err 14h
497	bs2Trap_XX_32bit_macro_no_err 15h
498	bs2Trap_XX_32bit_macro_no_err 16h
499	bs2Trap_XX_32bit_macro_no_err 17h
500	bs2Trap_XX_32bit_macro_no_err 18h
501	bs2Trap_XX_32bit_macro_no_err 19h
502	bs2Trap_XX_32bit_macro_no_err 1ah
503	bs2Trap_XX_32bit_macro_no_err 1bh
504	bs2Trap_XX_32bit_macro_no_err 1ch
505	bs2Trap_XX_32bit_macro_no_err 1dh
506	bs2Trap_XX_32bit_macro_no_err 1eh
507	bs2Trap_XX_32bit_macro_no_err 1fh
508
509	;;
510	; Common 32-bit trap handler.
511	;
512	; return GS ebp + 2ch - v86
513	; return FS ebp + 28h - v86
514	; return DS ebp + 24h - v86
515	; return ES ebp + 20h - v86
516	; return SS ebp + 1ch - higher privilege
517	; return ESP ebp + 18h - higher privilege
518	; return EFLAGS ebp + 14h
519	; return CS ebp + 10h
520	; return EIP ebp + 0ch
521	; error code ebp + 08h
522	; vector # ebp + 04h
523	BITS 32
524	BEGINCODEHIGH
525	BEGINPROC bs2Trap_XX_32bit
526	push ebp ; ebp + 00h
527	mov ebp, esp
528	pushfd ; ebp - 04h
529	push eax ; ebp - 08h
530	push ebx ; ebp - 0ch
531	push ecx ; ebp - 10h
532	push ds ; ebp - 14h
533
534	mov eax, ss ; load flat DS. Using SS here because of conforming IDTE.CS tests.
535	mov ds, ax
536
537	;
538	; Benchmark mode? Then resume the action right away!
539	;
540	mov eax, [ebp + 04h]
541	cmp [g_u8TrapBenchmarkNo], al
542	jne .test_mode
543	cmp byte [g_fTrapPrepared], 0
544	je .test_mode
545	mov eax, [g_TrapResumeRIP]
546	mov [ebp + 0ch], eax
547
548	pop ds
549	pop ecx
550	pop ebx
551	;pop eax
552	;popfd
553	leave
554	add esp, 08h ; Skip the vector # and error code.
555	xor eax, eax
556	iret
557
558
559	;
560	; Update the globals.
561	;
562	.test_mode:
563	xor ecx, ecx ; zero register
564	inc dword [g_u32cTraps]
565	mov eax, [ebp + 04h]
566	mov [g_u8LastTrapNo], al
567	mov eax, [ebp + 08h]
568	mov [g_u64LastTrapErr], eax
569	mov [g_u64LastTrapErr + 4], ecx
570	mov eax, [ebp - 04h]
571	mov [g_u64LastTrapHandlerRFlags], eax
572	mov dword [g_u64LastTrapHandlerRFlags + 4], ecx
573	mov ax, cs
574	mov [g_u16LastTrapHandlerCS], ax
575	mov ax, ss
576	mov [g_u16LastTrapHandlerSS], ax
577	lea eax, [ebp + 4]
578	mov [g_u64LastTrapHandlerRSP], eax
579	mov [g_u64LastTrapHandlerRSP + 4], ecx
580
581	;
582	; Save the registers.
583	;
584	lea ebx, [g_LastTrapRegs]
585	mov eax, [ebp - 08h]
586	mov [ebx + BS2REGS.rax], eax
587	mov [ebx + BS2REGS.rax + 4], ecx
588	mov eax, [ebp - 0ch]
589	mov [ebx + BS2REGS.rbx], eax
590	mov [ebx + BS2REGS.rbx + 4], ecx
591	mov eax, [ebp - 10h]
592	mov [ebx + BS2REGS.rcx], eax
593	mov [ebx + BS2REGS.rcx + 4], ecx
594	mov [ebx + BS2REGS.rdx], edx
595	mov [ebx + BS2REGS.rdx + 4], ecx
596	mov [ebx + BS2REGS.rdi], edi
597	mov [ebx + BS2REGS.rdi + 4], ecx
598	mov [ebx + BS2REGS.rsi], esi
599	mov [ebx + BS2REGS.rsi + 4], ecx
600	mov eax, [ebp]
601	mov [ebx + BS2REGS.rbp], eax
602	mov [ebx + BS2REGS.rbp + 4], ecx
603	mov eax, [ebp + 0ch]
604	mov [ebx + BS2REGS.rip], eax
605	mov [ebx + BS2REGS.rip + 4], ecx
606	mov [ebx + BS2REGS.r8], ecx
607	mov [ebx + BS2REGS.r8 + 4], ecx
608	mov [ebx + BS2REGS.r9], ecx
609	mov [ebx + BS2REGS.r9 + 4], ecx
610	mov [ebx + BS2REGS.r10], ecx
611	mov [ebx + BS2REGS.r10 + 4], ecx
612	mov [ebx + BS2REGS.r11], ecx
613	mov [ebx + BS2REGS.r11 + 4], ecx
614	mov [ebx + BS2REGS.r12], ecx
615	mov [ebx + BS2REGS.r12 + 4], ecx
616	mov [ebx + BS2REGS.r13], ecx
617	mov [ebx + BS2REGS.r13 + 4], ecx
618	mov [ebx + BS2REGS.r14], ecx
619	mov [ebx + BS2REGS.r14 + 4], ecx
620	mov [ebx + BS2REGS.r15], ecx
621	mov [ebx + BS2REGS.r15 + 4], ecx
622	mov eax, [ebp + 14h]
623	mov [ebx + BS2REGS.rflags], eax
624	mov [ebx + BS2REGS.rflags+4],ecx
625	mov eax, [ebp + 10h]
626	mov [ebx + BS2REGS.cs], ax
627	mov [ebx + BS2REGS.cBits], byte 32
628
629	; Part of the stack varies depending on the trap context.
630	test dword [ebx + BS2REGS.rflags], X86_EFL_VM
631	jnz .v86
632	test ax, 7h
633	jz .ring0
634
635	.ring0:
636	lea eax, [ebp + 18h]
637	mov [ebx + BS2REGS.rsp], eax
638	mov [ebx + BS2REGS.rsp + 4], ecx
639	mov [ebx + BS2REGS.ss], ss
640	mov eax, [ebp - 14h]
641	mov [ebx + BS2REGS.ds], ax
642	mov [ebx + BS2REGS.es], es
643	mov [ebx + BS2REGS.fs], fs
644	mov [ebx + BS2REGS.gs], gs
645	jmp .do_crX
646
647	.higher_privilege:
648	mov eax, [ebp + 18h]
649	mov [ebx + BS2REGS.rsp], eax
650	mov [ebx + BS2REGS.rsp + 4], ecx
651	mov eax, [ebp + 20h]
652	mov [ebx + BS2REGS.ss], ax
653	mov eax, [ebp - 14h]
654	mov [ebx + BS2REGS.ds], ax
655	mov [ebx + BS2REGS.es], es
656	mov [ebx + BS2REGS.fs], fs
657	mov [ebx + BS2REGS.gs], gs
658	jmp .do_crX
659
660	.v86:
661	mov eax, [ebp + 18h]
662	mov [ebx + BS2REGS.rsp], eax
663	mov [ebx + BS2REGS.rsp + 4], ecx
664	mov eax, [ebp + 1ch]
665	mov [ebx + BS2REGS.ss], ax
666	mov eax, [ebp + 24h]
667	mov [ebx + BS2REGS.ds], ax
668	mov eax, [ebp + 20h]
669	mov [ebx + BS2REGS.es], ax
670	mov eax, [ebp + 28h]
671	mov [ebx + BS2REGS.fs], ax
672	mov eax, [ebp + 2ch]
673	mov [ebx + BS2REGS.gs], ax
674	;jmp .do_crX
675
676	.do_crX:
677	; The CRx registers are only accessible from ring-0 (CS=conforming, CPL < 0)
678	test byte [ebx + BS2REGS.ss], 3
679	jnz .skip_crX
680	mov eax, cr0
681	mov [ebx + BS2REGS.cr0], eax
682	mov [ebx + BS2REGS.cr0 + 4], ecx
683	mov eax, cr2
684	mov [ebx + BS2REGS.cr2], eax
685	mov [ebx + BS2REGS.cr2 + 4], ecx
686	mov eax, cr3
687	mov [ebx + BS2REGS.cr3], eax
688	mov [ebx + BS2REGS.cr3 + 4], ecx
689	mov eax, cr4
690	mov [ebx + BS2REGS.cr4], eax
691	mov [ebx + BS2REGS.cr4 + 4], ecx
692	mov [ebx + BS2REGS.cr8], ecx
693	mov [ebx + BS2REGS.cr8 + 4], ecx
694	.skip_crX:
695
696	;
697	; Advance to a prepared resume position or panic.
698	;
699	cmp byte [g_fTrapPrepared], 0
700	je .no_resume_pos
701	mov byte [g_fTrapPrepared], 0
702	mov eax, [g_TrapResumeRIP]
703	mov [ebp + 0ch], eax
704
705	.resume:
706	%ifdef BS2_WITH_XCPT_DB_CLEARING_TF
707	cmp byte [ebp + 04h], X86_XCPT_DB ; make sure we won't trap again due to a TF.
708	jne .resume_no_clear_trap_flags
709	and word [ebp + 14h], ~X86_EFL_TF
710	.resume_no_clear_trap_flags:
711	%endif
712	pop ds
713	pop ecx
714	pop ebx
715	pop eax
716	;popfd
717	leave
718	add esp, 8h
719	iret
720
721
722	.no_resume_pos:
723	;
724	; Look for a trap record.
725	;
726	mov ecx, [g_cTrapRecs] ; the number of records.
727	test ecx, ecx
728	jz .panic
729	mov eax, [g_LastTrapRegs + BS2REGS.rip]
730	sub eax, [g_pTrapRecBase] ; the offWhere we're looking for.
731	jb .panic
732
733	; Look starting at the previous record first.
734	mov ebx, [g_iTrapRecLast]
735	sub ecx, ebx
736	jbe .traprec_loop2 ; g_iTrapRecLast is out of range.
737	shl ebx, BS2TRAPREC_SIZE_SHIFT
738	add ebx, [g_paTrapRecs] ; ebx points to the record we hit last time.
739	.traprec_loop1_next:
740	cmp [ebx + BS2TRAPREC.offWhere], eax
741	je .traprec_found
742	add ebx, BS2TRAPREC_size
743	dec ecx
744	jnz .traprec_loop1_next
745
746	; Start searching from the start, stopping at the previous record.
747	.traprec_loop2:
748	mov ecx, [g_iTrapRecLast]
749	or ecx, ecx
750	jz .panic ; not found.
751	mov ebx, [g_paTrapRecs]
752	.traprec_loop2_next:
753	cmp [ebx + BS2TRAPREC.offWhere], eax
754	je .traprec_found
755	add ebx, BS2TRAPREC_size
756	dec ecx
757	jnz .traprec_loop2_next
758	jmp .panic ; not found
759
760	.traprec_found:
761	; Remember the hit for the next trap.
762	mov eax, ebx
763	sub eax, [g_paTrapRecs]
764	shr eax, BS2TRAPREC_SIZE_SHIFT
765	mov [g_iTrapRecLast], eax
766
767	;
768	; Fail the test if we got the wrong trap or error code.
769	;
770	mov al, [g_u8LastTrapNo]
771	cmp al, [ebx + BS2TRAPREC.u8TrapNo]
772	je .traprec_ok_trap
773	push eax
774	movzx eax, byte [ebx + BS2TRAPREC.u8TrapNo]
775	push eax
776	push .s_szWrongTrap
777	call NAME(TestFailedF_p32)
778	add esp, 12
779
780	.traprec_ok_trap:
781	mov ax, [g_u64LastTrapErr]
782	cmp ax, [ebx + BS2TRAPREC.u16ErrCd]
783	je .traprec_ok_err_cd
784	push eax
785	movzx eax, word [ebx + BS2TRAPREC.u16ErrCd]
786	push eax
787	push .s_szWrongErrCd
788	call NAME(TestFailedF_p32)
789	add esp, 12
790
791	.traprec_ok_err_cd:
792	;
793	; Advance the EIP and resume execution.
794	;
795	movzx eax, byte [ebx + BS2TRAPREC.offResumeAddend]
796	add eax, [g_LastTrapRegs + BS2REGS.rip]
797	mov [ebp + 0ch], eax
798	jmp .resume
799
800
801	;
802	; Write panic message and then halt.
803	;
804	.panic:
805	push dword [g_LastTrapRegs + BS2REGS.rflags]
806	push dword [g_LastTrapRegs + BS2REGS.ss]
807	push dword [g_LastTrapRegs + BS2REGS.gs]
808	push dword [g_LastTrapRegs + BS2REGS.fs]
809	push dword [g_LastTrapRegs + BS2REGS.es]
810	push dword [g_LastTrapRegs + BS2REGS.ds]
811	push dword [g_LastTrapRegs + BS2REGS.cs]
812	; line break
813	push dword [g_LastTrapRegs + BS2REGS.cr4]
814	push dword [g_LastTrapRegs + BS2REGS.cr3]
815	push dword [g_LastTrapRegs + BS2REGS.cr0]
816	push dword [g_LastTrapRegs + BS2REGS.rbp]
817	push dword [g_LastTrapRegs + BS2REGS.rsp]
818	push dword [g_LastTrapRegs + BS2REGS.rip]
819	; line break
820	push dword [g_LastTrapRegs + BS2REGS.rdi]
821	push dword [g_LastTrapRegs + BS2REGS.rsi]
822	push dword [g_LastTrapRegs + BS2REGS.rdx]
823	push dword [g_LastTrapRegs + BS2REGS.rcx]
824	push dword [g_LastTrapRegs + BS2REGS.rbx]
825	push dword [g_LastTrapRegs + BS2REGS.rax]
826	; line break
827	mov eax, [ebp + 08h]
828	push eax
829	mov eax, cr2
830	push eax
831	mov eax, [ebp + 0ch]
832	push eax
833	movzx eax, word [ebp + 10h]
834	push eax
835	movzx eax, byte [ebp + 04h]
836	push eax
837	push .s_szPanicMsg
838	call NAME(TestFailedF_p32)
839
840	call Bs2Panic
841	jmp .panic ; paranoia
842
843	.s_szPanicMsg:
844	db 'trap #%RX8 at %RX16:%RX32 cr2=%RX32 err=%RX32', 13, 10
845	db 'eax=%RX32 ebx=%RX32 ecx=%RX32 edx=%RX32 esi=%RX32 edi=%RX32', 13, 10
846	db 'eip=%RX32 esp=%RX32 ebp=%RX32 cr0=%RX32 cr3=%RX32 cr4=%RX32', 13, 10
847	db 'cs=%RX16 ds=%RX16 es=%RX16 fs=%RX16 gs=%RX16 ss=%RX16 eflags=%RX32', 13, 10
848	db 0
849	.s_szWrongTrap:
850	db 'Expected trap %RX8 got %RX8', 13, 10, 0
851	.s_szWrongErrCd:
852	db 'Expected errcd %RX16 got %RX16', 13, 10, 0
853	ENDPROC bs2Trap_XX_32bit
854
855	;;
856	; Service IRQ handler, 32-bit version.
857	;
858	; Takes requests in eax and later maybe parameters in other registers.
859	;
860	; return GS ebp + 24h - v86
861	; return FS ebp + 20h - v86
862	; return DS ebp + 1ch - v86
863	; return ES ebp + 18h - v86
864	; return SS ebp + 14h - higher privilege
865	; return ESP ebp + 10h - higher privilege
866	; return EFLAGS ebp + 0ch
867	; return CS ebp + 08h
868	; return EIP ebp + 04h
869	BEGINCODELOW
870	BEGINPROC bs2TrapService32bit
871	jmp .highsegment
872	BEGINCODEHIGH
873	.highsegment:
874	push ebp ; ebp
875	mov ebp, esp
876	push eax ; ebp - 04h
877	push edx ; ebp - 08h
878	push ecx ; ebp - 0ch
879	push ebx ; ebp - 10h
880	push ds ; ebp - 14h
881
882	mov dx, ss
883	mov ds, dx
884
885	;
886	; Classify the caller context in cl.
887	;; @todo What if CS on the stack is conforming?
888	;
889	%define BS2_TRP_SRV_CALLER_SAME_RING 0
890	%define BS2_TRP_SRV_CALLER_OTHER_RING 1
891	%define BS2_TRP_SRV_CALLER_VM 2
892	test dword [ebp + 0ch], X86_EFL_VM
893	jnz .vm_ctx
894
895	mov cx, ss
896	mov ch, [ebp + 08h] ; cs
897	and cx, 00303h
898	cmp ch, cl
899	jz .same_ctx
900	mov cl, BS2_TRP_SRV_CALLER_OTHER_RING
901	jmp .done_ctx
902	.vm_ctx:
903	mov cl, BS2_TRP_SRV_CALLER_VM
904	jmp .done_ctx
905	.same_ctx:
906	mov cl, BS2_TRP_SRV_CALLER_SAME_RING
907	.done_ctx:
908
909	;
910	; Switch (eax).
911	;
912	cmp eax, BS2_SYSCALL_TO_RING3
913	jbe .to_ringX
914
915	; Unknown request.
916	.failure:
917	mov eax, -1
918	.return: ; careful with ebp here!
919	pop ds
920	pop ebx
921	pop ecx
922	pop edx
923	;pop eax
924	leave
925	iretd
926
927	;
928	; Switching to the ring specified by eax.
929	; Annoying that ss:esp isn't always restored.
930	;
931	.to_ringX:
932	cmp cl, BS2_TRP_SRV_CALLER_VM
933	je .failure
934	sub al, BS2_SYSCALL_TO_RING0
935
936	; Fake missing stack registers if necessary.
937	cmp cl, BS2_TRP_SRV_CALLER_SAME_RING
938	jnz .have_stack_regs
939
940	sub esp, 8h
941	sub ebp, 8h
942	xor ebx, ebx
943	.move_more:
944	mov edx, [esp + 8 + ebx]
945	mov [esp + ebx], edx
946	add ebx, 4
947	cmp ebx, 9*4
948	jb .move_more
949
950	mov dx, ss
951	mov [ebp + 14h], edx
952	lea edx, [ebp + 18h]
953	mov [ebp + 10h], edx
954
955	.have_stack_regs:
956	; Translate the selector registers
957	mov dx, [ebp - 14h]
958	call bs2SRegToRing
959	mov [ebp - 14h], dx
960
961	mov dx, es
962	call bs2SRegToRing
963	mov es, dx
964
965	mov dx, fs
966	call bs2SRegToRing
967	mov fs, dx
968
969	mov dx, gs
970	call bs2SRegToRing
971	mov gs, dx
972
973	mov dx, [ebp + 08h] ; cs
974	call bs2SRegToRing
975	mov [ebp + 08h], dx
976
977	mov dx, [ebp + 14h] ; ss
978	call bs2SRegToRing
979	mov [ebp + 14h], dx
980
981	or dword [ebp + 0ch], X86_EFL_IOPL ; set IOPL=3
982
983	; If the desired target is ring-0 we cannot use iret.
984	cmp al, 0
985	je .iret_to_ring_with_stack
986
987	.done_success:
988	xor eax, eax
989	jmp .return
990
991	.iret_to_ring_with_stack:
992	;
993	; Move the iret-to-same-ring to the desired return position. By also
994	; moving the saved ebp we make the leave instruction do stack
995	; adjusting/switching for us.
996	;
997	cli ; paranoia, it's disable already.
998	mov eax, [ebp + 10h]
999	lea edx, [ebp + 18h]
1000	cmp eax, edx
1001	lea ecx, [ebp + 08h] ; same stack, just shifted 8 bytes
1002	je .move_iret_and_ebp
1003	mov ecx, [ebp + 10h] ; different stack.
1004	sub ecx, 10h
1005	.move_iret_and_ebp:
1006	mov edx, [ebp + 0ch]
1007	mov eax, [ebp + 08h]
1008	mov [ecx + 0ch], edx
1009	mov [ecx + 08h], eax
1010	mov edx, [ebp + 04h]
1011	mov eax, [ebp + 00h]
1012	mov [ecx + 04h], edx
1013	mov [ecx + 00h], eax
1014	mov ebp, ecx
1015	xor eax, eax
1016	jmp .return
1017
1018	ENDPROC bs2TrapService32bit
1019
1020	%endif ; BS2_INC_CMN_PM
1021
1022
1023	%ifdef BS2_INC_CMN_LM
1024	;
1025	; 64-bit TSS (X86TSS64).
1026	;
1027	BEGINCODELOW
1028	ALIGNDATA(16)
1029	bs2Tss64Bit:
1030	dd 0 ; 00h - u32Reserved - Reserved.
1031	dq BS2_R0_STACK_ADDR ; 04h - rsp0 - Ring-0 stack pointer. (static)
1032	dq BS2_R1_STACK_ADDR ; 1ch - rsp1 - Ring-1 stack pointer. (static)
1033	dq BS2_R2_STACK_ADDR ; 14h - rsp2 - Ring-2 stack pointer. (static)
1034	dq 0 ; 2ch - reserved
1035	dq BS2_DF_R0_STACK_ADDR ; 24h - ist1;
1036	dq BS2_R0_STACK_ADDR ; 3ch - ist2;
1037	dq BS2_R0_STACK_ADDR ; 34h - ist3;
1038	dq BS2_R0_STACK_ADDR ; 4ch - ist4;
1039	dq BS2_R0_STACK_ADDR ; 44h - ist5;
1040	dq BS2_R0_STACK_ADDR ; 5ch - ist6;
1041	dq BS2_R0_STACK_ADDR ; 54h - ist7;
1042	dw 0,0,0,0,0 ; 6ch - reserved
1043	dw 0 ; 76h - offIoBitmap - Offset relative to the TSS of the
1044	; 00h - start of the I/O Bitmap and the end of the
1045	; 00h - interrupt redirection bitmap.
1046	bs2Tss64BitEnd:
1047	times (68h - (bs2Tss64BitEnd - bs2Tss64Bit)) db 0
1048	times ((bs2Tss64BitEnd - bs2Tss64Bit) - 68h) db 0
1049
1050	;
1051	; 64-bit IDT (X86DESC64GATE).
1052	;
1053	BEGINCODELOW
1054	ALIGNDATA(16)
1055	bs2Idt64bit:
1056	dw bs2Trap_00h_64bit, BS2_SEL_CS64, 08e00h, 00000h, 0, 0, 0, 0 ; p=1 dpl=0 type=int64gate
1057	dw bs2Trap_01h_64bit, BS2_SEL_CS64, 08e00h, 00000h, 0, 0, 0, 0 ; p=1 dpl=0 type=int64gate
1058	dw bs2Trap_02h_64bit, BS2_SEL_CS64, 08e00h, 00000h, 0, 0, 0, 0 ; p=1 dpl=0 type=int64gate
1059	bs2Idt64bit_BP:
1060	dw bs2Trap_03h_64bit, BS2_SEL_CS64, 08e00h, 00000h, 0, 0, 0, 0 ; p=1 dpl=0 type=int64gate
1061	dw bs2Trap_04h_64bit, BS2_SEL_CS64, 08e00h, 00000h, 0, 0, 0, 0 ; p=1 dpl=0 type=int64gate
1062	dw bs2Trap_05h_64bit, BS2_SEL_CS64, 08e00h, 00000h, 0, 0, 0, 0 ; p=1 dpl=0 type=int64gate
1063	dw bs2Trap_06h_64bit, BS2_SEL_CS64, 08e00h, 00000h, 0, 0, 0, 0 ; p=1 dpl=0 type=int64gate
1064	dw bs2Trap_07h_64bit, BS2_SEL_CS64, 08e00h, 00000h, 0, 0, 0, 0 ; p=1 dpl=0 type=int64gate
1065	dw bs2Trap_08h_64bit, BS2_SEL_CS64, 08e00h, 00000h, 0, 0, 0, 0 ; p=1 dpl=0 type=int64gate
1066	dw bs2Trap_09h_64bit, BS2_SEL_CS64, 08e00h, 00000h, 0, 0, 0, 0 ; p=1 dpl=0 type=int64gate
1067	dw bs2Trap_0ah_64bit, BS2_SEL_CS64, 08e00h, 00000h, 0, 0, 0, 0 ; p=1 dpl=0 type=int64gate
1068	dw bs2Trap_0bh_64bit, BS2_SEL_CS64, 08e00h, 00000h, 0, 0, 0, 0 ; p=1 dpl=0 type=int64gate
1069	dw bs2Trap_0ch_64bit, BS2_SEL_CS64, 08e00h, 00000h, 0, 0, 0, 0 ; p=1 dpl=0 type=int64gate
1070	dw bs2Trap_0dh_64bit, BS2_SEL_CS64, 08e00h, 00000h, 0, 0, 0, 0 ; p=1 dpl=0 type=int64gate
1071	dw bs2Trap_0eh_64bit, BS2_SEL_CS64, 08e00h, 00000h, 0, 0, 0, 0 ; p=1 dpl=0 type=int64gate
1072	dw bs2Trap_0fh_64bit, BS2_SEL_CS64, 08e00h, 00000h, 0, 0, 0, 0 ; p=1 dpl=0 type=int64gate
1073	dw bs2Trap_10h_64bit, BS2_SEL_CS64, 08e00h, 00000h, 0, 0, 0, 0 ; p=1 dpl=0 type=int64gate
1074	dw bs2Trap_11h_64bit, BS2_SEL_CS64, 08e00h, 00000h, 0, 0, 0, 0 ; p=1 dpl=0 type=int64gate
1075	dw bs2Trap_12h_64bit, BS2_SEL_CS64, 08e00h, 00000h, 0, 0, 0, 0 ; p=1 dpl=0 type=int64gate
1076	dw bs2Trap_13h_64bit, BS2_SEL_CS64, 08e00h, 00000h, 0, 0, 0, 0 ; p=1 dpl=0 type=int64gate
1077	dw bs2Trap_14h_64bit, BS2_SEL_CS64, 08e00h, 00000h, 0, 0, 0, 0 ; p=1 dpl=0 type=int64gate
1078	dw bs2Trap_15h_64bit, BS2_SEL_CS64, 08e00h, 00000h, 0, 0, 0, 0 ; p=1 dpl=0 type=int64gate
1079	dw bs2Trap_16h_64bit, BS2_SEL_CS64, 08e00h, 00000h, 0, 0, 0, 0 ; p=1 dpl=0 type=int64gate
1080	dw bs2Trap_17h_64bit, BS2_SEL_CS64, 08e00h, 00000h, 0, 0, 0, 0 ; p=1 dpl=0 type=int64gate
1081	dw bs2Trap_18h_64bit, BS2_SEL_CS64, 08e00h, 00000h, 0, 0, 0, 0 ; p=1 dpl=0 type=int64gate
1082	dw bs2Trap_19h_64bit, BS2_SEL_CS64, 08e00h, 00000h, 0, 0, 0, 0 ; p=1 dpl=0 type=int64gate
1083	dw bs2Trap_1ah_64bit, BS2_SEL_CS64, 08e00h, 00000h, 0, 0, 0, 0 ; p=1 dpl=0 type=int64gate
1084	dw bs2Trap_1bh_64bit, BS2_SEL_CS64, 08e00h, 00000h, 0, 0, 0, 0 ; p=1 dpl=0 type=int64gate
1085	dw bs2Trap_1ch_64bit, BS2_SEL_CS64, 08e00h, 00000h, 0, 0, 0, 0 ; p=1 dpl=0 type=int64gate
1086	dw bs2Trap_1dh_64bit, BS2_SEL_CS64, 08e00h, 00000h, 0, 0, 0, 0 ; p=1 dpl=0 type=int64gate
1087	dw bs2Trap_1eh_64bit, BS2_SEL_CS64, 08e00h, 00000h, 0, 0, 0, 0 ; p=1 dpl=0 type=int64gate
1088	dw bs2Trap_1fh_64bit, BS2_SEL_CS64, 08e00h, 00000h, 0, 0, 0, 0 ; p=1 dpl=0 type=int64gate
1089	dw bs2TrapService64bit,BS2_SEL_CS64,0ee00h, 00000h, 0, 0, 0, 0 ; p=1 dpl=3 type=int64gate
1090	bs2Idt64bitEnd
1091
1092
1093	;
1094	; 64-bit trap handlers.
1095	;
1096	BITS 64
1097	%macro bs2Trap_XX_64bit_macro 1
1098	BEGINCODELOW
1099	bs2Trap_ %+ %1 %+ _64bit:
1100	push %1
1101	jmp bs2Trap_XX_64bit
1102	%endmacro
1103	%macro bs2Trap_XX_64bit_macro_no_err 1
1104	bs2Trap_ %+ %1 %+ _64bit:
1105	push 0
1106	push %1
1107	jmp bs2Trap_XX_64bit
1108	%endmacro
1109	bs2Trap_XX_64bit_macro_no_err 00h
1110	bs2Trap_XX_64bit_macro_no_err 01h
1111	bs2Trap_XX_64bit_macro_no_err 02h
1112	bs2Trap_XX_64bit_macro_no_err 03h
1113	bs2Trap_XX_64bit_macro_no_err 04h
1114	bs2Trap_XX_64bit_macro_no_err 05h
1115	bs2Trap_XX_64bit_macro_no_err 06h
1116	bs2Trap_XX_64bit_macro_no_err 07h
1117	bs2Trap_XX_64bit_macro 08h
1118	bs2Trap_XX_64bit_macro_no_err 09h
1119	bs2Trap_XX_64bit_macro 0ah
1120	bs2Trap_XX_64bit_macro 0bh
1121	bs2Trap_XX_64bit_macro 0ch
1122	bs2Trap_XX_64bit_macro 0dh
1123	bs2Trap_XX_64bit_macro 0eh
1124	bs2Trap_XX_64bit_macro_no_err 0fh
1125	bs2Trap_XX_64bit_macro_no_err 10h
1126	bs2Trap_XX_64bit_macro 11h
1127	bs2Trap_XX_64bit_macro_no_err 12h
1128	bs2Trap_XX_64bit_macro_no_err 13h
1129	bs2Trap_XX_64bit_macro_no_err 14h
1130	bs2Trap_XX_64bit_macro_no_err 15h
1131	bs2Trap_XX_64bit_macro_no_err 16h
1132	bs2Trap_XX_64bit_macro_no_err 17h
1133	bs2Trap_XX_64bit_macro_no_err 18h
1134	bs2Trap_XX_64bit_macro_no_err 19h
1135	bs2Trap_XX_64bit_macro_no_err 1ah
1136	bs2Trap_XX_64bit_macro_no_err 1bh
1137	bs2Trap_XX_64bit_macro_no_err 1ch
1138	bs2Trap_XX_64bit_macro_no_err 1dh
1139	bs2Trap_XX_64bit_macro_no_err 1eh
1140	bs2Trap_XX_64bit_macro_no_err 1fh
1141
1142	;;
1143	; Common 64-bit trap handler.
1144	;
1145	; return SS rbp + 38h
1146	; return RSP rbp + 30h
1147	; return RFLAGS rbp + 28h
1148	; return CS rbp + 20h
1149	; return RIP rbp + 18h
1150	; error code rbp + 10h
1151	; vector # rbp + 08h
1152	BEGINCODEHIGH
1153	BEGINPROC bs2Trap_XX_64bit
1154	push rbp ; rbp + 00h
1155	mov rbp, rsp
1156	pushfq ; rbp - 08h
1157	push rax ; rbp - 10h
1158	push rbx ; rbp - 18h
1159
1160	;
1161	; Benchmark mode? Then resume the action right away!
1162	;
1163	mov rax, [rbp + 08h]
1164	cmp [g_u8TrapBenchmarkNo], al
1165	jne .test_mode
1166	cmp byte [g_fTrapPrepared], 0
1167	je .test_mode
1168	mov rax, [g_TrapResumeRIP]
1169	mov [rbp + 18h], rax
1170
1171	pop rbx
1172	;pop rax
1173	;popfq
1174	leave
1175	add rsp, 10h ; Skip the vector # and error code.
1176	xor rax, rax
1177	iretq
1178
1179	;
1180	; Save the trap information
1181	;
1182	.test_mode:
1183	inc dword [g_u32cTraps]
1184	mov rax, [rbp + 08h]
1185	mov [g_u8LastTrapNo], al
1186	mov rax, [rbp + 10h]
1187	mov [g_u64LastTrapErr], rax
1188	mov rax, [rbp - 08h]
1189	mov [g_u64LastTrapHandlerRFlags], rax
1190	mov ax, cs
1191	mov [g_u16LastTrapHandlerCS], ax
1192	mov ax, ss
1193	mov [g_u16LastTrapHandlerSS], ax
1194	lea rax, [rbp + 8]
1195	mov [g_u64LastTrapHandlerRSP], rax
1196
1197	; Save the registers.
1198	lea rbx, [g_LastTrapRegs]
1199	mov rax, [rbp - 10h]
1200	mov [rbx + BS2REGS.rax], rax
1201	mov rax, [rbp - 18h]
1202	mov [rbx + BS2REGS.rbx], rax
1203	mov [rbx + BS2REGS.rcx], rcx
1204	mov [rbx + BS2REGS.rdx], rdx
1205	mov [rbx + BS2REGS.rdi], rdi
1206	mov [rbx + BS2REGS.rsi], rsi
1207	mov rax, [rbp]
1208	mov [rbx + BS2REGS.rbp], rax
1209	mov rax, [rbp + 30h]
1210	mov [rbx + BS2REGS.rsp], rax
1211	mov rax, [rbp + 18h]
1212	mov [rbx + BS2REGS.rip], rax
1213	mov [rbx + BS2REGS.r8], r8
1214	mov [rbx + BS2REGS.r9], r9
1215	mov [rbx + BS2REGS.r10], r10
1216	mov [rbx + BS2REGS.r11], r11
1217	mov [rbx + BS2REGS.r12], r12
1218	mov [rbx + BS2REGS.r13], r13
1219	mov [rbx + BS2REGS.r14], r14
1220	mov [rbx + BS2REGS.r15], r15
1221	mov rax, [rbp + 28h]
1222	mov [rbx + BS2REGS.rflags], rax
1223	mov rax, [rbp + 20h]
1224	mov [rbx + BS2REGS.cs], ax
1225	mov [rbx + BS2REGS.ds], ds
1226	mov [rbx + BS2REGS.es], es
1227	mov [rbx + BS2REGS.fs], fs
1228	mov [rbx + BS2REGS.gs], gs
1229	mov rax, [rbp + 38h]
1230	mov [rbx + BS2REGS.ss], ax
1231	mov [rbx + BS2REGS.cBits], byte 64
1232
1233	; The CRx registers are only accessible from ring-0 (CS=conforming, CPL < 0)
1234	test byte [rbx + BS2REGS.ss], 3
1235	jnz .skip_crX
1236	mov rax, cr0
1237	mov [rbx + BS2REGS.cr0], rax
1238	mov rax, cr2
1239	mov [rbx + BS2REGS.cr2], rax
1240	mov rax, cr3
1241	mov [rbx + BS2REGS.cr3], rax
1242	mov rax, cr4
1243	mov [rbx + BS2REGS.cr4], rax
1244	mov rax, cr8
1245	mov [rbx + BS2REGS.cr8], rax
1246	.skip_crX:
1247
1248	;
1249	; Advance to a prepared resume position or panic.
1250	;
1251	cmp byte [g_fTrapPrepared], 0
1252	je .no_resume_pos
1253	mov byte [g_fTrapPrepared], 0
1254	mov rax, [g_TrapResumeRIP]
1255	mov [rbp + 18h], rax
1256	jmp .resume
1257
1258	.resume:
1259	%ifdef BS2_WITH_XCPT_DB_CLEARING_TF
1260	cmp byte [rbp + 08h], X86_XCPT_DB ; make sure we won't trap again due to a TF.
1261	jne .resume_no_clear_trap_flags
1262	and word [rbp + 28h], ~X86_EFL_TF
1263	.resume_no_clear_trap_flags:
1264	%endif
1265	pop rbx
1266	pop rax
1267	;popfq
1268	leave
1269	add rsp, 10h
1270	iretq
1271
1272
1273	.no_resume_pos:
1274	;
1275	; Look for a trap record.
1276	;
1277	push rcx
1278
1279	mov ecx, [g_cTrapRecs] ; the number of records.
1280	test ecx, ecx
1281	jz .panic
1282	mov rax, [g_LastTrapRegs + BS2REGS.rip]
1283	sub rax, [g_pTrapRecBase] ; the offWhere we're looking for.
1284	jb .panic
1285	mov rbx, _4G
1286	cmp rax, rbx
1287	jae .panic ; out of range.
1288
1289	; Look starting at the previous record first.
1290	mov ebx, [g_iTrapRecLast]
1291	sub ecx, ebx
1292	jbe .traprec_loop2 ; g_iTrapRecLast is out of range.
1293	shl rbx, BS2TRAPREC_SIZE_SHIFT
1294	add rbx, [g_paTrapRecs] ; ebx points to the record we hit last time.
1295	.traprec_loop1_next:
1296	cmp [rbx + BS2TRAPREC.offWhere], eax
1297	je .traprec_found
1298	add rbx, BS2TRAPREC_size
1299	dec ecx
1300	jnz .traprec_loop1_next
1301
1302	; Start searching from the start, stopping at the previous record.
1303	.traprec_loop2:
1304	mov ecx, [g_iTrapRecLast]
1305	or ecx, ecx
1306	jz .panic ; not found.
1307	mov rbx, [g_paTrapRecs]
1308	.traprec_loop2_next:
1309	cmp [rbx + BS2TRAPREC.offWhere], eax
1310	je .traprec_found
1311	add rbx, BS2TRAPREC_size
1312	dec ecx
1313	jnz .traprec_loop2_next
1314	jmp .panic ; not found
1315
1316	.traprec_found:
1317	; Remember the hit for the next trap.
1318	mov rax, rbx
1319	sub rax, [g_paTrapRecs]
1320	shr rax, BS2TRAPREC_SIZE_SHIFT
1321	mov [g_iTrapRecLast], eax
1322
1323	;
1324	; Fail the test if we got the wrong trap or error code.
1325	;
1326	mov al, [g_u8LastTrapNo wrt rip]
1327	cmp al, [rbx + BS2TRAPREC.u8TrapNo]
1328	je .traprec_ok_trap
1329	push rax
1330	movzx rax, byte [rbx + BS2TRAPREC.u8TrapNo]
1331	push rax
1332	push .s_szWrongTrap
1333	call NAME(TestFailedF_p64)
1334	add rsp, 24
1335
1336	.traprec_ok_trap:
1337	mov ax, [g_u64LastTrapErr wrt rip]
1338	cmp ax, [rbx + BS2TRAPREC.u16ErrCd]
1339	je .traprec_ok_err_cd
1340	push rax
1341	movzx rax, word [rbx + BS2TRAPREC.u16ErrCd]
1342	push rax
1343	push .s_szWrongErrCd
1344	call NAME(TestFailedF_p64)
1345	add rsp, 24
1346
1347	.traprec_ok_err_cd:
1348	;
1349	; Advance the EIP and resume execution.
1350	;
1351	movzx rax, byte [rbx + BS2TRAPREC.offResumeAddend]
1352	add rax, [g_LastTrapRegs + BS2REGS.rip]
1353	mov [rbp + 18h], rax
1354
1355	pop rcx
1356	jmp .resume
1357
1358
1359	;
1360	; Format a panic message and halt.
1361	;
1362	.panic:
1363	lea rbx, [g_LastTrapRegs]
1364	; line break
1365	movzx eax, word [rbx + BS2REGS.ss]
1366	push rax
1367	movzx eax, word [rbx + BS2REGS.gs]
1368	push rax
1369	movzx eax, word [rbx + BS2REGS.fs]
1370	push rax
1371	movzx eax, word [rbx + BS2REGS.es]
1372	push rax
1373	movzx eax, word [rbx + BS2REGS.ds]
1374	push rax
1375	movzx eax, word [rbx + BS2REGS.cs]
1376	push rax
1377	; line break
1378	push qword [rbx + BS2REGS.rbp]
1379	push qword [rbx + BS2REGS.rsp]
1380	push qword [rbx + BS2REGS.rip]
1381	; line break
1382	push qword [rbx + BS2REGS.rflags]
1383	push qword [rbx + BS2REGS.r15]
1384	push qword [rbx + BS2REGS.r14]
1385	; line break
1386	push qword [rbx + BS2REGS.r13]
1387	push qword [rbx + BS2REGS.r12]
1388	push qword [rbx + BS2REGS.r11]
1389	; line break
1390	push qword [rbx + BS2REGS.r10]
1391	push qword [rbx + BS2REGS.r9]
1392	push qword [rbx + BS2REGS.r8]
1393	; line break
1394	push qword [rbx + BS2REGS.rdi]
1395	push qword [rbx + BS2REGS.rsi]
1396	push qword [rbx + BS2REGS.rdx]
1397	; line break
1398	push qword [rbx + BS2REGS.rcx]
1399	push qword [rbx + BS2REGS.rbx]
1400	push qword [rbx + BS2REGS.rax]
1401	; line break
1402	mov eax, [rbx + BS2REGS.cr8]
1403	push rax
1404	mov eax, [rbx + BS2REGS.cr4]
1405	push rax
1406	mov eax, [rbx + BS2REGS.cr3]
1407	push rax
1408	mov eax, [rbx + BS2REGS.cr0]
1409	push rax
1410	; line break
1411	push qword [rbp + 10h]
1412	push qword [rbx + BS2REGS.cr2]
1413	push qword [rbx + BS2REGS.rip]
1414	movzx eax, word [rbp + BS2REGS.ss]
1415	push rax
1416	movzx eax, byte [rbp + 08h]
1417	push rax
1418	push .s_szPanicMsg
1419	call NAME(TestFailedF_p64)
1420
1421	call Bs2Panic
1422	jmp .panic ; paranoia
1423
1424	.s_szPanicMsg:
1425	db 'trap #%RX8 at %RX16:%RX64 cr2=%RX64 err=%RX64', 13, 10
1426	db 'cr0=%RX64 cr3=%RX64 cr4=%RX64 cr8=%RX16', 13, 10
1427	db 'rax=%RX64 rbx=%RX64 rcx=%RX64', 13, 10
1428	db 'rdx=%RX64 rsi=%RX64 rdi=%RX64', 13, 10
1429	db 'r8 =%RX64 r9 =%RX64 r10=%RX64', 13, 10
1430	db 'r11=%RX64 r12=%RX64 r13=%RX64', 13, 10
1431	db 'r14=%RX64 r15=%RX64 rfl=%RX64', 13, 10
1432	db 'rip=%RX64 rsp=%RX64 rbp=%RX64 ', 13, 10
1433	db 'cs=%RX16 ds=%RX16 es=%RX16 fs=%RX16 gs=%RX16 ss=%RX16', 13, 10
1434	db 0
1435	.s_szWrongTrap:
1436	db 'Expected trap %RX8 got %RX8', 13, 10, 0
1437	.s_szWrongErrCd:
1438	db 'Expected errcd %RX16 got %RX16', 13, 10, 0
1439	ENDPROC bs2Trap_XX_64bit
1440
1441
1442	;;
1443	; Service IRQ handler.
1444	;
1445	; Takes requests in eax and later maybe parameters in other registers.
1446	;
1447	; return SS rbp + 28h
1448	; return RSP rbp + 20h
1449	; return RFLAGS rbp + 18h
1450	; return CS rbp + 10h
1451	; return RIP rbp + 08h
1452	BEGINCODELOW
1453	BEGINPROC bs2TrapService64bit
1454	jmp .highsegment
1455	BEGINCODEHIGH
1456	.highsegment:
1457	push rbp
1458	mov rbp, rsp
1459	push rax
1460	push rdx
1461	push rcx
1462
1463
1464	;
1465	; Switch (eax).
1466	;
1467	cmp eax, BS2_SYSCALL_TO_RING3
1468	jbe .to_ringX
1469
1470	; Unknown request.
1471	mov rax, -1
1472	.return:
1473	pop rcx
1474	pop rdx
1475	;pop rax
1476	leave
1477	iretq
1478
1479	;
1480	; Switching to the ring specified by eax.
1481	;
1482	.to_ringX:
1483	sub eax, BS2_SYSCALL_TO_RING0 ; al = new ring number.
1484
1485	mov dx, ds
1486	call bs2SRegToRing
1487	mov ds, dx
1488
1489	mov dx, es
1490	call bs2SRegToRing
1491	mov es, dx
1492
1493	mov dx, fs
1494	call bs2SRegToRing
1495	mov fs, dx
1496
1497	mov dx, gs
1498	call bs2SRegToRing
1499	mov gs, dx
1500
1501	mov dx, [rbp + 10h] ; cs
1502	call bs2SRegToRing
1503	mov [rbp + 10h], dx
1504
1505	mov dx, [rbp + 28h] ; ss
1506	call bs2SRegToRing
1507	mov [rbp + 28h], dx
1508
1509	or dword [ebp + 18h], X86_EFL_IOPL ; set IOPL=3
1510
1511	jmp .done_success
1512
1513	.done_success:
1514	xor eax, eax
1515	jmp .return
1516
1517	ENDPROC bs2TrapService64bit
1518
1519	%endif ; BS2_INC_CMN_LM
1520
1521
1522	;;
1523	; Converts a segment value (dx) to the ring specified by al.
1524	;
1525	; If the selector isn't a known CS, DS or SS selector it will be set to null.
1526	;
1527	; @returns dx
1528	; @param al The desired ring.
1529	; @param dx The segment to convert.
1530	;
1531	; @remarks WARNING! This has to work exactly the same both in 32-bit and 64-bit mode.
1532	;
1533	BEGINCODEHIGH
1534	BITS 32
1535	BEGINPROC bs2SRegToRing
1536	;
1537	; Classify the incoming selector.
1538	;
1539	cmp dx, BS2_SEL_R0_BASE
1540	jb .null
1541	cmp dx, BS2_SEL_R0_BASE + BS2_SEL_GRP_SIZE
1542	jb .ring0
1543
1544	cmp dx, BS2_SEL_R1_BASE
1545	jb .miss
1546	cmp dx, BS2_SEL_R1_BASE + BS2_SEL_GRP_SIZE
1547	jb .ring1
1548
1549	cmp dx, BS2_SEL_R2_BASE
1550	jb .miss
1551	cmp dx, BS2_SEL_R2_BASE + BS2_SEL_GRP_SIZE
1552	jb .ring2
1553
1554	cmp dx, BS2_SEL_R3_BASE
1555	jb .miss
1556	cmp dx, BS2_SEL_R3_BASE + BS2_SEL_GRP_SIZE
1557	jb .ring3
1558	jmp .miss
1559
1560	;
1561	; Convert the incoming selector to ring-0 and then from ring-0 to the
1562	; desired one.
1563	;
1564	.ring0:
1565	cmp al, 0
1566	je .done
1567
1568	add dx, BS2_SEL_R1_BASE - BS2_SEL_R0_BASE
1569	cmp al, 1
1570	je .done
1571
1572	add dx, BS2_SEL_R2_BASE - BS2_SEL_R1_BASE
1573	cmp al, 2
1574	je .done
1575
1576	add dx, BS2_SEL_R3_BASE - BS2_SEL_R2_BASE
1577	cmp al, 3
1578	je .done
1579	.panic:
1580	hlt
1581	jmp .panic
1582
1583	.ring1:
1584	sub dx, BS2_SEL_R1_BASE - BS2_SEL_R0_BASE
1585	jmp .ring0
1586	.ring2:
1587	sub dx, BS2_SEL_R2_BASE - BS2_SEL_R0_BASE
1588	jmp .ring0
1589	.ring3:
1590	sub dx, BS2_SEL_R3_BASE - BS2_SEL_R0_BASE
1591	jmp .ring0
1592
1593	.done:
1594	and dl, ~3h
1595	or dl, al ; set the RPL
1596	ret
1597
1598	.miss:
1599	.null:
1600	xor dx, dx
1601	ret
1602	ENDPROC bs2SRegToRing
1603
1604	BEGINCODELOW
1605

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

Original Format