Changeset 50491 in vbox for trunk/src/VBox/Frontends/VirtualBox

Timestamp:

Feb 18, 2014 12:11:28 PM (11 years ago)

Author:

vboxsync

svn:sync-xref-src-repo-rev:

92332

Message:

FE/Qt: Mac OS X: 7016: UICocoaApplication: Native notification handling framework.

Location:

trunk/src/VBox/Frontends/VirtualBox/src/platform/darwin

Files:

• UICocoaApplication.h (modified) (4 diffs)
• UICocoaApplication.mm (modified) (4 diffs)

trunk/src/VBox/Frontends/VirtualBox/src/platform/darwin/UICocoaApplication.h

@@ -18 +18 @@
 #define ___darwin_VBoxCocoaApplication_h
 
+/* Qt includes: */
+#include <QMap>
+
+/* GUI includes: */
 #include "VBoxCocoaHelper.h"
+
 ADD_COCOA_NATIVE_REF(UICocoaApplicationPrivate);
 ADD_COCOA_NATIVE_REF(NSAutoreleasePool);
+ADD_COCOA_NATIVE_REF(NSString);
+ADD_COCOA_NATIVE_REF(NSWindow);
+
+/* Forward declarations: */
+class QWidget;
 
 /** Event handler callback.
@@ -29 +39 @@
  */
 typedef bool (*PFNVBOXCACALLBACK)(const void *pvCocoaEvent, const void *pvCarbonEvent, void *pvUser);
+
+/** Native notification callback type for QWidget. */
+typedef void (*PfnNativeNotificationCallbackForQWidget)(const QString &strNativeNotificationName, QWidget *pWidget);
 
 /* C++ singleton for our private NSApplication object */
@@ -41 +54 @@
     void unregisterForNativeEvents(uint32_t fMask, PFNVBOXCACALLBACK pfnCallback, void *pvUser);
 
+    /** Register passed @a pWidget to native notification @a strNativeNotificationName, using @a pCallback as handler. */
+    void registerToNativeNotification(const QString &strNativeNotificationName, QWidget *pWidget, PfnNativeNotificationCallbackForQWidget pCallback);
+    /** Unregister passed @a pWidget from native notification @a strNativeNotificationName. */
+    void unregisterFromNativeNotification(const QString &strNativeNotificationName, QWidget *pWidget);
+    /** Redirects native notification @a pstrNativeNotificationName for window @a pWindow to registered listener. */
+    void nativeNotificationProxy(NativeNSStringRef pstrNativeNotificationName, NativeNSWindowRef pWindow);
+
 private:
     UICocoaApplication();
@@ -46 +66 @@
     NativeUICocoaApplicationPrivateRef m_pNative;
     NativeNSAutoreleasePoolRef m_pPool;
+
+    /** Map of notification callbacks registered for corresponding QWidget(s). */
+    QMap<QWidget*, QMap<QString, PfnNativeNotificationCallbackForQWidget> > m_callbacks;
 };
 

trunk/src/VBox/Frontends/VirtualBox/src/platform/darwin/UICocoaApplication.mm

@@ -16 +16 @@
  */
 
-/* Local includes */
+/* GUI includes: */
 #include "UICocoaApplication.h"
 #include "VBoxUtils-darwin.h"
@@ -68 +68 @@
 - (void)setCallback:(uint32_t)fMask :(PFNVBOXCACALLBACK)pfnCallback :(void *)pvUser;
 - (void)unsetCallback:(uint32_t)fMask :(PFNVBOXCACALLBACK)pfnCallback :(void *)pvUser;
+
+- (void)registerToNotification :(NSString*)pstrNotificationName :(NSWindow*)pWindow;
+- (void)unregisterFromNotification :(NSString*)pstrNotificationName :(NSWindow*)pWindow;
+- (void)notificationCallback :(NSNotification*)notification;
 @end /* @interface UICocoaApplicationPrivate */
 
@@ -160 +164 @@
     m_fMask = fNewMask;
 }
