Changeset 726 in vbox

Timestamp:

Feb 6, 2007 7:21:48 PM (18 years ago)

Author:

vboxsync

svn:sync-xref-src-repo-rev:

18368

Message:

Implemented the VMMR0 setjmp/longjmp like stuff for AMD64.

Location:

trunk/src/VBox/VMM

Files:

• VMMR0/VMMR0A.asm (modified) (4 diffs)
• testcase/tstVMMR0CallHost-1.cpp (modified) (1 diff)

trunk/src/VBox/VMM/VMMR0/VMMR0A.asm

@@ -44 +44 @@
 ;
 ; @returns  VINF_SUCCESS on success or whatever is passed to vmmR0CallHostLongJmp.
-; @param    pJmpBuf     Our jmp_buf.
-; @param    pfn         The function to be called when not resuming.
-; @param    pVM         The argument of that function.
+; @param    pJmpBuf msc:rcx gcc:rdi x86:[esp+4]     Our jmp_buf.
+; @param    pfn     msc:rdx gcc:rsi x86:[esp+8]     The function to be called when not resuming.
+; @param    pVM     msc:r8  gcc:rcx x86:[esp+c]     The argument of that function.
 ;
 BEGINPROC vmmR0CallHostSetJmp
@@ -128 +128 @@
 
 %ifdef __AMD64__
-    int3    ; implement me!
+    ;
+    ; Save the registers.
+    ;
+ %ifdef ASM_CALL64_MSC
+    xchg    rdx, rcx                    ; rdx=pJmpBuf rcx=pfn
+ %else
+    mov     rdx, rdi                    ; pJmpBuf
+ %endif
+    mov     [rdx + VMMR0JMPBUF.rbx], rbx
+ %ifdef ASM_CALL64_MSC
+    mov     [rdx + VMMR0JMPBUF.rsi], rsi
+    mov     [rdx + VMMR0JMPBUF.rdi], rdi
+ %endif
+    mov     [rdx + VMMR0JMPBUF.rbp], rbp
+    mov     [rdx + VMMR0JMPBUF.r12], r12
+    mov     [rdx + VMMR0JMPBUF.r13], r13
+    mov     [rdx + VMMR0JMPBUF.r14], r14
+    mov     [rdx + VMMR0JMPBUF.r15], r15
+    mov     rax, [rsp]
+    mov     [rdx + VMMR0JMPBUF.rip], rax
+    lea     r10, [rsp + 8]              ; (used in resume)
+    mov     [rdx + VMMR0JMPBUF.rsp], r10
+
+    ;
+    ; If we're not in a ring-3 call, call pfn and return.
+    ;
+    test    byte [rdx + VMMR0JMPBUF.fInRing3Call], 1
+    jnz     .resume
+
+    push    rdx                         ; Save it and fix stack alignment (16).
+ %ifdef ASM_CALL64_MSC
+    mov     rax, rcx                    ; pfn
+    mov     rcx, r8                     ; pVM -> arg0
+ %else
+    mov     rax, rsi                    ; pfn
+    mov     rdi, rcx                    ; pVM -> arg0
+ %endif
+    call    rax
+    pop     rdx                         ; pJmpBuf
+    and     qword [rdx + VMMR0JMPBUF.rip], byte 0 ; used for valid check.
+    ret
+
+    ;
+    ; Resume VMMR0CallHost the call.
+    ;
+.resume:
+    ; Sanity checks.
+    cmp     r10, [rdx + VMMR0JMPBUF.SpCheck]
+    je      .rspCheck_ok
+.bad:
+    and     qword [rdx + VMMR0JMPBUF.rip], byte 0 ; used for valid check.
+    mov     rbx, [rdx + VMMR0JMPBUF.rbx]
+ %ifdef ASM_CALL64_MSC
+    mov     rsi, [rdx + VMMR0JMPBUF.rsi]
+    mov     rdi, [rdx + VMMR0JMPBUF.rdi]
+ %endif
+    mov     r12, [rdx + VMMR0JMPBUF.r12] 
+    mov     r13, [rdx + VMMR0JMPBUF.r13] 
+    mov     r14, [rdx + VMMR0JMPBUF.r14] 
+    mov     r15, [rdx + VMMR0JMPBUF.r15] 
+    mov     eax, VERR_INTERNAL_ERROR    ; todo better return code!
+    ret
+
+.rspCheck_ok:
+    mov     ecx, [rdx + VMMR0JMPBUF.cbSavedStack]
+    cmp     rcx, 8192
+    ja      .bad
+    test    rcx, 3
+    jnz     .bad
+    mov     rdi, [rdx + VMMR0JMPBUF.rsp]
+    sub     rdi, [rdx + VMMR0JMPBUF.SpResume]
+    cmp     rcx, rdi
+    jne     .bad
+
+    ;
+    ; Restore the stack.
+    ;
+    mov     byte [rdx + VMMR0JMPBUF.fInRing3Call], 0
+    mov     ecx, [rdx + VMMR0JMPBUF.cbSavedStack]
+    shr     ecx, 3
+    mov     rsi, [rdx + VMMR0JMPBUF.pvSavedStack]
+    mov     rdi, [rdx + VMMR0JMPBUF.SpResume]
+    mov     rsp, rdi
+    rep movsq
+
+    ;
+    ; Continue where we left off.
+    ;
+    popf
+    pop     rbx
+ %ifdef ASM_CALL64_MSC
+    pop     rsi
+    pop     rdi
+ %endif
+    pop     r12
+    pop     r13
+    pop     r14
+    pop     r15
+    pop     rbp
+    xor     eax, eax                    ; VINF_SUCCESS
+    ret
 %endif
 ENDPROC vmmR0CallHostSetJmp
