Changeset 20997 in vbox for trunk/src/VBox

Timestamp:

Jun 26, 2009 10:23:04 PM (16 years ago)

Author:

vboxsync

Message:

HWACCM,CPUM: Fix for 64-bit Windows trashing guest XMM registers - VMX part.

Location:

trunk/src/VBox/VMM

Files:

• HWACCMInternal.h (modified) (3 diffs)
• Makefile.kmk (modified) (1 diff)
• VMMR0/CPUMR0.cpp (modified) (3 diffs)
• VMMR0/CPUMR0A.asm (modified) (2 diffs)
• VMMR0/HWACCMR0A.asm (modified) (3 diffs)
• VMMR0/HWVMXR0.cpp (modified) (1 diff)

trunk/src/VBox/VMM/HWACCMInternal.h

@@ -441 +441 @@
 typedef VMCSCACHE *PVMCSCACHE;
 
+/** VMX StartVM function. */
+typedef DECLCALLBACK(int) FNHWACCMVMXSTARTVM(RTHCUINT fResume, PCPUMCTX pCtx, PVMCSCACHE pCache, PVM pVM, PVMCPU pVCpu);
+/** Pointer to an VMX StartVM function. */
+typedef R0PTRTYPE(FNHWACCMVMXSTARTVM *) PFNHWACCMVMXSTARTVM;
+
 /**
  * HWACCM VMCPU Instance data.
@@ -480 +485 @@
 
         /** Ring 0 handlers for VT-x. */
-        DECLR0CALLBACKMEMBER(int,  pfnStartVM,(RTHCUINT fResume, PCPUMCTX pCtx, PVMCSCACHE pCache, PVM pVM, PVMCPU pVCpu));
+        PFNHWACCMVMXSTARTVM         pfnStartVM;
 
         /** Current VMX_VMCS_CTRL_PROC_EXEC_CONTROLS. */
@@ -719 +724 @@
 VMMR0DECL(int) HWACCMR0DummyLoadGuestState(PVM pVM, PVMCPU pVCpu, PCPUMCTX pCtx);
 
+# ifdef VBOX_WITH_KERNEL_USING_XMM
+DECLASM(int) hwaccmR0VMXStartVMWrapperXMM(RTHCUINT fResume, PCPUMCTX pCtx, PVMCSCACHE pCache, PVM pVM, PVMCPU pVCpu, PFNHWACCMVMXSTARTVM pfnStartVM);
+# endif
 
 # ifdef VBOX_WITH_HYBRID_32BIT_KERNEL

trunk/src/VBox/VMM/Makefile.kmk

@@ -415 +415 @@
         VBOX_WITH_2X_4GB_ADDR_SPACE   VBOX_WITH_2X_4GB_ADDR_SPACE_IN_R0 \
         VBOX_WITH_HYBRID_32BIT_KERNEL VBOX_WITH_HYBRID_32BIT_KERNEL_IN_R0
+VMMR0_DEFS.win.amd64  = VBOX_WITH_KERNEL_USING_XMM
 
 ifeq ($(VBOX_LDR_FMT),pe)

trunk/src/VBox/VMM/VMMR0/CPUMR0.cpp