+
+/** Register @a pWindow to cocoa notification @a pstrNotificationName. */
+- (void) registerToNotification :(NSString*)pstrNotificationName :(NSWindow*)pWindow
+{
+    /* Register notification observer: */
+    [[NSNotificationCenter defaultCenter] addObserver:self
+                                             selector:@selector(notificationCallback:)
+                                                 name:pstrNotificationName
+                                               object:pWindow];
+}
+
+/** Unregister @a pWindow from cocoa notification @a pstrNotificationName. */
+- (void) unregisterFromNotification :(NSString*)pstrNotificationName :(NSWindow*)pWindow
+{
+    /* Uninstall notification observer: */
+    [[NSNotificationCenter defaultCenter] removeObserver:self
+                                                    name:pstrNotificationName
+                                                  object:pWindow];
+}
+
+/** Redirects cocoa @a notification to UICocoaApplication instance. */
+- (void) notificationCallback :(NSNotification*)notification
+{
+    /* Get current notification name: */
+    NSString *pstrName = [notification name];
+
+    /* Define known notification names: */
+    NSString *spstrWillEnterFullscreenNotification = @"NSWindowWillEnterFullScreenNotification";
+    NSString *spstrDidEnterFullscreenNotification  = @"NSWindowDidEnterFullScreenNotification";
+    NSString *spstrWillExitFullscreenNotification  = @"NSWindowWillExitFullScreenNotification";
+    NSString *spstrDidExitFullscreenNotification   = @"NSWindowDidExitFullScreenNotification";
+
+    /* Redirect known notifications to UICocoaApplication instance: */
+    if (   [pstrName isEqualToString :spstrWillEnterFullscreenNotification]
+        || [pstrName isEqualToString :spstrDidEnterFullscreenNotification]
+        || [pstrName isEqualToString :spstrWillExitFullscreenNotification]
+        || [pstrName isEqualToString :spstrDidExitFullscreenNotification])
+        UICocoaApplication::instance()->nativeNotificationProxy(pstrName, [notification object]);
+}
 @end /* @implementation UICocoaApplicationPrivate */
 
@@ -206 +249 @@
 }
 
+void UICocoaApplication::registerToNativeNotification(const QString &strNativeNotificationName, QWidget *pWidget, PfnNativeNotificationCallbackForQWidget pCallback)
+{
+    /* Make sure it is not registered yet: */
+    AssertReturnVoid(!m_callbacks.contains(pWidget) || !m_callbacks[pWidget].contains(strNativeNotificationName));
+
+    /* Remember callback: */
+    m_callbacks[pWidget][strNativeNotificationName] = pCallback;
+
+    /* Register observer: */
+    NativeNSStringRef pstrNativeNotificationName = darwinToNativeString(strNativeNotificationName.toLatin1().constData());
+    NativeNSWindowRef pWindow = darwinToNativeWindow(pWidget);
+    [m_pNative registerToNotification :pstrNativeNotificationName :pWindow];
+}
+
+void UICocoaApplication::unregisterFromNativeNotification(const QString &strNativeNotificationName, QWidget *pWidget)
+{
+    /* Make sure it is registered yet: */
+    AssertReturnVoid(m_callbacks.contains(pWidget) && m_callbacks[pWidget].contains(strNativeNotificationName));
+
+    /* Forget callback: */
+    m_callbacks[pWidget].remove(strNativeNotificationName);
+    if (m_callbacks[pWidget].isEmpty())
+        m_callbacks.remove(pWidget);
+
+    /* Unregister observer: */
+    NativeNSStringRef pstrNativeNotificationName = darwinToNativeString(strNativeNotificationName.toLatin1().constData());
+    NativeNSWindowRef pWindow = darwinToNativeWindow(pWidget);
+    [m_pNative unregisterFromNotification :pstrNativeNotificationName :pWindow];
+}
+
+void UICocoaApplication::nativeNotificationProxy(NativeNSStringRef pstrNotificationName, NativeNSWindowRef pWindow)
+{
+    /* Get notification name: */
+    QString strNotificationName = darwinFromNativeString(pstrNotificationName);
+
+    /* Check if existing widget(s) have corresponding notification handler: */
+    const QList<QWidget*> &keys1 = m_callbacks.keys();
+    for (int i = 0; i < keys1.size(); ++i)
+    {
+        QWidget *pWidget = keys1[i];
+        if (darwinToNativeWindow(pWidget) == pWindow)
+        {
+            const QMap<QString, PfnNativeNotificationCallbackForQWidget> &callbacks = m_callbacks[pWidget];
+            if (callbacks.contains(strNotificationName))
+                callbacks[strNotificationName](strNotificationName, pWidget);
+        }
+    }
+}
+