@@ -137 +237 @@
 ; This will save the stack and registers.
 ;
-; @param    pJmpBuf         Pointer to the jump buffer.
-; @param    rc              The return code.
+; @param    pJmpBuf msc:rcx gcc:rdi x86:[ebp+8]     Pointer to the jump buffer.
+; @param    rc      msc:rdx gcc:rsi x86:[ebp+c]     The return code.
 ;
 BEGINPROC vmmR0CallHostLongJmp
@@ -209 +309 @@
 
 %ifdef __AMD64__
-    int3    ; implement me!
+    ;
+    ; Save the registers on the stack.
+    ;
+    push    rbp
+    mov     rbp, rsp
+    push    r15
+    push    r14
+    push    r13
+    push    r12
+ %ifdef ASM_CALL64_MSC
+    push    rdi
+    push    rsi
+ %endif
+    push    rbx
+    pushf
+
+    ;
+    ; Normalize the parameters.
+    ;
+ %ifdef ASM_CALL64_MSC
+                                        ; pJmpBuf already in rdx
+    mov     eax, ecx                    ; rc
+ %else
+    mov     rdx, rdi                    ; pJmpBuf
+    mov     eax, esi                    ; rc
+ %endif
+
+    ;
+    ; Is the jump buffer armed?
+    ;
+    cmp     qword [rdx + VMMR0JMPBUF.rip], byte 0
+    je      .nok
+
+    ;
+    ; Save the stack.
+    ;
+    mov     rdi, [rdx + VMMR0JMPBUF.pvSavedStack]
+    mov     [rdx + VMMR0JMPBUF.SpResume], rsp
+    mov     rsi, rsp
+    mov     rcx, [rdx + VMMR0JMPBUF.rsp]
+    sub     rcx, rsi
+
+    ; two sanity checks on the size.
+    cmp     rcx, 8192                   ; check max size.
+    jbe     .ok
+.nok:
+    mov     eax, VERR_INTERNAL_ERROR
+    popf
+    pop     rbx
+ %ifdef ASM_CALL64_MSC
+    pop     rsi
+    pop     rdi
+ %endif
+    pop     r12
+    pop     r13
+    pop     r14
+    pop     r15
+    leave
+    ret
+
+.ok:
+    test    ecx, 7                      ; check alignment
+    jnz     .nok
+    mov     [rdx + VMMR0JMPBUF.cbSavedStack], ecx
+    shr     ecx, 3
+    rep movsq
+
+    ; store the last pieces of info.
+    mov     rcx, [edx + VMMR0JMPBUF.rsp]
+    mov     [rdx + VMMR0JMPBUF.SpCheck], rcx
+    mov     byte [rdx + VMMR0JMPBUF.fInRing3Call], 1
+
+    ;
+    ; Do the long jump.
+    ;
+    mov     rbx, [rdx + VMMR0JMPBUF.rbx]
+ %ifdef ASM_CALL64_MSC
+    mov     rsi, [rdx + VMMR0JMPBUF.rsi]
+    mov     rdi, [rdx + VMMR0JMPBUF.rdi]
+ %endif
+    mov     r12, [rdx + VMMR0JMPBUF.r12]
+    mov     r13, [rdx + VMMR0JMPBUF.r13]
+    mov     r14, [rdx + VMMR0JMPBUF.r14]
+    mov     r15, [rdx + VMMR0JMPBUF.r15]
+    mov     rbp, [rdx + VMMR0JMPBUF.rbp]
+    mov     rcx, [rdx + VMMR0JMPBUF.rip]
+    mov     rsp, [rdx + VMMR0JMPBUF.rsp]
+    jmp     rcx
 %endif
 ENDPROC vmmR0CallHostLongJmp

trunk/src/VBox/VMM/testcase/tstVMMR0CallHost-1.cpp

@@ -62 +62 @@
 DECLCALLBACK(int) tst2(intptr_t i)
 {
+    if (i < 0 || i > 8192)
+    {
+        RTPrintf("tstVMMR0CallHost-1: FAILURE - i=%d is out of range [0..8192]\n", i);
+        return 1;
+    }
     int iExpect = (i % 7) == 0 ? i + 10000 : i;
     int rc = foo(i, 0, -1);