@@ -183 +183 @@
     {
 #ifndef CPUM_CAN_HANDLE_NM_TRAPS_IN_KERNEL_MODE
-# ifdef VBOX_WITH_HYBRID_32BIT_KERNEL /** @todo remove the #else here and move cpumHandleLazyFPUAsm back to VMMGC after branching out 2.1. */
+# if defined(VBOX_WITH_HYBRID_32BIT_KERNEL) || defined(VBOX_WITH_KERNEL_USING_XMM) /** @todo remove the #else here and move cpumHandleLazyFPUAsm back to VMMGC after branching out 3.0!!. */
+        /** @todo Move the FFXR handling down into
+         *        cpumR0SaveHostRestoreguestFPUState to optimize the
+         *        VBOX_WITH_KERNEL_USING_XMM handling. */
         /* Clear MSR_K6_EFER_FFXSR or else we'll be unable to save/restore the XMM state with fxsave/fxrstor. */
         uint64_t SavedEFER = 0;
@@ -300 +303 @@
     {
 #ifndef CPUM_CAN_HANDLE_NM_TRAPS_IN_KERNEL_MODE
+# ifdef VBOX_WITH_KERNEL_USING_XMM
+        /*
+         * We've already saved the XMM registers in the assembly wrapper, so
+         * we have to save them before saving the entire FPU state and put them
+         * back afterwards.
+         */
+        /** @todo This could be skipped if MSR_K6_EFER_FFXSR is set, but
+         *        I'm not able to test such an optimization tonight.
+         *        We could just all this in assembly. */
+        uint128_t aGuestXmmRegs[16];
+        memcpy(&aGuestXmmRegs[0], &pVCpu->cpum.s.Guest.fpu.aXMM[0], sizeof(aGuestXmmRegs));
+# endif
+
+        /* Clear MSR_K6_EFER_FFXSR or else we'll be unable to save/restore the XMM state with fxsave/fxrstor. */
         uint64_t oldMsrEFERHost = 0;
-
-        /* Clear MSR_K6_EFER_FFXSR or else we'll be unable to save/restore the XMM state with fxsave/fxrstor. */
         if (pVCpu->cpum.s.fUseFlags & CPUM_MANUAL_XMM_RESTORE)
         {
@@ -314 +329 @@
             ASMWrMsr(MSR_K6_EFER, oldMsrEFERHost | MSR_K6_EFER_FFXSR);
 
+# ifdef VBOX_WITH_KERNEL_USING_XMM
+        memcpy(&pVCpu->cpum.s.Guest.fpu.aXMM[0], &aGuestXmmRegs[0], sizeof(aGuestXmmRegs));
+# endif
+
 #else  /* CPUM_CAN_HANDLE_NM_TRAPS_IN_KERNEL_MODE */
+# ifdef VBOX_WITH_KERNEL_USING_XMM
+#  error "Fix all the NM_TRAPS_IN_KERNEL_MODE code path. I'm not going to fix unused code now."
+# endif
         cpumR0SaveFPU(pCtx);
         if (pVCpu->cpum.s.fUseFlags & CPUM_MANUAL_XMM_RESTORE)

trunk/src/VBox/VMM/VMMR0/CPUMR0A.asm

@@ -34 +34 @@
  %error "The jump table doesn't link on leopard."
 %endif
+
+;*******************************************************************************
+;*      Defined Constants And Macros                                           *
+;*******************************************************************************
+;; The offset of the XMM registers in X86FXSTATE.
+; Use define because I'm too lazy to convert the struct.
+%define XMM_OFF_IN_X86FXSTATE   160
 
 
@@ -103 +110 @@
     fxsave  [xDX + CPUMCPU.Host.fpu]    ; ASSUMES that all VT-x/AMD-V boxes sports fxsave/fxrstor (safe assumption)
     fxrstor [xDX + CPUMCPU.Guest.fpu]
+
+%ifdef VBOX_WITH_KERNEL_USING_XMM
+    ; Restore the non-volatile xmm registers. ASSUMING 64-bit windows
+    lea     r11, [xDX + CPUMCPU.Host.fpu + XMM_OFF_IN_X86FXSTATE]
+    movdqa  xmm6,  [r11 + 060h]
+    movdqa  xmm7,  [r11 + 070h]
+    movdqa  xmm8,  [r11 + 080h]
+    movdqa  xmm9,  [r11 + 090h]
+    movdqa  xmm10, [r11 + 0a0h]
+    movdqa  xmm11, [r11 + 0b0h]
+    movdqa  xmm12, [r11 + 0c0h]
+    movdqa  xmm13, [r11 + 0d0h]
+    movdqa  xmm14, [r11 + 0e0h]
+    movdqa  xmm15, [r11 + 0f0h]
+%endif
 
 .done:

trunk/src/VBox/VMM/VMMR0/HWACCMR0A.asm

@@ -64 +64 @@
  %endif
 %endif
+
+;; The offset of the XMM registers in X86FXSTATE.
+; Use define because I'm too lazy to convert the struct.
+%define XMM_OFF_IN_X86FXSTATE   160
 
 
@@ -249 +253 @@
 extern NAME(SUPR0Abs64bitKernelDS)
 extern NAME(SUPR0AbsKernelCS)
+%endif
+%ifdef VBOX_WITH_KERNEL_USING_XMM
+extern NAME(CPUMIsGuestFPUStateActive)
 %endif
 
@@ -1020 +1027 @@
 
 
+%ifdef VBOX_WITH_KERNEL_USING_XMM
+;;
+; Wrapper around vmx.pfnStartVM that preserves host XMM registers and
+; load the guest ones when necessary.
+;
+; @cproto       DECLASM(int) hwaccmR0VMXStartVMWrapperXMM(RTHCUINT fResume, PCPUMCTX pCtx, PVMCSCACHE pCache, PVM pVM, PVMCPU pVCpu, PFNHWACCMVMXSTARTVM pfnStartVM);
+;
+; @returns      eax
+;
+; @param        fResumeVM       msc:rcx
+; @param        pCtx            msc:rdx
+; @param        pVMCSCache      msc:r8
+; @param        pVM             msc:r9
+; @param        pVCpu           msc:[rbp+30h]
+; @param        pfnStartVM      msc:[rbp+38h]
+;
+; ASSUMING 64-bit and windows for now.
+ALIGNCODE(16)
+BEGINPROC hwaccmR0VMXStartVMWrapperXMM
+        push    xBP
+        mov     xBP, xSP
+        sub     xSP, 0a0h + 040h        ; Don't bother optimizing the frame size.
+
+        ; spill input parameters.
+        mov     [xBP + 010h], rcx       ; fResumeVM
+        mov     [xBP + 018h], rdx       ; pCtx
+        mov     [xBP + 020h], r8        ; pVMCSCache
+        mov     [xBP + 028h], r9        ; pVM
+
+        ; Ask CPUM whether we've started using the FPU yet.
+        mov     rcx, [xBP + 30h]        ; pVCpu
+        call    NAME(CPUMIsGuestFPUStateActive)
+        test    al, al
+        jnz     .guest_fpu_state_active
+
+        ; No need to mess with XMM registers just call the start routine and return.
+        mov     r11, [xBP + 38h]        ; pfnStartVM
+        mov     r10, [xBP + 30h]        ; pVCpu
+        mov     [xSP + 020h], r10
+        mov     rcx, [xBP + 010h]       ; fResumeVM
+        mov     rdx, [xBP + 018h]       ; pCtx
+        mov     r8,  [xBP + 020h]       ; pVMCSCache
+        mov     r9,  [xBP + 028h]       ; pVM
+        call    r11
+
+        leave
+        ret
+
+ALIGNCODE(8)
+.guest_fpu_state_active:
+        ; Save the host XMM registers.
+        movdqa  [rsp + 040h + 000h], xmm6
+        movdqa  [rsp + 040h + 010h], xmm7
+        movdqa  [rsp + 040h + 020h], xmm8
+        movdqa  [rsp + 040h + 030h], xmm9
+        movdqa  [rsp + 040h + 040h], xmm10
+        movdqa  [rsp + 040h + 050h], xmm11
+        movdqa  [rsp + 040h + 060h], xmm12
+        movdqa  [rsp + 040h + 070h], xmm13
+        movdqa  [rsp + 040h + 080h], xmm14
+        movdqa  [rsp + 040h + 090h], xmm15
+
+        ; Load the full guest XMM register state.
+        mov     r10, [xBP + 018h]       ; pCtx
+        lea     r10, [r10 + XMM_OFF_IN_X86FXSTATE]
+        movdqa  xmm0,  [r10 + 000h]
+        movdqa  xmm1,  [r10 + 010h]
+        movdqa  xmm2,  [r10 + 020h]
+        movdqa  xmm3,  [r10 + 030h]
+        movdqa  xmm4,  [r10 + 040h]
+        movdqa  xmm5,  [r10 + 050h]
+        movdqa  xmm6,  [r10 + 060h]
+        movdqa  xmm7,  [r10 + 070h]
+        movdqa  xmm8,  [r10 + 080h]
+        movdqa  xmm9,  [r10 + 090h]
+        movdqa  xmm10, [r10 + 0a0h]
+        movdqa  xmm11, [r10 + 0b0h]
+        movdqa  xmm12, [r10 + 0c0h]
+        movdqa  xmm13, [r10 + 0d0h]
+        movdqa  xmm14, [r10 + 0e0h]
+        movdqa  xmm15, [r10 + 0f0h]
+
+        ; Make the call (same as in the other case ).
+        mov     r11, [xBP + 38h]        ; pfnStartVM
+        mov     r10, [xBP + 30h]        ; pVCpu
+        mov     [xSP + 020h], r10
+        mov     rcx, [xBP + 010h]       ; fResumeVM
+        mov     rdx, [xBP + 018h]       ; pCtx
+        mov     r8,  [xBP + 020h]       ; pVMCSCache
+        mov     r9,  [xBP + 028h]       ; pVM
+        call    r11
+
+        ; Save the guest XMM registers.
+        mov     r10, [xBP + 018h]       ; pCtx
+        lea     r10, [r10 + XMM_OFF_IN_X86FXSTATE]
+        movdqa  [r10 + 000h], xmm0
+        movdqa  [r10 + 010h], xmm1
+        movdqa  [r10 + 020h], xmm2
+        movdqa  [r10 + 030h], xmm3
+        movdqa  [r10 + 040h], xmm4
+        movdqa  [r10 + 050h], xmm5
+        movdqa  [r10 + 060h], xmm6
+        movdqa  [r10 + 070h], xmm7
+        movdqa  [r10 + 080h], xmm8
+        movdqa  [r10 + 090h], xmm9
+        movdqa  [r10 + 0a0h], xmm10
+        movdqa  [r10 + 0b0h], xmm11
+        movdqa  [r10 + 0c0h], xmm12
+        movdqa  [r10 + 0d0h], xmm13
+        movdqa  [r10 + 0e0h], xmm14
+        movdqa  [r10 + 0f0h], xmm15
+
+        ; Load the host XMM registers.
+        movdqa  xmm6,  [rsp + 040h + 000h]
+        movdqa  xmm7,  [rsp + 040h + 010h]
+        movdqa  xmm8,  [rsp + 040h + 020h]
+        movdqa  xmm9,  [rsp + 040h + 030h]
+        movdqa  xmm10, [rsp + 040h + 040h]
+        movdqa  xmm11, [rsp + 040h + 050h]
+        movdqa  xmm12, [rsp + 040h + 060h]
+        movdqa  xmm13, [rsp + 040h + 070h]
+        movdqa  xmm14, [rsp + 040h + 080h]
+        movdqa  xmm15, [rsp + 040h + 090h]
+        leave
+        ret
+ENDPROC   hwaccmR0VMXStartVMWrapperXMM
+%endif
 
 ;

trunk/src/VBox/VMM/VMMR0/HWVMXR0.cpp

@@ -2334 +2334 @@
 
     TMNotifyStartOfExecution(pVCpu);
+#ifdef VBOX_WITH_KERNEL_USING_XMM
+    rc = hwaccmR0VMXStartVMWrapperXMM(pVCpu->hwaccm.s.fResumeVM, pCtx, &pVCpu->hwaccm.s.vmx.VMCSCache, pVM, pVCpu, pVCpu->hwaccm.s.vmx.pfnStartVM);
+#else
     rc = pVCpu->hwaccm.s.vmx.pfnStartVM(pVCpu->hwaccm.s.fResumeVM, pCtx, &pVCpu->hwaccm.s.vmx.VMCSCache, pVM, pVCpu);
+#endif
     TMNotifyEndOfExecution(pVCpu);
     VMCPU_SET_STATE(pVCpu, VMCPUSTATE_STARTED);